[gentoo-commits] repo/gentoo:master commit in: dev-python/moto/

[Michał Górny]

commit:     663c55a0c892c0db0c44de95dd897b51ec120cae
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  9 06:02:18 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Sep  9 07:18:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=663c55a0

dev-python/moto: Bump to 1.3.16

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/moto/Manifest           |  1 +
 dev-python/moto/moto-1.3.16.ebuild | 86 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 16ffb850e54..bf08796e5b8 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,2 +1,3 @@
 DIST moto-1.3.14.tar.gz 1829165 BLAKE2B 2ec30c4cc571492a9d2c08f66a39ad04cfc0baa7864db8a5be4ea9af24ecb59bad3e85c44fa8a7babc16bf66188cb6bef89484f1f302a11e6eec1f8dbf516492 SHA512 1fe7e9d49dadada82f24d6bef1c21419c414e027c21ed1099bd1eab7c269ac5638ed44a29d1557b37562a44b22a7c7251fc1ca8ba88cde6b82d39dbc620aa6a6
 DIST moto-1.3.15.tar.gz 1760920 BLAKE2B 61f64f31e0227a29d773c033cbd77eb7dc4e0c8ad3eed5b373c34cb0ca410032dd02fe5ce26885d25b48e06d40a0e6988100720abd9b4a6b67318b6b6972ad1b SHA512 140b94eb063b08562429edc933da2bde87dc09d6bdbb8ea9846318772de9b9135181e62d0b552b638351e98bf8e1168305e45bc484258c9fe6991ca906ce5af0
+DIST moto-1.3.16.tar.gz 1761006 BLAKE2B adb48ac770e0753403fd41309ebc2085e5d9cdfad5dc791d9cc1216af10e55038c37526a8549a034a3327d821c56b0f6cdd775a17336285bfc637c09191dd78d SHA512 80a1335fea8d6dd42b4062365da4719d26cd6c18e5c186c950bbb844dce44e91ffe5e5173742f3b60d6ba2cab93d45359b43c2cb0ccf74d16009986457c243a4

diff --git a/dev-python/moto/moto-1.3.16.ebuild b/dev-python/moto/moto-1.3.16.ebuild
new file mode 100644
index 00000000000..cebf5f92d96
--- /dev/null
+++ b/dev-python/moto/moto-1.3.16.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/cfn-python-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.3.0[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto-2.36.0[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${RDEPEND}
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# Disable tests that fail with network-sandbox.
+	sed -e 's|^\(def \)\(test_context_manager()\)|\1_\2|' \
+		-e 's|^\(def \)\(test_decorator_start_and_stop()\)|\1_\2|' \
+		-i tests/test_core/test_decorator_calls.py || die
+
+	# require docker
+	rm tests/test_awslambda/test_lambda*.py || die
+	rm tests/test_batch/test_batch.py || die
+
+	sed -e 's:test_create_stack_lambda_and_dynamodb:_&:' \
+		-i tests/test_cloudformation/test_cloudformation_stack_crud.py || die
+	sed -e 's:test_lambda_function:_&:' \
+		-i tests/test_cloudformation/test_cloudformation_stack_integration.py || die
+	sed -e 's:test_passthrough_requests:_&:' \
+		-i tests/test_core/test_request_mocking.py || die
+	sed -e 's:test_delete_subscription_filter_errors:_&:' \
+		-e 's:test_put_subscription_filter_update:_&:' \
+		-e 's:test_put_subscription_filter_with_lambda:_&:' \
+		-i tests/test_logs/test_logs.py || die
+
+	# these tests crash nose
+	rm tests/test_xray/test_xray_client.py || die
+
+	distutils-r1_python_prepare_all
+}