[gentoo-commits] repo/gentoo:master commit in: app-arch/snappy/

[Michał Górny]

commit:     64be55454886b6b693413b2669a095d35f435e85
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 31 12:20:07 2016 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 31 12:22:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64be5545

app-arch/snappy: Clean up the ebuild, bump to EAPI=6

Replace partial use of deprecated autotools-multilib with correct
combination of autotools & multilib-minimal. Clean up the code a bit,
and bump it to EAPI=6.

 app-arch/snappy/snappy-1.1.3-r1.ebuild | 42 ++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/app-arch/snappy/snappy-1.1.3-r1.ebuild b/app-arch/snappy/snappy-1.1.3-r1.ebuild
new file mode 100644
index 0000000..2e7e891
--- /dev/null
+++ b/app-arch/snappy/snappy-1.1.3-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools multilib-minimal
+
+DESCRIPTION="A high-speed compression/decompression library by Google"
+HOMEPAGE="https://github.com/google/snappy"
+SRC_URI="https://github.com/google/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86
+	~amd64-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+src_prepare() {
+	# Avoid automagic lzo and gzip by not checking for it
+	sed -i '/^CHECK_EXT_COMPRESSION_LIB/d' configure.ac || die
+
+	# don't install unwanted files
+	sed -i 's/COPYING INSTALL//' Makefile.am || die
+
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--without-gflags
+		--disable-gtest
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE=${S} \
+	econf "${myconf[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED%/}"/usr/lib* -name '*.la' -delete || die
+}