[gentoo-commits] gentoo-x86 commit in net-misc/suite3270: ChangeLog suite3270-3.3.7_p8.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/10/10 08:17:25

  Modified:             ChangeLog
  Added:                suite3270-3.3.7_p8.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc11/cvs/Linux 2.6.27-rc1-10246-gca5de40 x86_64)

Revision  Changes    Path
1.24                 net-misc/suite3270/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/suite3270/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -p -w -b -B -u -u -r1.23 -r1.24
--- ChangeLog	10 Oct 2008 08:14:28 -0000	1.23
+++ ChangeLog	10 Oct 2008 08:17:25 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/suite3270
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.23 2008/10/10 08:14:28 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.24 2008/10/10 08:17:25 robbat2 Exp $
+
+*suite3270-3.3.7_p8 (10 Oct 2008)
+
+  10 Oct 2008; Robin H. Johnson <robbat2@g.o>
+  +suite3270-3.3.7_p8.ebuild:
+  Version bump.
 
   10 Oct 2008; Robin H. Johnson <robbat2@g.o>
   suite3270-3.2.20.ebuild, suite3270-3.3.2_p1.ebuild,



1.1                  net-misc/suite3270/suite3270-3.3.7_p8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/suite3270/suite3270-3.3.7_p8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/suite3270/suite3270-3.3.7_p8.ebuild?rev=1.1&content-type=text/plain

Index: suite3270-3.3.7_p8.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/suite3270-3.3.7_p8.ebuild,v 1.1 2008/10/10 08:17:25 robbat2 Exp $

inherit eutils

IUSE="cjk doc ncurses ssl tcl X"

S="${WORKDIR}"
DESCRIPTION="Complete 3270 access package"
SRC_URI="http://x3270.bgp.nu/download/${PN}-${PV/_/}.tgz"
HOMEPAGE="http://www.geocities.com/SiliconValley/Peaks/7814/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~s390 ~sparc ~x86"

RDEPEND="X? ( x11-libs/libX11
			  x11-libs/libXaw
			  x11-libs/libXmu
			  x11-libs/libXt )
		 cjk? ( dev-libs/icu )
		 ncurses? ( sys-libs/ncurses
					sys-libs/readline )
		 ssl? ( dev-libs/openssl )
		 tcl? ( dev-lang/tcl )"

DEPEND="${RDEPEND}
		X? ( x11-misc/imake
			 x11-misc/xbitmaps
			 x11-proto/xproto
			 app-text/rman
			 x11-apps/mkfontdir
			 x11-apps/bdftopcf )"

SUB_PV="3.3"
MY_FONTDIR="/usr/share/fonts/x3270"

suite3270_makelist() {
	MY_PLIST="pr3287 s3270"
	use ncurses && MY_PLIST="${MY_PLIST} c3270"
	use tcl && MY_PLIST="${MY_PLIST} tcl3270"
	use X && MY_PLIST="${MY_PLIST} x3270"
}

src_compile() {
	local myconf

	myconf="--without-pr3287"
	myconf="${myconf} --cache-file=${S}/config.cache"
	myconf="${myconf} $(use_enable cjk dbcs)"
	myconf="${myconf} $(use_enable ssl)"
	myconf="${myconf} $(use_with X x)"
	myconf="${myconf} $(use_with X fontdir ${MY_FONTDIR})"

	suite3270_makelist
	for p in ${MY_PLIST} ; do
		cd "${S}/${p}-${SUB_PV}"
		econf ${myconf} || die "econf failed on ${p}"
		emake || die "emake faild on ${p}"
	done
}

src_install () {
	suite3270_makelist
	use X && dodir ${MY_FONTDIR}
	for p in ${MY_PLIST} ; do
		cd "${S}/${p}-${SUB_PV}"
		emake DESTDIR="${D}" install install.man \
			|| die "emake failed on ${p}"
		use doc && docinto ${p} && dohtml html/*
	done

	use X && rm -f "${D}/${MY_FONTDIR}/fonts.dir"
	return 0
}

pkg_postinst() {
	if use X ; then
		einfo "Running mkfontdir on ${MY_FONTDIR}"
		mkfontdir ${MY_FONTDIR}
	fi
}