[gentoo-commits] gentoo-x86 commit in dev-vcs/tortoisehg: tortoisehg-2.1.3.ebuild metadata.xml ChangeLog

[Mike Gilbert (floppym)]

floppym     11/09/07 02:33:42

  Added:                tortoisehg-2.1.3.ebuild metadata.xml ChangeLog
  Log:
  New package, resolves bug 277383 by manny15. Thanks also to Arne Babenhauserheide, Denilson Sá, and Alphat-PC.
  
  (Portage version: 2.2.0_alpha53/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-vcs/tortoisehg/tortoisehg-2.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.1.3.ebuild?rev=1.1&content-type=text/plain

Index: tortoisehg-2.1.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.1.3.ebuild,v 1.1 2011/09/07 02:33:42 floppym Exp $

EAPI=3

SUPPORT_PYTHON_ABIS=1
PYTHON_DEPEND="2:2.5"
RESTRICT_PYTHON_ABIS="2.4 3.*"

inherit distutils eutils multilib

DESCRIPTION="Set of graphical tools for Mercurial"
HOMEPAGE="http://tortoisehg.bitbucket.org"
SRC_URI="http://bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc nautilus"

RDEPEND="dev-python/iniparse
	dev-python/pygments
	dev-python/PyQt4
	dev-python/qscintilla-python
	>=dev-vcs/mercurial-1.9
	nautilus? ( dev-python/nautilus-python )"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-1.0.3 )"

src_prepare() {
	# make the install respect multilib.
	sed -i -e "s:lib/nautilus:$(get_libdir)/nautilus:" setup.py || die
	distutils_src_prepare
}

src_compile() {
	distutils_src_compile

	if use doc ; then
		emake -C doc html || die
	fi
}

src_install() {
	distutils_src_install
	dodoc doc/ReadMe*.txt doc/TODO || die

	if use doc ; then
		dohtml -r doc/build/html || die
	fi

	insinto /usr/share/icons/hicolor/scalable/apps
	newins icons/scalable/apps/thg-logo.svg tortoisehg_logo.svg || die
	domenu contrib/${PN}.desktop || die

	if ! use nautilus; then
		rm -rf "${ED}usr/$(get_libdir)/nautilus" || die
	fi
}



1.1                  dev-vcs/tortoisehg/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>floppym@g.o</email>
		<name>Mike Gilbert</name>
	</maintainer>
	<use>
		<flag name="nautilus">Integrate with <pkg>gnome-base/nautilus</pkg> file manager</flag>
	</use>
</pkgmetadata>



1.1                  dev-vcs/tortoisehg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-vcs/tortoisehg
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.1 2011/09/07 02:33:42 floppym Exp $

*tortoisehg-2.1.3 (07 Sep 2011)

  07 Sep 2011; Mike Gilbert <floppym@g.o> +tortoisehg-2.1.3.ebuild,
  +metadata.xml:
  New package, resolves bug 277383 by manny15. Thanks also to Arne
  Babenhauserheide, Denilson Sá, and Alphat-PC.