[gentoo-commits] gentoo-x86 commit in dev-libs/libcdio-paranoia: ChangeLog libcdio-paranoia-0.93_p1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/01/29 06:59:42

  Modified:             ChangeLog
  Added:                libcdio-paranoia-0.93_p1.ebuild
  Log:
  Version bump (bug #524356)
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.25                 dev-libs/libcdio-paranoia/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	18 Jun 2014 19:12:09 -0000	1.24
+++ ChangeLog	29 Jan 2015 06:59:42 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libcdio-paranoia
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog,v 1.24 2014/06/18 19:12:09 mgorny Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio-paranoia/ChangeLog,v 1.25 2015/01/29 06:59:42 polynomial-c Exp $
+
+*libcdio-paranoia-0.93_p1 (29 Jan 2015)
+
+  29 Jan 2015; Lars Wendler <polynomial-c@g.o>
+  +libcdio-paranoia-0.93_p1.ebuild:
+  Version bump (bug #524356).
 
   18 Jun 2014; Michał Górny <mgorny@g.o>
   libcdio-paranoia-0.90_p1-r1.ebuild:



1.1                  dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1.ebuild?rev=1.1&content-type=text/plain

Index: libcdio-paranoia-0.93_p1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1.ebuild,v 1.1 2015/01/29 06:59:42 polynomial-c Exp $

EAPI=5
MY_P=${PN}-10.2+${PV/_p/+}

AUTOTOOLS_AUTORECONF=yes

inherit eutils autotools-multilib

DESCRIPTION="an advanced CDDA reader with error correction"
HOMEPAGE="http://www.gnu.org/software/libcdio/"
SRC_URI="mirror://gnu/${PN%-*}/${MY_P}.tar.gz"

# COPYING-GPL from cdparanoia says "2 or later"
# COPYING-LGPL from cdparanoia says "2.1 or later" but 2 files are without the
# clause "or later" so we use LGPL-2.1 without +
LICENSE="GPL-3+ GPL-2+ LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="+cxx static-libs test"

RDEPEND="app-admin/eselect-cdparanoia
	>=dev-libs/libcdio-0.93[${MULTILIB_USEDEP}]
	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r10
		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig
	test? ( dev-lang/perl )"

S=${WORKDIR}/${MY_P}

DOCS=( AUTHORS ChangeLog NEWS README THANKS )

src_prepare() {
	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466410
	autotools-multilib_src_prepare
}

src_configure() {
	local myeconfargs=(
		--disable-maintainer-mode
		--disable-example-progs
		$(use_enable cxx)
		--disable-cpp-progs
		--with-cd-paranoia-name=libcdio-paranoia
	)
	autotools-multilib_src_configure
}

pkg_postinst() {
	eselect cdparanoia update ifunset
}

pkg_postrm() {
	eselect cdparanoia update ifunset
}