[gentoo-commits] gentoo-x86 commit in x11-wm/fluxbox: fluxbox-1.3.0.ebuild ChangeLog

[Jim Ramsay (lack)]

lack        11/02/22 13:22:55

  Modified:             ChangeLog
  Added:                fluxbox-1.3.0.ebuild
  Log:
  Fluxbox 1.3.0 is released!  (Bug #355643)
  
  (Portage version: 2.1.9.34/cvs/Linux i686)

Revision  Changes    Path
1.284                x11-wm/fluxbox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.284&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.284&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?r1=1.283&r2=1.284

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v
retrieving revision 1.283
retrieving revision 1.284
diff -u -r1.283 -r1.284
--- ChangeLog	20 Feb 2011 23:50:34 -0000	1.283
+++ ChangeLog	22 Feb 2011 13:22:55 -0000	1.284
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/fluxbox
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.283 2011/02/20 23:50:34 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.284 2011/02/22 13:22:55 lack Exp $
+
+*fluxbox-1.3.0 (21 Feb 2011)
+
+  21 Feb 2011; Jim Ramsay <lack@g.o> +fluxbox-1.3.0.ebuild,
+  +files/fluxbox-1.3.0-osx-has-otool.patch:
+  Fluxbox 1.3.0 is released! (Bug #355643)
 
   20 Feb 2011; Joseph Jezak <josejx@g.o> fluxbox-1.1.1-r3.ebuild:
   Marked ppc/ppc64 stable for bug #352833.



1.1                  x11-wm/fluxbox/fluxbox-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: fluxbox-1.3.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.0.ebuild,v 1.1 2011/02/22 13:22:55 lack Exp $

EAPI="4"
inherit eutils prefix

IUSE="nls xinerama bidi +truetype gnome +imlib +slit +toolbar vim-syntax"

DESCRIPTION="Fluxbox is an X11 window manager featuring tabs and an iconbar"

SRC_URI="mirror://sourceforge/fluxbox/${P}.tar.bz2"
HOMEPAGE="http://www.fluxbox.org"

# Please note that USE="gnome" simply adds support for some gnome protocols, and
# does not depend on external libraries.  However, it does make the binary a
# fair bit bigger, so we don't want to turn it on unless the user actually wants
# it.

RDEPEND="x11-libs/libXpm
	x11-libs/libXrandr
	xinerama? ( x11-libs/libXinerama )
	x11-apps/xmessage
	x11-libs/libXft
	truetype? ( media-libs/freetype )
	bidi? ( dev-libs/fribidi )
	imlib? ( >=media-libs/imlib2-1.2.0[X] )
	vim-syntax? ( app-vim/fluxbox-syntax )
	!!<x11-themes/fluxbox-styles-fluxmod-20040809-r1
	!!<=x11-misc/fluxconf-0.9.9
	!!<=x11-misc/fbdesk-1.2.1"
DEPEND="nls? ( sys-devel/gettext )
	x11-proto/xextproto
	xinerama? ( x11-proto/xineramaproto )
	${RDEPEND}"
PROVIDE="virtual/blackbox"

SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux"

src_prepare() {
	# We need to be able to include directories rather than just plain
	# files in menu [include] items. This patch will allow us to do clever
	# things with style ebuilds.
	epatch "${FILESDIR}/gentoo_style_location-1.1.x.patch"
	eprefixify util/fluxbox-generate_menu.in

	epatch "${FILESDIR}"/${P}-osx-has-otool.patch

	# Add in the Gentoo -r number to fluxbox -version output.
	if [[ "${PR}" == "r0" ]] ; then
		suffix="gentoo"
	else
		suffix="gentoo-${PR}"
	fi
	sed -i \
		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
		version.h.in || die "version sed failed"
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable xinerama) \
		$(use_enable truetype xft) \
		$(use_enable gnome) \
		$(use_enable imlib imlib2) \
		$(use_enable bidi fribidi ) \
		$(use_enable slit ) \
		$(use_enable toolbar ) \
		--sysconfdir="${EPREFIX}"/etc/X11/${PN} \
		--with-style="${EPREFIX}"/usr/share/fluxbox/styles/Emerge \
		${myconf}
}

src_compile() {
	default

	ebegin "Creating a menu file (may take a while)"
	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
		CHECKINIT="no. go away." HOME="${T}/home" \
		"${S}/util/fluxbox-generate_menu" -is -ds \
		|| die "menu generation failed"
	eend $?
}

src_install() {
	dodir /usr/share/fluxbox
	emake DESTDIR="${D}" STRIP="" install || die "install failed"
	dodoc README* AUTHORS TODO* ChangeLog NEWS

	dodir /usr/share/xsessions
	insinto /usr/share/xsessions
	doins "${FILESDIR}/${PN}.desktop"

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}/${PN}.xsession" fluxbox

	dodir /usr/share/fluxbox/menu.d

	# Styles menu framework
	dodir /usr/share/fluxbox/menu.d/styles
	insinto /usr/share/fluxbox/menu.d/styles
	doins "${FILESDIR}/styles-menu-fluxbox" || die
	doins "${FILESDIR}/styles-menu-commonbox" || die
	doins "${FILESDIR}/styles-menu-user" || die
}