[gentoo-commits] gentoo-x86 commit in media-video/pitivi: ChangeLog pitivi-0.13.5.ebuild

[Arun Raghavan (ford_prefect)]

ford_prefect    11/01/31 06:12:00

  Modified:             ChangeLog
  Added:                pitivi-0.13.5.ebuild
  Log:
  Bump to 0.13.5. Lots of enhancements and bug fixes.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.22                 media-video/pitivi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	20 Mar 2010 12:41:32 -0000	1.21
+++ ChangeLog	31 Jan 2011 06:12:00 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/pitivi
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.21 2010/03/20 12:41:32 nirbheek Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.22 2011/01/31 06:12:00 ford_prefect Exp $
+
+*pitivi-0.13.5 (31 Jan 2011)
+
+  31 Jan 2011; Arun Raghavan <ford_prefect@g.o> +pitivi-0.13.5.ebuild,
+  +files/pitivi-0.13.5-work-with-old-good.patch:
+  Bump to 0.13.5. Lots of enhancements and bug fixes.
 
 *pitivi-0.13.4 (20 Mar 2010)
 



1.1                  media-video/pitivi/pitivi-0.13.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/pitivi-0.13.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/pitivi-0.13.5.ebuild?rev=1.1&content-type=text/plain

Index: pitivi-0.13.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/pitivi-0.13.5.ebuild,v 1.1 2011/01/31 06:12:00 ford_prefect Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit gnome2 python eutils virtualx

DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
HOMEPAGE="http://www.pitivi.org"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=dev-lang/python-2.5
	>=dev-python/pygtk-2.14.0
	dev-python/dbus-python
	>=dev-python/gconf-python-2.12
	dev-python/pycairo
	dev-python/pygoocanvas
	net-zope/zope-interface
	gnome-base/librsvg

	>=media-libs/gstreamer-0.10.28
	>=dev-python/gst-python-0.10.19
	>=media-libs/gnonlin-0.10.16
	>=media-libs/gst-plugins-base-0.10.0
	>=media-libs/gst-plugins-good-0.10.0
	>=media-plugins/gst-plugins-ffmpeg-0.10.0
	>=media-plugins/gst-plugins-xvideo-0.10.0
	>=media-plugins/gst-plugins-libpng-0.10.0"
DEPEND="${RDEPEND}
	dev-python/setuptools
	>=dev-util/intltool-0.35.5"

DOCS="AUTHORS ChangeLog NEWS RELEASE"

src_prepare() {
	gnome2_src_prepare

	epatch "${FILESDIR}/${P}-work-with-old-good.patch"

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile
}

src_configure() {
	addpredict $(unset HOME; echo ~)/.gconf
	addpredict $(unset HOME; echo ~)/.gconfd
	addpredict $(unset HOME; echo ~)/.gstreamer-0.10

	gnome2_src_configure
}

src_test() {
	export XDG_CONFIG_HOME="${WORKDIR}/.config"
	export XDG_DATA_HOME="${WORKDIR}/.local"
	# Force Xvfb to be used
	unset DISPLAY
	# pitivi/configure.py checks this in get_pixmap_dir()
	mkdir "${S}/.git"
	Xemake check || die "tests failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize "/usr/$(get_libdir)/${PN}/python/${PN}"
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup "/usr/$(get_libdir)/${PN}/python/${PN}"
}