[gentoo-commits] gentoo-x86 commit in net-mail/notmuch: ChangeLog notmuch-0.17.ebuild

[Amadeusz Zolnowski (aidecoe)]

aidecoe     14/01/02 19:43:36

  Modified:             ChangeLog
  Added:                notmuch-0.17.ebuild
  Log:
  Version bump.
  
  NEWS
  ~~~~
  (Extracted headlines from NEWS file. See it for details.)
  
  - Incompatible change in SHA1 computation for big-endian architectures.
  
  Command-Line Interface
  ----------------------
  
  - New options to better support handling duplicate messages
  - Improved `notmuch new` performance for unchanged folders
  - `notmuch reply --format=text` RFC 2047-encodes headers
  - `notmuch compact` command
  
  Emacs Interface
  ---------------
  
  - `notmuch-tree` (formerly `notmuch-pick`) has been added to mainline
  - Tagging threads in search is now race-free
  - `notmuch-hello` refreshes when switching to the buffer
  - Specific mini-buffer prompts for tagging operations
  - Built-in help improvements
  - Quote replies as they are displayed in show view
  - Fixed inconsistent use of configured search order
  - Common keymap for notmuch-wide bindings
  - The `notmuch-tag` function now requires a list of tag changes
  - Fixed `notmuch-reply` putting reply in primary selection
  - Fixed `notmuch-show` invisible part handling
  - Fixed `notmuch-show` attachment viewers and stderr
  - Fixed `notmuch-mua-reply` point placement when signature involved
  
  Vim Interface
  -------------
  
  - Composing new messages in the Vim interface (as opposed reply to existing
  messages)
  - Support for going straight to a search
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F0134531E1DBFAB5)

Revision  Changes    Path
1.84                 net-mail/notmuch/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	22 Sep 2013 06:51:11 -0000	1.83
+++ ChangeLog	2 Jan 2014 19:43:36 -0000	1.84
@@ -1,6 +1,49 @@
 # ChangeLog for net-mail/notmuch
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.83 2013/09/22 06:51:11 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.84 2014/01/02 19:43:36 aidecoe Exp $
+
+*notmuch-0.17 (02 Jan 2014)
+
+  02 Jan 2014; Amadeusz Żołnowski <aidecoe@g.o> +notmuch-0.17.ebuild:
+  Version bump.
+
+  NEWS
+  ~~~~
+  (Extracted headlines from NEWS file. See it for details.)
+
+  - Incompatible change in SHA1 computation for big-endian architectures.
+
+  Command-Line Interface
+  ----------------------
+
+  - New options to better support handling duplicate messages
+  - Improved `notmuch new` performance for unchanged folders
+  - `notmuch reply --format=text` RFC 2047-encodes headers
+  - `notmuch compact` command
+
+  Emacs Interface
+  ---------------
+
+  - `notmuch-tree` (formerly `notmuch-pick`) has been added to mainline
+  - Tagging threads in search is now race-free
+  - `notmuch-hello` refreshes when switching to the buffer
+  - Specific mini-buffer prompts for tagging operations
+  - Built-in help improvements
+  - Quote replies as they are displayed in show view
+  - Fixed inconsistent use of configured search order
+  - Common keymap for notmuch-wide bindings
+  - The `notmuch-tag` function now requires a list of tag changes
+  - Fixed `notmuch-reply` putting reply in primary selection
+  - Fixed `notmuch-show` invisible part handling
+  - Fixed `notmuch-show` attachment viewers and stderr
+  - Fixed `notmuch-mua-reply` point placement when signature involved
+
+  Vim Interface
+  -------------
+
+  - Composing new messages in the Vim interface (as opposed reply to existing
+  messages)
+  - Support for going straight to a search
 
   22 Sep 2013; Agostino Sarubbo <ago@g.o> notmuch-0.16-r1.ebuild:
   Stable for x86, wrt bug #484926



1.1                  net-mail/notmuch/notmuch-0.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.17.ebuild?rev=1.1&content-type=text/plain

Index: notmuch-0.17.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/notmuch-0.17.ebuild,v 1.1 2014/01/02 19:43:36 aidecoe Exp $

EAPI=5

DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit elisp-common eutils pax-utils distutils-r1

DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
HOMEPAGE="http://notmuchmail.org/"
SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="
	python? ( ${PYTHON_REQUIRED_USE} )
	test? ( crypt emacs python )
	"
IUSE="bash-completion crypt debug doc emacs mutt nmbug python test
	zsh-completion"

CDEPEND="
	>=dev-libs/glib-2.22
	>=dev-libs/gmime-2.6.7
	!=dev-libs/gmime-2.6.19
	<dev-libs/xapian-1.3
	sys-libs/talloc
	debug? ( dev-util/valgrind )
	emacs? ( >=virtual/emacs-23 )
	python? ( ${PYTHON_DEPS} )
	x86? ( >=dev-libs/xapian-1.2.7-r2 )
	"
DEPEND="${CDEPEND}
	virtual/pkgconfig
	doc? ( python? ( dev-python/sphinx[${PYTHON_USEDEP}] ) )
	test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
		>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb )
	"
RDEPEND="${CDEPEND}
	crypt? ( app-crypt/gnupg )
	nmbug? ( dev-vcs/git virtual/perl-File-Temp virtual/perl-PodParser )
	mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
		dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
		virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
		virtual/perl-PodParser
		)
	zsh-completion? ( app-shells/zsh )
	"

DOCS=( AUTHORS NEWS README )
SITEFILE="50${PN}-gentoo.el"
MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"

bindings() {
	local ret=0

	if use $1; then
		pushd bindings/$1 || die
		shift
		"$@"
		ret=$?
		popd || die
	fi

	return $ret
}

pkg_setup() {
	if use emacs; then
		elisp-need-emacs 23 || die "Emacs version too low"
	fi
}

src_prepare() {
	default
	bindings python distutils-r1_src_prepare
	bindings python mv README README-python || die
	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
}

src_configure() {
	local myeconfargs=(
		--bashcompletiondir="${ROOT}/usr/share/bash-completion"
		--emacslispdir="${ROOT}/${SITELISP}/${PN}"
		--emacsetcdir="${ROOT}/${SITEETC}/${PN}"
		--with-gmime-version=2.6
		--zshcompletiondir="${ROOT}/usr/share/zsh/site-functions"
		$(use_with bash-completion)
		$(use_with emacs)
		$(use_with zsh-completion)
	)
	econf "${myeconfargs[@]}"
}

src_compile() {
	default
	bindings python distutils-r1_src_compile

	if use mutt; then
		pushd contrib/notmuch-mutt || die
		emake notmuch-mutt.1
		popd || die
	fi

	if use doc; then
		pydocs() {
			pushd docs || die
			emake html
			mv html ../python || die
			popd || die
		}
		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
	fi
}

src_test() {
	pax-mark -m notmuch
	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" default
	pax-mark -ze notmuch
}

src_install() {
	default

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	fi

	if use nmbug; then
		dobin devel/nmbug/nmbug
	fi

	if use mutt; then
		[[ -e /etc/mutt/notmuch-mutt.rc ]] && NOTMUCH_MUTT_RC_EXISTS=1
		pushd contrib/notmuch-mutt || die
		dobin notmuch-mutt
		doman notmuch-mutt.1
		insinto /etc/mutt
		doins notmuch-mutt.rc
		dodoc README-mutt
		popd || die
	fi

	DOCS="" bindings python distutils-r1_src_install
	use doc && bindings python dohtml -r python
}

pkg_postinst() {
	use emacs && elisp-site-regen

	if use mutt && [[ ! ${NOTMUCH_MUTT_RC_EXISTS} ]]; then
		elog "To enable notmuch support in mutt, add the following line into"
		elog "your mutt config file, please:"
		elog ""
		elog "  source /etc/mutt/notmuch-mutt.rc"
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
}