[gentoo-commits] gentoo-x86 commit in net-dns/mydns: metadata.xml ChangeLog mydns-1.2.8.27.ebuild

[Matsuu Takuto (matsuu)]

matsuu      10/11/05 12:20:35

  Modified:             metadata.xml ChangeLog
  Added:                mydns-1.2.8.27.ebuild
  Log:
  Version bumped, bug #267587.
  
  (Portage version: 2.1.9.22/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-dns/mydns/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/mydns/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	15 May 2007 13:55:25 -0000	1.2
+++ metadata.xml	5 Nov 2010 12:20:35 -0000	1.3
@@ -6,4 +6,8 @@
   <email>matsuu@g.o</email>
   <name>MATSUU Takuto</name>
 </maintainer>
+<use>
+  <flag name='alias'>Enable David Phillips aliasing</flag>
+  <flag name='status'>Enable the STATUS opcode to check server status</flag>
+</use>
 </pkgmetadata>



1.35                 net-dns/mydns/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/mydns/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	17 Jun 2010 21:47:22 -0000	1.34
+++ ChangeLog	5 Nov 2010 12:20:35 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for net-dns/mydns
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/mydns/ChangeLog,v 1.34 2010/06/17 21:47:22 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/mydns/ChangeLog,v 1.35 2010/11/05 12:20:35 matsuu Exp $
+
+*mydns-1.2.8.27 (04 Nov 2010)
+
+  04 Nov 2010; MATSUU Takuto <matsuu@g.o> +mydns-1.2.8.27.ebuild:
+  Version bumped, bug #267587.
 
   17 Jun 2010; Patrick Lauer <patrick@g.o> mydns-1.1.0-r1.ebuild,
   mydns-1.1.0-r2.ebuild:



1.1                  net-dns/mydns/mydns-1.2.8.27.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/mydns-1.2.8.27.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/mydns/mydns-1.2.8.27.ebuild?rev=1.1&content-type=text/plain

Index: mydns-1.2.8.27.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/mydns/mydns-1.2.8.27.ebuild,v 1.1 2010/11/05 12:20:35 matsuu Exp $

EAPI="3"
inherit autotools confutils eutils

DESCRIPTION="A DNS-Server which gets its data from a MySQL-/PostgreSQL-database"
HOMEPAGE="http://www.mydns.pl/"
SRC_URI="mirror://sourceforge/mydns-ng/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86"
IUSE="alias debug nls mysql postgres ssl static status zlib"

RDEPEND="mysql? ( virtual/mysql )
	nls? ( virtual/libintl )
	postgres? ( dev-db/postgresql-base )
	ssl? ( dev-libs/openssl )
	zlib? ( sys-libs/zlib )
	virtual/libiconv"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	sys-devel/bison"

S="${WORKDIR}/${P%.*}"

pkg_setup() {
	confutils_require_one mysql postgres
}

src_prepare() {
	epatch \
		"${FILESDIR}/${PN}-1.1.0-m4.patch" \
		"${FILESDIR}/04-update-smash-fix.dpatch" \
		"${FILESDIR}/${PN}-1.1.0-gentoo.patch"
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable alias) \
		$(use_enable nls) \
		$(use_enable debug) \
		$(use_with mysql) \
		$(use_with postgres pgsql) \
		$(use_enable static) \
		$(use_enable static static-build) \
		$(use_enable status) \
		$(use_with ssl openssl) \
		$(use_with zlib) \
		--without-included-gettext || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS BUGS ChangeLog NEWS README TODO contrib/admin.php contrib/stats.php contrib/create_domain.pl contrib/fix_rr_serial.pl contrib/MyDNS.pm contrib/README || die

	if use postgres; then
		sed -e 's/__db__/postgresql/g' "${FILESDIR}/mydns.rc6" > "${T}/mydns.rc6" || die
		dodoc QUICKSTART.postgres || die
	fi
	if use mysql; then
		sed -e 's/__db__/mysql/g' "${FILESDIR}/mydns.rc6" > "${T}/mydns.rc6" || die
		dodoc QUICKSTART.mysql README.mysql || die
	fi
	newinitd "${T}/mydns.rc6" mydns || die

	## Avoid file collision
	rm -f "${ED}/usr/share/locale/locale.alias"

	# Install config file
	insinto /etc
	newins mydns.conf mydns.conf || die
	fowners root:root /etc/mydns.conf || die
	fperms 0600 /etc/mydns.conf || die
}

pkg_postinst() {
	if use postgres; then
		elog "# createdb mydns"
		elog "# /usr/sbin/mydns --create-tables | psql mydns"
		elog
		elog "to create the tables in the PostgreSQL-Database."
		elog "For more info see QUICKSTART.postgres."
	fi
	if use mysql; then
		elog "# mysqladmin -u <useruname> -p create mydns"
		elog "# /usr/sbin/mydns --create-tables | mysql -u <username> -p mydns"
		elog
		elog "to create the tables in the MySQL-Database."
		elog "For more info see QUICKSTART.mysql."
	fi
	elog
}