[gentoo-commits] proj/gamerlay:master commit in: games-engines/wyrmgus/

[Azamat H. Hackimov]

commit:     ea4cbcdf6c197569a3cda46666b2ed484a2c4b7d
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Fri Feb  5 19:12:54 2021 +0000
Commit:     Azamat H. Hackimov <winterheart <AT> gentoo <DOT> ru>
CommitDate: Fri Feb  5 19:26:09 2021 +0000
URL:        https://gitweb.gentoo.org/proj/gamerlay.git/commit/?id=ea4cbcdf

games-engines/wyrmgus: update package

Migrate to EAPI=7, update ebuild

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>

 games-engines/wyrmgus/wyrmgus-2.7.1.ebuild | 81 ------------------------------
 games-engines/wyrmgus/wyrmgus-4.1.3.ebuild | 56 +++++++++++++++++++++
 2 files changed, 56 insertions(+), 81 deletions(-)

diff --git a/games-engines/wyrmgus/wyrmgus-2.7.1.ebuild b/games-engines/wyrmgus/wyrmgus-2.7.1.ebuild
deleted file mode 100644
index ff60484..0000000
--- a/games-engines/wyrmgus/wyrmgus-2.7.1.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit cmake-utils
-
-DESCRIPTION="Modified Stratagus engine for Wyrmsun"
-HOMEPAGE="https://andrettin.github.io/"
-SRC_URI="https://github.com/Andrettin/Wyrmgus/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug doc mikmod mng ogg opengl static theora"
-
-RDEPEND="dev-lang/lua:0
-	dev-lua/toluapp
-	media-libs/libpng:=
-	media-libs/libsdl
-	media-sound/fluidsynth
-	mikmod? ( media-sound/mikmod )
-	mng? (
-		static? ( media-libs/libmng[static-libs] )
-		!static? ( media-libs/libmng )
-	)
-	ogg? (
-		static? ( media-libs/libvorbis[static-libs] )
-		!static? ( media-libs/libvorbis )
-	)
-	theora? (
-		static? ( media-libs/libtheora[static-libs] )
-		!static? ( media-libs/libtheora )
-	)
-	static? (
-		dev-db/sqlite:3[static-libs]
-		dev-games/physfs[static-libs]
-		media-sound/oaml[static-libs]
-		sys-libs/zlib[static-libs]
-		x11-libs/libICE[static-libs]
-		x11-libs/libXext[static-libs]
-	)
-	!static? (
-		dev-games/physfs
-		dev-db/sqlite:3
-		media-sound/oaml
-		sys-libs/zlib
-		x11-libs/libICE
-		x11-libs/libXext
-	)
-"
-
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
-
-S="${WORKDIR}/${PN/w/W}-${PV}"
-
-src_prepare() {
-	sed -i 's#\(install(TARGETS stratagus DESTINATION \)${GAMEDIR})#\1${BINDIR})#' CMakeLists.txt
-	eapply_user
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DENABLE_STATIC=$(usex static)
-		-DENABLE_DOC=$(usex doc)
-		-DWITH_MIKMOD=$(usex mikmod)
-		-DWITH_MNG=$(usex mng)
-		-DWITH_OGGVORBIS=$(usex ogg)
-		-DWITH_THEORA=$(usex theora)
-		-DWITH_RENDERER=$(usex opengl OpenGL NativeSDL)
-		-DWITH_BZIP2=ON
-		-DWITH_FLUIDSYNTH=ON
-		-DWITH_PHYSFS=ON
-	)
-	cmake-utils_src_configure
-}
-
-src_install() {
-	newbin "${BUILD_DIR}/stratagus" wyrmgus
-}

diff --git a/games-engines/wyrmgus/wyrmgus-4.1.3.ebuild b/games-engines/wyrmgus/wyrmgus-4.1.3.ebuild
new file mode 100644
index 0000000..ab5d989
--- /dev/null
+++ b/games-engines/wyrmgus/wyrmgus-4.1.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 )
+
+inherit cmake lua-single
+
+DESCRIPTION="Modified Stratagus engine for Wyrmsun"
+HOMEPAGE="https://andrettin.github.io/"
+SRC_URI="https://github.com/Andrettin/Wyrmgus/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bzip2 doc opengl X"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	bzip2? ( app-arch/bzip2:= )
+	opengl? ( virtual/opengl )
+	X? ( x11-libs/libX11 )
+	dev-libs/boost:=
+	dev-lua/toluapp
+	dev-qt/qtcore
+	dev-qt/qtgui
+	dev-qt/qtlocation
+	dev-qt/qtmultimedia
+	dev-qt/qtwidgets
+	media-libs/libsdl
+	media-libs/sdl-mixer
+	sys-libs/zlib
+"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/Wyrmgus-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOC=$(usex doc)
+		-DWITH_RENDERER=$(usex opengl OpenGL NativeSDL)
+		-DWITH_BZIP2=$(usex bzip2)
+		-DWITH_X11=$(usex X)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}/wyrmgus"
+	dodoc README.MD
+}