[gentoo-commits] gentoo-x86 commit in sys-fs/udisks: udisks-1.0.2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    10/12/02 15:39:13

  Modified:             ChangeLog
  Added:                udisks-1.0.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 sys-fs/udisks/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	29 Oct 2010 06:24:18 -0000	1.22
+++ ChangeLog	2 Dec 2010 15:39:13 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/udisks
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.22 2010/10/29 06:24:18 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.23 2010/12/02 15:39:13 ssuominen Exp $
+
+*udisks-1.0.2 (02 Dec 2010)
+
+  02 Dec 2010; Samuli Suominen <ssuominen@g.o> +udisks-1.0.2.ebuild:
+  Version bump.
 
   29 Oct 2010; Jeroen Roovers <jer@g.o> udisks-1.0.1-r1.ebuild:
   Stable for HPPA (bug #329621).



1.1                  sys-fs/udisks/udisks-1.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.0.2.ebuild?rev=1.1&content-type=text/plain

Index: udisks-1.0.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/udisks-1.0.2.ebuild,v 1.1 2010/12/02 15:39:13 ssuominen Exp $

EAPI=3
inherit eutils bash-completion linux-info

DESCRIPTION="Daemon providing interfaces to work with storage devices"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/udisks"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug doc nls remote-access"

COMMON_DEPEND=">=sys-fs/udev-147[extras]
	>=dev-libs/glib-2.16.1:2
	>=sys-apps/dbus-1.4.0
	>=dev-libs/dbus-glib-0.92
	>=sys-auth/polkit-0.97
	>=sys-block/parted-1.8.8[device-mapper]
	>=sys-fs/lvm2-2.02.66
	>=dev-libs/libatasmart-0.14
	>=sys-apps/sg3_utils-1.27.20090411
	!sys-apps/devicekit-disks"
RDEPEND="${COMMON_DEPEND}
	virtual/eject
	remote-access? ( net-dns/avahi )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	doc? ( dev-util/gtk-doc
		app-text/docbook-xml-dtd:4.1.2 )
	nls? ( >=dev-util/intltool-0.40.0 )"

RESTRICT="test" # this would need running dbus and sudo available

pkg_setup() {
	if use amd64 || use x86; then
		CONFIG_CHECK="~USB_SUSPEND ~!IDE"
		linux-info_pkg_setup
	fi
}

src_configure() {
	econf \
		--localstatedir="${EPREFIX}"/var \
		--disable-dependency-tracking \
		--disable-static \
		$(use_enable debug verbose-mode) \
		--enable-man-pages \
		$(use_enable doc gtk-doc) \
		$(use_enable remote-access) \
		$(use_enable nls) \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS HACKING NEWS README

	rm -f "${ED}"/etc/profile.d/udisks-bash-completion.sh
	dobashcompletion tools/udisks-bash-completion.sh ${PN}

	find "${ED}" -name '*.la' -exec rm -f '{}' +
	keepdir /media
}