[gentoo-commits] repo/gentoo:master commit in: sci-geosciences/qgis/

[Andreas Sturmlechner]

commit:     d2416a856e16ae2671ae10a0e716588959727e98
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 17 20:04:43 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Sep 17 21:24:58 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2416a85

sci-geosciences/qgis: Drop 3.2.1

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 sci-geosciences/qgis/Manifest          |   1 -
 sci-geosciences/qgis/qgis-3.2.1.ebuild | 220 ---------------------------------
 2 files changed, 221 deletions(-)

diff --git a/sci-geosciences/qgis/Manifest b/sci-geosciences/qgis/Manifest
index 4383dfbacdc..8ad97a048eb 100644
--- a/sci-geosciences/qgis/Manifest
+++ b/sci-geosciences/qgis/Manifest
@@ -1,5 +1,4 @@
 DIST qgis-3.0.3.tar.bz2 94462631 BLAKE2B 047f4d8852b7572dc94b9c04ec9c81e53bab2ed63a7a490682b7c557ae1b21fcc3257e751cc794d368dc4124c20c008ffdc7f1f4b79af2faea78774dc6ef430c SHA512 67f46f1acacd6688984b0c13aa5880e2f31d85b5a28ebf12830d33f198c2e5983887a8c85036b8be59edf3836ba7d38985f58433f53d3164c2ffb4a6db94d046
-DIST qgis-3.2.1.tar.bz2 72064255 BLAKE2B 7811726c3c8e84e9d2e0f2cd500d3373895bd2f91b093943d451f65de5d722ae986df59754f6d1ca6bb1a0597a841c568b40113498cb9ef707c878184387fe44 SHA512 737aa95f71661c4b2738a9db8fea49ce21f04a94768130f33b063dbca17f04119a74508211257510196b239d3acc9019e17478820534a4353519f91fbb0bc27f
 DIST qgis-3.2.2.tar.bz2 71947443 BLAKE2B a6fc159ce6d90f4273483159831c9b89db40c3bd5fb34ec90d799978aae11a609509d5fd5189dc1edfb9fb72cd9ccd9298414d024db3c43561ea096774b7be17 SHA512 d19d44f71285e1d8a1d365a406550c68cd48215c7f9f67a979052f1f115d636c66c6a291e1a108b19a641f357b27e104ac642158f375fb631c141e844f468949
 DIST qgis-3.2.3.tar.bz2 71991789 BLAKE2B 656c0304cfc32d619a72f08185f76cf02aed7336fac8a4bf928c7f8b0e00df2e995e891a7ba757d8ce6acb5892c5c7425765608ee0441fa7eae8070a828734d4 SHA512 3366fce6232dd1b7657c0693debf742309d5594c7875017f464efd33e63bd4116eb062a0ebeb5b3108572a9658c3fb7d729e5a5db8fefb3ceae490ef1ec6bd22
 DIST qgis_sample_data-2.8.14.tar.gz 22119181 BLAKE2B 2d0565e91ec8119382bc9ab8e262dc04227fe8289146794891759ff5a32012245270614ba1119a6329fc45cf56852830c2079589309aa3467873f71f5c608eac SHA512 6b2653d5b57ffc2c2317639dac212429840984ac917ca3e452b39aabb99ea106d1a77c1c1dd967244ef16ede9deae751b170affdf08b72239eafed5b8977da3d

diff --git a/sci-geosciences/qgis/qgis-3.2.1.ebuild b/sci-geosciences/qgis/qgis-3.2.1.ebuild
deleted file mode 100644
index d5ad55122d0..00000000000
--- a/sci-geosciences/qgis/qgis-3.2.1.ebuild
+++ /dev/null
@@ -1,220 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python3_{5,6} )
-PYTHON_REQ_USE="sqlite"
-QT_MIN_VER="5.9.4"
-
-if [[ ${PV} != *9999 ]]; then
-	SRC_URI="https://qgis.org/downloads/${P}.tar.bz2
-		examples? ( https://qgis.org/downloads/data/qgis_sample_data.tar.gz -> qgis_sample_data-2.8.14.tar.gz )"
-	KEYWORDS="~amd64 ~x86"
-else
-	GIT_ECLASS="git-r3"
-	EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
-fi
-inherit cmake-utils eutils ${GIT_ECLASS} gnome2-utils python-single-r1 qmake-utils xdg-utils
-unset GIT_ECLASS
-
-DESCRIPTION="User friendly Geographic Information System"
-HOMEPAGE="https://www.qgis.org/"
-
-LICENSE="GPL-2+ GPL-3+"
-SLOT="0"
-IUSE="3d examples georeferencer grass mapserver oracle polar postgres python +webkit"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE} mapserver? ( python )"
-
-COMMON_DEPEND="
-	app-crypt/qca:2[qt5(+),ssl]
-	>=dev-db/spatialite-4.2.0
-	dev-db/sqlite:3
-	dev-libs/expat
-	dev-libs/libzip:=
-	dev-libs/qtkeychain[qt5(+)]
-	>=dev-qt/designer-${QT_MIN_VER}:5
-	>=dev-qt/qtconcurrent-${QT_MIN_VER}:5
-	>=dev-qt/qtcore-${QT_MIN_VER}:5
-	>=dev-qt/qtgui-${QT_MIN_VER}:5
-	>=dev-qt/qtnetwork-${QT_MIN_VER}:5[ssl]
-	>=dev-qt/qtpositioning-${QT_MIN_VER}:5
-	>=dev-qt/qtprintsupport-${QT_MIN_VER}:5
-	>=dev-qt/qtsvg-${QT_MIN_VER}:5
-	>=dev-qt/qtsql-${QT_MIN_VER}:5
-	>=dev-qt/qtwidgets-${QT_MIN_VER}:5
-	>=dev-qt/qtxml-${QT_MIN_VER}:5
-	>=sci-libs/gdal-2.2.3:=[geos]
-	sci-libs/geos
-	sci-libs/libspatialindex:=
-	sci-libs/proj
-	>=x11-libs/qscintilla-2.10.1:=[qt5(+)]
-	>=x11-libs/qwt-6.1.2:6=[qt5(+),svg]
-	3d? ( >=dev-qt/qt3d-${QT_MIN_VER}:5 )
-	georeferencer? ( sci-libs/gsl:= )
-	grass? ( =sci-geosciences/grass-7*:= )
-	mapserver? ( dev-libs/fcgi )
-	oracle? (
-		dev-db/oracle-instantclient:=
-		sci-libs/gdal:=[oracle]
-	)
-	polar? ( >=x11-libs/qwtpolar-1.1.1-r1[qt5(+)] )
-	postgres? ( dev-db/postgresql:= )
-	python? (
-		${PYTHON_DEPS}
-		dev-python/future[${PYTHON_USEDEP}]
-		dev-python/httplib2[${PYTHON_USEDEP}]
-		dev-python/jinja[${PYTHON_USEDEP}]
-		dev-python/markupsafe[${PYTHON_USEDEP}]
-		dev-python/owslib[${PYTHON_USEDEP}]
-		dev-python/pygments[${PYTHON_USEDEP}]
-		dev-python/PyQt5[designer,network,sql,svg,webkit?,${PYTHON_USEDEP}]
-		dev-python/python-dateutil[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		>=dev-python/qscintilla-python-2.10.1[qt5(+),${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/sip:=[${PYTHON_USEDEP}]
-		dev-python/six[${PYTHON_USEDEP}]
-		>=sci-libs/gdal-2.2.3[python,${PYTHON_USEDEP}]
-		postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
-	)
-	webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-qt/linguist-tools-${QT_MIN_VER}:5
-	>=dev-qt/qttest-${QT_MIN_VER}:5
-	>=dev-qt/qtxmlpatterns-${QT_MIN_VER}:5
-	sys-devel/bison
-	sys-devel/flex
-	python? ( ${PYTHON_DEPS} )
-"
-RDEPEND="${COMMON_DEPEND}
-	sci-geosciences/gpsbabel
-"
-
-# Disabling test suite because upstream disallow running from install path
-RESTRICT="test"
-
-PATCHES=(
-	# git master
-	"${FILESDIR}/${PN}-2.18.12-cmake-lib-suffix.patch"
-	"${FILESDIR}/${P}-qtwebkit-optional.patch" # bug 663394
-)
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	cmake-utils_src_prepare
-
-	sed -e "s:\${QT_BINARY_DIR}:$(qt5_get_bindir):" \
-		-i CMakeLists.txt || die "Failed to fix lrelease path"
-
-	sed -e "/QT_LRELEASE_EXECUTABLE/d" \
-		-e "/QT_LUPDATE_EXECUTABLE/s/set/find_program/" \
-		-e "s:lupdate-qt5:NAMES lupdate PATHS $(qt5_get_bindir) NO_DEFAULT_PATH:" \
-		-i cmake/modules/ECMQt4To5Porting.cmake || die "Failed to fix ECMQt4To5Porting.cmake"
-
-	cd src/plugins || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DQGIS_MANUAL_SUBDIR=/share/man/
-		-DBUILD_SHARED_LIBS=ON
-		-DQGIS_LIB_SUBDIR=$(get_libdir)
-		-DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis
-		-DQWT_INCLUDE_DIR=/usr/include/qwt6
-		-DQWT_LIBRARY=/usr/$(get_libdir)/libqwt6-qt5.so
-		-DPEDANTIC=OFF
-		-DWITH_APIDOC=OFF
-		-DWITH_QSPATIALITE=ON
-		-DENABLE_TESTS=OFF
-		-DWITH_3D=$(usex 3d)
-		-DWITH_GEOREFERENCER=$(usex georeferencer)
-		-DWITH_GRASS7=$(usex grass)
-		-DWITH_SERVER=$(usex mapserver)
-		-DWITH_ORACLE=$(usex oracle)
-		-DWITH_QWTPOLAR=$(usex polar)
-		-DWITH_POSTGRESQL=$(usex postgres)
-		-DWITH_BINDINGS=$(usex python)
-		-DWITH_CUSTOM_WIDGETS=$(usex python)
-		-DWITH_QTWEBKIT=$(usex webkit)
-	)
-
-	if use grass; then
-		mycmakeargs+=(
-			-DGRASS_PREFIX7=/usr/$(get_libdir)/grass70
-		)
-	fi
-
-	use python && mycmakeargs+=( -DBINDINGS_GLOBAL_INSTALL=ON )
-
-	# bugs 612956, 648726
-	addpredict /dev/dri/renderD128
-	addpredict /dev/dri/renderD129
-
-	cmake-utils_src_configure
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	domenu debian/qgis.desktop
-
-	local size type
-	for size in 16 22 24 32 48 64 96 128 256; do
-		newicon -s ${size} debian/icons/${PN}-icon${size}x${size}.png ${PN}.png
-		newicon -c mimetypes -s ${size} debian/icons/${PN}-mime-icon${size}x${size}.png ${PN}-mime.png
-		for type in qgs qml qlr qpt; do
-			newicon -c mimetypes -s ${size} debian/icons/${PN}-${type}${size}x${size}.png ${PN}-${type}.png
-		done
-	done
-	newicon -s scalable images/icons/qgis_icon.svg qgis.svg
-
-	insinto /usr/share/mime/packages
-	doins debian/qgis.xml
-
-	if use examples; then
-		docinto examples
-		dodoc -r "${WORKDIR}"/qgis_sample_data/.
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-
-	if use python; then
-		python_optimize "${ED%/}"/usr/share/qgis/python
-	fi
-
-	if use grass; then
-		python_fix_shebang "${ED%/}"/usr/share/qgis/grass/scripts
-	fi
-}
-
-pkg_postinst() {
-	if use postgres; then
-		elog "If you don't intend to use an external PostGIS server"
-		elog "you should install:"
-		elog "   dev-db/postgis"
-	elif use python; then
-		elog "Support of PostgreSQL is disabled."
-		elog "But some installed python-plugins import the psycopg2 module."
-		elog "If you do not need these plugins just disable them"
-		elog "in the Plugins menu, else you need to set USE=\"postgres\""
-	fi
-	if has_version "<sci-geosciences/qgis-3"; then
-		elog "QGIS is now based on PyQt5. Old scripts may not work anymore."
-	fi
-
-	gnome2_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}