[gentoo-commits] gentoo-x86 commit in net-analyzer/mtr: mtr-9999.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         13/09/27 13:46:45

  Modified:             ChangeLog
  Added:                mtr-9999.ebuild
  Log:
  Live ebuild.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.148                net-analyzer/mtr/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/mtr/ChangeLog?rev=1.148&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/mtr/ChangeLog?rev=1.148&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/mtr/ChangeLog?r1=1.147&r2=1.148

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/mtr/ChangeLog,v
retrieving revision 1.147
retrieving revision 1.148
diff -u -r1.147 -r1.148
--- ChangeLog	7 Sep 2013 20:16:19 -0000	1.147
+++ ChangeLog	27 Sep 2013 13:46:45 -0000	1.148
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/mtr
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/ChangeLog,v 1.147 2013/09/07 20:16:19 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/ChangeLog,v 1.148 2013/09/27 13:46:45 jer Exp $
+
+*mtr-9999 (27 Sep 2013)
+
+  27 Sep 2013; Jeroen Roovers <jer@g.o> +mtr-9999.ebuild:
+  Live ebuild.
 
   07 Sep 2013; Agostino Sarubbo <ago@g.o> mtr-0.85.ebuild:
   Stable for sparc, wrt bug #482936



1.1                  net-analyzer/mtr/mtr-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/mtr/mtr-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/mtr/mtr-9999.ebuild?rev=1.1&content-type=text/plain

Index: mtr-9999.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/mtr-9999.ebuild,v 1.1 2013/09/27 13:46:45 jer Exp $

EAPI=5
inherit eutils autotools flag-o-matic git-r3

DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
HOMEPAGE="http://www.bitwizard.nl/mtr/"
EGIT_REPO_URI="https://github.com/traviscross/mtr.git"
SRC_URI="mirror://gentoo/gtk-2.0-for-mtr.m4.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="gtk ipv6 suid"

RDEPEND="
	sys-libs/ncurses
	gtk? (
		dev-libs/glib:2
		x11-libs/gtk+:2
	)
"
DEPEND="
	${RDEPEND}
	virtual/pkgconfig
"

DOCS=( AUTHORS FORMATS NEWS README SECURITY TODO )

src_unpack() {
	git-r3_src_unpack
	unpack ${A}
}

src_prepare() {
	epatch \
		"${FILESDIR}"/0.80-impl-dec.patch \
		"${FILESDIR}"/0.85-ipv6.patch \
		"${FILESDIR}"/0.85-gtk.patch

	sed -i -e '/^AC_INIT/s|\[[0-9.]*\]|['"${EGIT_VERSION}"']|g' configure.ac || die

	# Keep this comment and following mv, even in case ebuild does not need
	# it: kept gtk-2.0.m4 in SRC_URI but you'll have to mv it before autoreconf
	mv "${WORKDIR}"/gtk-2.0-for-mtr.m4 gtk-2.0.m4 || die #222909
	AT_M4DIR="." eautoreconf
}

src_configure() {
	# In the source's configure script -lresolv is commented out. Apparently it
	# is needed for 64bit macos still.
	[[ ${CHOST} == *-darwin* ]] && append-libs -lresolv
	econf \
		$(use_enable ipv6) \
		$(use_with gtk)

	# It's a bit absurd to have to do this, but the package isn't
	# actually "configured" and ready to be compiled until this is
	# done because upstream packaged .o files with the tarball.
	# Remember to take this out on future versions.
	emake clean
}

src_install() {
	default

	if use !prefix ; then
		fowners root:0 /usr/sbin/mtr
		if use suid; then
			fperms 4711 /usr/sbin/mtr
		else
			fperms 0710 /usr/sbin/mtr
		fi
	fi
}