[gentoo-commits] repo/gentoo:master commit in: games-fps/urbanterror-data/

[David Seifert]

commit:     8e0507c4843f7ac90c552dedb750ef369e85bb98
Author:     Nils Freydank <holgersson <AT> posteo <DOT> de>
AuthorDate: Tue Aug 22 15:13:41 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Wed Aug 30 06:26:09 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e0507c4

ygames-fps/urbanterror-data: Drop SVG image as license is unclear

Free license of the image source came from wikicommons, and only
one explicitly under GPL is in .ico format. Drop it to avoid
legal issues.

Package-Manager: Portage-2.3.8, Repoman-2.3.3
Closes: https://github.com/gentoo/gentoo/pull/5381

 .../urbanterror-data-4.3.2-r1.ebuild               | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/games-fps/urbanterror-data/urbanterror-data-4.3.2-r1.ebuild b/games-fps/urbanterror-data/urbanterror-data-4.3.2-r1.ebuild
new file mode 100644
index 00000000000..95dea99a4f6
--- /dev/null
+++ b/games-fps/urbanterror-data/urbanterror-data-4.3.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+inherit check-reqs eutils
+
+ENGINE_PV=${PV}
+
+MY_PN=UrbanTerror
+MY_PV=43_full
+
+DESCRIPTION="Data files for UrbanTerror"
+HOMEPAGE="http://www.urbanterror.info"
+SRC_URI="https://up.barbatos.fr/urt/${MY_PN}${MY_PV}.zip -> ${P}.zip"
+
+# fetch updates recursively for |4.3.x-4.3.0|
+if [[ "${PV}" != "4.3.0" ]]; then
+	MY_CTR=0
+	while [[ "${MY_CTR}" -lt "${PV/4.3./}" ]]; do
+		SRC_URI="${SRC_URI} https://up.barbatos.fr/urt/${MY_PN}-4.3.${MY_CTR}-to-4.3.$(( ${MY_CTR} + 1 )).zip -> ${PN}-4.3.${MY_CTR}-to-4.3.$(( ${MY_CTR} + 1 )).zip"
+		MY_CTR=$(( ${MY_CTR} + 1 ))
+	done
+fi
+unset MY_CTR
+
+LICENSE="Q3AEULA-20000111 urbanterror-4.2-maps"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+DEPEND="app-arch/unzip"
+
+S="${WORKDIR}/${MY_PN}43"
+
+CHECKREQS_DISK_BUILD="3300M"
+CHECKREQS_DISK_USR="1400M"
+
+src_prepare() {
+	default
+
+	# apply updates we fetched before
+	# again recursively for |4.3.x - 4.3.0|
+	local MY_CTR
+	if [[ "${PV}" != "4.3.0" ]]; then
+		MY_CTR=0
+		while [[ "${MY_CTR}" -lt "${PV/4.3./}" ]]; do
+			cp -dfpr \
+				"${WORKDIR}"/${MY_PN}-4.3.${MY_CTR}-to-4.3.$(( ${MY_CTR} + 1 ))/* "${S}"
+			MY_CTR=$(( ${MY_CTR} + 1 ))
+		done
+	fi
+}
+
+src_install() {
+	insinto /usr/share/urbanterror/q3ut4
+	doins q3ut4/*.pk3
+	# These files are *essential* for startup
+	newins q3ut4/server_example.cfg server.cfg
+	newins q3ut4/autoexec_example.cfg autoexec.cfg
+
+	dodoc q3ut4/readme43.txt
+	docinto examples
+	dodoc q3ut4/{server_example.cfg,mapcycle_example.txt}
+}