[gentoo-commits] repo/gentoo:master commit in: sys-cluster/pacemaker/

[Alexys Jacob]

commit:     43d97f36b607be3536627591c225a23e11a81215
Author:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
AuthorDate: Thu Oct 31 00:40:21 2019 +0000
Commit:     Alexys Jacob <ultrabug <AT> gentoo <DOT> org>
CommitDate: Fri Nov 15 21:52:45 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=43d97f36

sys-cluster/pacemaker: python compats, disable static lib

Since no other packages require the static libraries built
by pacemaker, I'll disable them as suggested by the links
below
https://flameeyes.blog/2011/08/29/useless-flag-static-libs/
https://archives.gentoo.org/gentoo-dev/message/2dada80c2b9c85b0e83e6328428bf8ab

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Alessandro Barbieri <lssndrbarbieri <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/13442
Signed-off-by: Alexys Jacob <ultrabug <AT> gentoo.org>

 sys-cluster/pacemaker/pacemaker-1.1.19-r1.ebuild | 80 ++++++++++++++++++++++++
 1 file changed, 80 insertions(+)

diff --git a/sys-cluster/pacemaker/pacemaker-1.1.19-r1.ebuild b/sys-cluster/pacemaker/pacemaker-1.1.19-r1.ebuild
new file mode 100644
index 00000000000..ed65ac8337a
--- /dev/null
+++ b/sys-cluster/pacemaker/pacemaker-1.1.19-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit autotools python-single-r1
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-${PV/_/-}"
+
+DESCRIPTION="Pacemaker CRM"
+HOMEPAGE="http://www.linux-ha.org/wiki/Pacemaker"
+SRC_URI="https://github.com/ClusterLabs/${PN}/archive/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="acl heartbeat smtp snmp"
+
+DEPEND="${PYTHON_DEPS}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	sys-cluster/cluster-glue
+	>=sys-cluster/libqb-0.14.0
+	sys-cluster/resource-agents
+
+	heartbeat?	( >=sys-cluster/heartbeat-3.0.0 )
+	!heartbeat?	( sys-cluster/corosync )
+	smtp?		( net-libs/libesmtp )
+	snmp?		( net-analyzer/net-snmp )
+"
+RDEPEND="${DEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S="${WORKDIR}/${PN}-${MY_P}"
+
+src_prepare() {
+	default
+	sed -i -e "s/ -ggdb//g" configure.ac || die
+	eautoreconf
+	python_fix_shebang .
+}
+
+src_configure() {
+	# appends lib to localstatedir automatically
+	local myconf=(
+		--libdir="/usr/$(get_libdir)"
+		--localstatedir=/var
+		--disable-dependency-tracking
+		--disable-fatal-warnings
+		--disable-static
+		--without-cs-quorum
+		--without-cman
+		$(use_with acl)
+		$(use_with heartbeat)
+		$(use_with smtp esmtp)
+		$(use_with snmp)
+	)
+
+	if use heartbeat ; then
+		myconf+=( --without-corosync )
+	else
+		myconf+=( --with-ais )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${D}/var/run" "${D}/etc/init.d"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}" || die
+	if has_version "<sys-cluster/corosync-2.0"; then
+		insinto /etc/corosync/service.d
+		newins "${FILESDIR}/${PN}.service" "${PN}" || die
+	fi
+	find "${D}" -name '*.la' -delete || die
+}