[gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-6.0.453.1.ebuild chromium-9999.ebuild chromium-6.0.437.1.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    10/07/03 09:34:47

  Modified:             ChangeLog chromium-9999.ebuild
  Added:                chromium-6.0.453.1.ebuild
  Removed:              chromium-6.0.437.1.ebuild
  Log:
  Version bump for dev channel release. Contains a workaround for bug #326609 by Aaron Haviland <orion@××××××.net>. Removed old ebuild.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.130                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.130&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.130&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.129&r2=1.130

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.129
retrieving revision 1.130
diff -u -r1.129 -r1.130
--- ChangeLog	3 Jul 2010 07:47:57 -0000	1.129
+++ ChangeLog	3 Jul 2010 09:34:47 -0000	1.130
@@ -1,6 +1,14 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.129 2010/07/03 07:47:57 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.130 2010/07/03 09:34:47 phajdan.jr Exp $
+
+*chromium-6.0.453.1 (03 Jul 2010)
+
+  03 Jul 2010; Pawel Hajdan jr <phajdan.jr@g.o>
+  -chromium-6.0.437.1.ebuild, +chromium-6.0.453.1.ebuild,
+  chromium-9999.ebuild:
+  Version bump for dev channel release. Contains a workaround for bug
+  #326609 by Aaron Haviland <orion@××××××.net>. Removed old ebuild.
 
 *chromium-5.0.375.99 (03 Jul 2010)
 



1.64                 www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.63&r2=1.64

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- chromium-9999.ebuild	23 Jun 2010 15:19:52 -0000	1.63
+++ chromium-9999.ebuild	3 Jul 2010 09:34:47 -0000	1.64
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.63 2010/06/23 15:19:52 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.64 2010/07/03 09:34:47 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -19,8 +19,6 @@
 
 RDEPEND="app-arch/bzip2
 	>=dev-libs/libevent-1.4.13
-	dev-libs/libxml2
-	dev-libs/libxslt
 	>=dev-libs/nss-3.12.3
 	>=gnome-base/gconf-2.24.0
 	>=media-libs/alsa-lib-1.0.19
@@ -91,6 +89,10 @@
 	elog "Installing/updating to version ${MAJOR}.${MINOR}.${BUILD}.${PATCH}_p${CREV} "
 }
 
+get_chromium_home() {
+	echo "/usr/$(get_libdir)/chromium-browser"
+}
+
 remove_bundled_lib() {
 	einfo "Removing bundled library $1 ..."
 	local out
@@ -106,27 +108,24 @@
 	remove_bundled_lib "third_party/libevent"
 	remove_bundled_lib "third_party/libjpeg"
 	remove_bundled_lib "third_party/libpng"
-	remove_bundled_lib "third_party/libxml"
-	remove_bundled_lib "third_party/libxslt"
+	# TODO: also remove third_party/libxml and third_party/libxslt when
+	# http://crbug.com/29333 is fixed.
 	# TODO: also remove third_party/zlib. For now the compilation fails if we
 	# remove it (minizip-related).
 }
 
 src_configure() {
-	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser
-
-	# Workaround for bug #318969.
-	# TODO: remove when http://crbug.com/43778 is fixed.
-	append-flags -D__STDC_CONSTANT_MACROS
-
 	local myconf=""
 
 	# Make it possible to build chromium on non-sse2 systems.
-	if ! use sse2; then
+	if use sse2; then
+		myconf="${myconf} -Ddisable_sse2=0"
+	else
 		myconf="${myconf} -Ddisable_sse2=1"
 	fi
 
 	# Use system-provided libraries.
+	# TODO: use_system_libxml (http://crbug.com/29333).
 	# TODO: use_system_sqlite (http://crbug.com/22208).
 	# TODO: use_system_icu, use_system_hunspell (upstream changes needed).
 	# TODO: use_system_ssl when we have a recent enough system NSS.
@@ -136,7 +135,6 @@
 		-Duse_system_libevent=1
 		-Duse_system_libjpeg=1
 		-Duse_system_libpng=1
-		-Duse_system_libxml=1
 		-Duse_system_zlib=1"
 
 	# The system-provided ffmpeg supports more codecs. Enable them in chromium.
@@ -151,8 +149,8 @@
 
 	# Enable sandbox.
 	myconf="${myconf}
-		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
-		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
+		-Dlinux_sandbox_path=$(get_chromium_home)/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=$(get_chromium_home)/chrome"
 
 	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
 	# and the performance gain isn't worth it.
@@ -204,21 +202,19 @@
 }
 
 src_install() {
-	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser
-
-	dodir ${CHROMIUM_HOME}
+	dodir "$(get_chromium_home)"
 
-	exeinto ${CHROMIUM_HOME}
+	exeinto "$(get_chromium_home)"
 	pax-mark m out/Release/chrome
 	doexe out/Release/chrome
 	doexe out/Release/chrome_sandbox
-	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox
+	fperms 4755 "$(get_chromium_home)/chrome_sandbox"
 	doexe out/Release/xdg-settings
 	doexe "${FILESDIR}"/chromium-launcher.sh
 
-	insinto ${CHROMIUM_HOME}
-	doins out/Release/chrome.pak
-	doins out/Release/resources.pak
+	insinto "$(get_chromium_home)"
+	doins out/Release/chrome.pak || die "installing chrome.pak failed"
+	doins out/Release/resources.pak || die "installing resources.pak failed"
 
 	doins -r out/Release/locales
 	doins -r out/Release/resources
@@ -229,16 +225,16 @@
 
 	# Chromium looks for these in its folder
 	# See media_posix.cc and base_paths_linux.cc
-	dosym /usr/$(get_libdir)/libavcodec.so.52 ${CHROMIUM_HOME}
-	dosym /usr/$(get_libdir)/libavformat.so.52 ${CHROMIUM_HOME}
-	dosym /usr/$(get_libdir)/libavutil.so.50 ${CHROMIUM_HOME}
+	dosym /usr/$(get_libdir)/libavcodec.so.52 "$(get_chromium_home)"
+	dosym /usr/$(get_libdir)/libavformat.so.52 "$(get_chromium_home)"
+	dosym /usr/$(get_libdir)/libavutil.so.50 "$(get_chromium_home)"
 
 	# Use system plugins by default.
-	dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/plugins
+	dosym /usr/$(get_libdir)/nsbrowser/plugins "$(get_chromium_home)/plugins"
 
 	# Install icon and desktop entry.
 	newicon out/Release/product_logo_48.png ${PN}-browser.png
-	dosym ${CHROMIUM_HOME}/chromium-launcher.sh /usr/bin/chromium
+	dosym "$(get_chromium_home)/chromium-launcher.sh" /usr/bin/chromium
 	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
 	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
 		|| die "desktop file sed failed"



1.1                  www-client/chromium/chromium-6.0.453.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-6.0.453.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-6.0.453.1.ebuild?rev=1.1&content-type=text/plain

Index: chromium-6.0.453.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-6.0.453.1.ebuild,v 1.1 2010/07/03 09:34:47 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib pax-utils toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="cups sse2"

RDEPEND="app-arch/bzip2
	>=dev-libs/libevent-1.4.13
	>=dev-libs/nss-3.12.3
	>=gnome-base/gconf-2.24.0
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg:0
	media-libs/libpng
	media-video/ffmpeg[threads]
	cups? ( >=net-print/cups-1.3.5 )
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	>=gnome-base/gnome-keyring-2.28.2
	sys-devel/flex"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-apps/xmessage
	x11-misc/xdg-utils
	virtual/ttf-fonts"

get_chromium_home() {
	echo "/usr/$(get_libdir)/chromium-browser"
}

remove_bundled_lib() {
	einfo "Removing bundled library $1 ..."
	local out
	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
		|| die "failed to remove bundled library $1"
	if [[ -z $out ]]; then
		die "no files matched when removing bundled library $1"
	fi
}

src_prepare() {
	# Disable VP8 until we have a recent enough system-provided ffmpeg.
	epatch "${FILESDIR}"/${PN}-disable-vp8-r1.patch

	remove_bundled_lib "third_party/bzip2"
	remove_bundled_lib "third_party/libevent"
	remove_bundled_lib "third_party/libjpeg"
	remove_bundled_lib "third_party/libpng"
	# TODO: also remove third_party/libxml and third_party/libxslt when
	# http://crbug.com/29333 is fixed.
	# TODO: also remove third_party/zlib. For now the compilation fails if we
	# remove it (minizip-related).
}

src_configure() {
	local myconf=""

	# Make it possible to build chromium on non-sse2 systems.
	if use sse2; then
		myconf="${myconf} -Ddisable_sse2=0"
	else
		myconf="${myconf} -Ddisable_sse2=1"
	fi

	# Use system-provided libraries.
	# TODO: use_system_libxml (http://crbug.com/29333).
	# TODO: use_system_sqlite (http://crbug.com/22208).
	# TODO: use_system_icu, use_system_hunspell (upstream changes needed).
	# TODO: use_system_ssl when we have a recent enough system NSS.
	myconf="${myconf}
		-Duse_system_bzip2=1
		-Duse_system_ffmpeg=1
		-Duse_system_libevent=1
		-Duse_system_libjpeg=1
		-Duse_system_libpng=1
		-Duse_system_zlib=1"

	# The system-provided ffmpeg supports more codecs. Enable them in chromium.
	myconf="${myconf} -Dproprietary_codecs=1"

	# The dependency on cups is optional, see bug #324105.
	if use cups; then
		myconf="${myconf} -Duse_cups=1"
	else
		myconf="${myconf} -Duse_cups=0"
	fi

	# Enable sandbox.
	myconf="${myconf}
		-Dlinux_sandbox_path=$(get_chromium_home)/chrome_sandbox
		-Dlinux_sandbox_chrome_path=$(get_chromium_home)/chrome"

	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
	# and the performance gain isn't worth it.
	myconf="${myconf} -Dv8_use_snapshot=0"

	# Disable tcmalloc memory allocator. It causes problems,
	# for example bug #320419.
	myconf="${myconf} -Dlinux_use_tcmalloc=0"

	# Disable gpu rendering, it is incompatible with nvidia-drivers,
	# bug #319331.
	myconf="${myconf} -Denable_gpu=0"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf="${myconf} -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf="${myconf} -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		append-flags -fno-tree-sink
		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf="${myconf} -Dwerror="

	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}

src_compile() {
	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
		rootdir="${S}" \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		AR=$(tc-getAR) \
		RANLIB=$(tc-getRANLIB) \
		|| die "compilation failed"
}

src_install() {
	dodir "$(get_chromium_home)"

	exeinto "$(get_chromium_home)"
	pax-mark m out/Release/chrome
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox
	fperms 4755 "$(get_chromium_home)/chrome_sandbox"
	doexe out/Release/xdg-settings
	doexe "${FILESDIR}"/chromium-launcher.sh

	insinto "$(get_chromium_home)"
	doins out/Release/chrome.pak || die "installing chrome.pak failed"
	doins out/Release/resources.pak || die "installing resources.pak failed"

	doins -r out/Release/locales
	doins -r out/Release/resources

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1
	newman out/Release/chrome.1 chromium.1

	# Chromium looks for these in its folder
	# See media_posix.cc and base_paths_linux.cc
	dosym /usr/$(get_libdir)/libavcodec.so.52 "$(get_chromium_home)"
	dosym /usr/$(get_libdir)/libavformat.so.52 "$(get_chromium_home)"
	dosym /usr/$(get_libdir)/libavutil.so.50 "$(get_chromium_home)"

	# Use system plugins by default.
	dosym /usr/$(get_libdir)/nsbrowser/plugins "$(get_chromium_home)/plugins"

	# Install icon and desktop entry.
	newicon out/Release/product_logo_48.png ${PN}-browser.png
	dosym "$(get_chromium_home)/chromium-launcher.sh" /usr/bin/chromium
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
		|| die "desktop file sed failed"

	# Install GNOME default application entry (bug #303100).
	dodir /usr/share/gnome-control-center/default-apps
	insinto /usr/share/gnome-control-center/default-apps
	doins "${FILESDIR}"/chromium.xml
}