[gentoo-commits] gentoo-x86 commit in mail-filter/postfwd: postfwd-1.35-r1.ebuild ChangeLog postfwd-1.35.ebuild

[Marc Schiffbauer (mschiff)]

mschiff     14/11/30 16:37:18

  Modified:             ChangeLog
  Added:                postfwd-1.35-r1.ebuild
  Removed:              postfwd-1.35.ebuild
  Log:
  Fixed typo in init script
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x296C6CCA35A64134)

Revision  Changes    Path
1.7                  mail-filter/postfwd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postfwd/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postfwd/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postfwd/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/postfwd/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	28 Nov 2014 20:52:14 -0000	1.6
+++ ChangeLog	30 Nov 2014 16:37:18 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/postfwd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/postfwd/ChangeLog,v 1.6 2014/11/28 20:52:14 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/postfwd/ChangeLog,v 1.7 2014/11/30 16:37:18 mschiff Exp $
+
+*postfwd-1.35-r1 (30 Nov 2014)
+
+  30 Nov 2014; Marc Schiffbauer <mschiff@g.o> +postfwd-1.35-r1.ebuild,
+  -postfwd-1.35.ebuild, files/postfwd.init:
+  Fixed typo in init script
 
   28 Nov 2014; Jeroen Roovers <jer@g.o> metadata.xml:
   Add proxy-maint.



1.1                  mail-filter/postfwd/postfwd-1.35-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postfwd/postfwd-1.35-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postfwd/postfwd-1.35-r1.ebuild?rev=1.1&content-type=text/plain

Index: postfwd-1.35-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/postfwd/postfwd-1.35-r1.ebuild,v 1.1 2014/11/30 16:37:18 mschiff Exp $

EAPI=4

inherit eutils user

DESCRIPTION="Versatile Postfix policy server with a flexible ruleset based configuration"
HOMEPAGE="http://www.postfwd.org/"
SRC_URI="http://www.postfwd.org/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+tools"

DEPEND=""
RDEPEND=">=dev-lang/perl-5.16.3
	virtual/perl-Sys-Syslog
	dev-perl/Net-DNS
	dev-perl/net-server
"

pkg_setup() {
	enewgroup postfwd
	enewuser postfwd -1 -1 -1 postfwd
}

src_install() {
	local BIN="postfwd2"
	# programs and tools
	dosbin "${S}"/sbin/${BIN}

	# man pages and documentation
	doman "${S}"/man/man8/${BIN}.8
	dodoc "${S}"/doc/{${BIN}.CHANGELOG,${BIN}.txt}

	# example configuration(s)
	insinto /usr/share/doc/${PF}/examples
	newins "${S}"/etc/${PN}.cf.sample ${PN}.cf.dist

	# plugins
	dodoc -r "${S}"/plugins

	# tools
	if use tools; then
		dodoc -r "${S}"/tools
	fi

	# init script and respective configuration file
	newinitd "${FILESDIR}"/${PN}.init ${PN}
	newconfd "${FILESDIR}"/${PN}.conf ${PN}
}

pkg_postinst() {
	einfo
	einfo "${PN} has no default configuration for safety reasons. Every"
	einfo "mail system is different, so you should craft a set of rules"
	einfo "that is suitable for your environment and save it to:"
	einfo "   /etc/postfix/postfwd.cf"
	einfo "You can find example configurations in:"
	einfo "   /usr/share/doc/${PF}/examples"
	einfo
	einfo "If you want ${PN} to start on system boot, you have to add it your"
	einfo "default run level:"
	einfo "   # rc-update add postfwd default"
	einfo "Also remember to edit /etc/conf.d/${PN} to your liking."
	einfo
	einfo "A plugins sampe folder has been placed under:"
	einfo
	einfo "   /usr/share/doc/${PF}/plugins"

	if use tools; then
		einfo
		einfo "You can find additional tools for testing ${PN} in:"
		einfo "   /usr/share/doc/${PF}/tools"
	fi

	ewarn
	ewarn "Please read the documentation carefully and properly test new"
	ewarn "rulesets before putting them into production use. Otherwise you"
	ewarn "risk accidental mail loss or worse."
	ewarn
	ewarn "Visit http://www.postfwd.org/ for more information."
	ewarn
}