[gentoo-commits] repo/gentoo:master commit in: dev-python/sunpy/

[Sebastien Fabbro]

commit:     b8f3583e8d65a71580a9a3324e9d05ddf388cb22
Author:     Sébastien Fabbro <bicatali <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 17 18:32:13 2017 +0000
Commit:     Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
CommitDate: Mon Jul 17 18:58:30 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b8f3583e

dev-python/sunpy: initial import

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 dev-python/sunpy/Manifest           |  1 +
 dev-python/sunpy/metadata.xml       | 18 +++++++++++++
 dev-python/sunpy/sunpy-0.7.8.ebuild | 51 +++++++++++++++++++++++++++++++++++++
 3 files changed, 70 insertions(+)

diff --git a/dev-python/sunpy/Manifest b/dev-python/sunpy/Manifest
new file mode 100644
index 00000000000..75530262ede
--- /dev/null
+++ b/dev-python/sunpy/Manifest
@@ -0,0 +1 @@
+DIST sunpy-0.7.8.tar.gz 5666138 SHA256 abb3238b4cfcc67bcb0e81733463e4abb672fc6e8c85684320d4ce552e587916 SHA512 46b493a823018b8500994cdfed8f8ae736ed471251a3b62d615821f8a9ea4228d2c78d7a9f66274fc49d0a386ad4d3d446547b8c06888157e5633fac844e8638 WHIRLPOOL 3939b14eb8452284cb435ace15d666962c801929c36c58748fed612b32cc9f2a7d172dfef588775bda3d21362c0a75be144490dbf89b90b6fe9e714de23d4c42

diff --git a/dev-python/sunpy/metadata.xml b/dev-python/sunpy/metadata.xml
new file mode 100644
index 00000000000..1915944eec8
--- /dev/null
+++ b/dev-python/sunpy/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@g.o</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    SunPy is a community-developed free and open-source software package for
+    solar physics. SunPy is meant to be a free alternative to the SolarSoft data
+    analysis environment. The aim of the SunPy project is to provide the
+    software tools necessary so that anyone can analyze solar data.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">sunpy</remote-id>
+    <remote-id type="github">sunpy/sunpy</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/dev-python/sunpy/sunpy-0.7.8.ebuild b/dev-python/sunpy/sunpy-0.7.8.ebuild
new file mode 100644
index 00000000000..9d1336d23d4
--- /dev/null
+++ b/dev-python/sunpy/sunpy-0.7.8.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Software library for solar physics based on Python"
+HOMEPAGE="http://sunpy.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="jpeg2k test"
+
+RDEPEND="
+	<dev-python/astropy-2[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/suds[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-libs/scikits_image[${PYTHON_USEDEP}]
+	jpeg2k? ( dev-python/glymur[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mpl[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" -m pytest sunpy -k "not figure and not online" || die
+}