[gentoo-commits] repo/gentoo:master commit in: dev-java/jmi-interface/

[Patrice Clement]

commit:     59e9f97681c3d3333e37fbcbdb4d62ebaf9dea23
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  2 21:45:49 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Sat Apr  2 21:46:07 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59e9f976

dev-java/jmi-interface: EAPI 5 bump. Switch to java-pkg-simple.

Package-Manager: portage-2.2.26

 dev-java/jmi-interface/jmi-interface-1.0-r4.ebuild | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-java/jmi-interface/jmi-interface-1.0-r4.ebuild b/dev-java/jmi-interface/jmi-interface-1.0-r4.ebuild
new file mode 100644
index 0000000..c3422cf
--- /dev/null
+++ b/dev-java/jmi-interface/jmi-interface-1.0-r4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+JMI_ZIP="jmi-${PV/./_}-fr-interfaces.zip"
+MOF_XML="mof-${PV}.xml.bz2"
+
+DESCRIPTION="Java Metadata Interface Sample Class Interface"
+HOMEPAGE="http://java.sun.com/products/jmi/"
+SRC_URI="mirror://gentoo/${JMI_ZIP}
+		 mirror://gentoo/${MOF_XML}"
+
+LICENSE="sun-bcla-jmi"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+
+CDEPEND="dev-java/ant-core:0"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6
+	source? ( app-arch/zip )"
+
+JAVA_SRC_DIR="src"
+
+src_unpack() {
+	mkdir "${S}/src" || die
+	cd "${S}/src" || die
+	unpack ${JMI_ZIP}
+
+	# adding mof.xml required by Netbeans 
+	# #98603 and #162328
+	cd "${S}/src/javax/jmi/model" || die
+	unpack ${MOF_XML}
+	cp mof-1.0.xml mof.xml || die
+}
+
+java_prepare() {
+	# rename enum keywords because javadoc hates them
+	# even with -source 1.4, bummer
+	epatch "${FILESDIR}/${P}-enum.patch"
+}
+
+src_compile() {
+	java-pkg-simple_src_compile
+	java-pkg_addres "${PN}.jar" src -name "*.xml"
+}