[gentoo-commits] repo/gentoo:master commit in: app-mobilephone/sobexsrv/

[Andrew Savchenko]

commit:     f5d48e16d64ed36734a7aea566d5cb211a94b6b3
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  6 09:53:06 2020 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Sun Sep  6 09:56:55 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5d48e16

app-mobilephone/sobexsrv: ebuild fixes

- Migrate to GLEP 81
- Update to EAPI 7
- Drop USE=gtk as it requires python2-only dev-python/pygtk

Bug: https://bugs.gentoo.org/708178
Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 app-mobilephone/sobexsrv/sobexsrv-1.0.1-r3.ebuild | 72 +++++++++++++++++++++++
 1 file changed, 72 insertions(+)

diff --git a/app-mobilephone/sobexsrv/sobexsrv-1.0.1-r3.ebuild b/app-mobilephone/sobexsrv/sobexsrv-1.0.1-r3.ebuild
new file mode 100644
index 00000000000..e748963f7b5
--- /dev/null
+++ b/app-mobilephone/sobexsrv/sobexsrv-1.0.1-r3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_P="${P/_pre/pre}"
+
+DESCRIPTION="Scripting/Secure OBEX Server (for BlueZ Linux)"
+SRC_URI="http://www.mulliner.org/bluetooth/${MY_P}.tar.gz
+		 https://dev.gentoo.org/~joker/${P}-fix64.patch"
+HOMEPAGE="http://www.mulliner.org/bluetooth/sobexsrv.php"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND="
+	>=dev-libs/openobex-1.7.2-r1
+	net-wireless/bluez
+"
+RDEPEND="${DEPEND}
+	acct-user/sobexsrv
+	acct-group/sobexsrv
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${DISTDIR}/${P}"-fix64.patch
+	"${FILESDIR}/${P}"-openobex16.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e 's:/usr/man/man8:/usr/share/man/man8:' \
+		-e 's/install: all/install:/' \
+	    -i Makefile || die
+
+	sed -e 's/^CFLAGS =/CFLAGS +=/' \
+	    -e 's/^CC =/CC ?=/' \
+	    -e 's/$(CC) $(CFLAGS)/$(CC) $(LDFLAGS) $(CFLAGS)/' \
+	    -i src/Makefile || die
+}
+
+src_compile() {
+	tc-export CC
+	emake -C src
+}
+
+src_install() {
+	default
+	dodoc AUTHOR CONFIG SECURITY THANKS
+	rm "${D}/usr/bin/sobexsrv_handler" || die
+
+	newinitd "${FILESDIR}/init.d_sobexsrv" sobexsrv
+	newconfd "${FILESDIR}/conf.d_sobexsrv" sobexsrv
+}
+
+pkg_postinst() {
+	elog
+	elog "/usr/bin/sobexsrv is *NOT* installed set-uid root by"
+	elog "default. suid is required for the chroot option (-R)."
+	elog
+	elog "Execute the following commands to enable suid:"
+	elog
+	elog "chown root:sobexsrv /usr/bin/sobexsrv"
+	elog "chmod 4710 /usr/bin/sobexsrv"
+	elog
+}