[gentoo-commits] repo/gentoo:master commit in: app-metrics/consul_exporter/files/, app-metrics/consul_exporter/

[William Hubbs]

commit:     e4ec071de04483f6fdc6d1803a6fd5c0cead4b6f
Author:     William Hubbs <william.hubbs <AT> sony <DOT> com>
AuthorDate: Mon Apr 15 20:23:18 2019 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Mon Apr 15 20:26:22 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e4ec071d

app-metrics/consul_exporter: Prometheus exporter for consul metrics

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 app-metrics/consul_exporter/Manifest               |  1 +
 .../consul_exporter/consul_exporter-0.4.0.ebuild   | 52 ++++++++++++++++++++++
 .../consul_exporter/files/consul_exporter.confd    |  3 ++
 .../consul_exporter/files/consul_exporter.initd    | 15 +++++++
 app-metrics/consul_exporter/metadata.xml           |  8 ++++
 5 files changed, 79 insertions(+)

diff --git a/app-metrics/consul_exporter/Manifest b/app-metrics/consul_exporter/Manifest
new file mode 100644
index 00000000000..1cf6b3f6f0c
--- /dev/null
+++ b/app-metrics/consul_exporter/Manifest
@@ -0,0 +1 @@
+DIST consul_exporter-0.4.0.tar.gz 1107092 BLAKE2B 7f3d6ce797252e5895387d3bbd2a3ad41777bf4d98a4a7a4efc3e8caa0c71fd29be91675ae6fe304016f1cbf87ecf4ee3442b49d3bc08939d471326d4e5d4cd4 SHA512 faac0dfeec5b6fadf73ef68c0d24c059c89891918e498e145a50512b8c961764a02388b2bcce305e12ecf703fa76afdf5634b35aecbee0ac37926d78ce0b1e93

diff --git a/app-metrics/consul_exporter/consul_exporter-0.4.0.ebuild b/app-metrics/consul_exporter/consul_exporter-0.4.0.ebuild
new file mode 100644
index 00000000000..12823ba01c9
--- /dev/null
+++ b/app-metrics/consul_exporter/consul_exporter-0.4.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit user golang-build golang-vcs-snapshot
+
+EGO_PN="github.com/prometheus/consul_exporter"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+CONSUL_EXPORTER_COMMIT=75f02d8
+
+DESCRIPTION="Prometheus exporter for consul metrics"
+HOMEPAGE="https://github.com/prometheus/consul_exporter"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=">=dev-lang/go-1.11
+	dev-util/promu"
+
+RESTRICT="strip test"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${CONSUL_EXPORTER_COMMIT}/" \
+		-e "s/{{.Version}}/${PV}/" \
+		-e "s/-tags netgo/-mod vendor -tags netgo/" \
+		src/${EGO_PN}/.promu.yml || die "Sed failed"
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	GO111MODULE=on GOCACHE="${T}/go-cache" promu build -v || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin consul_exporter
+	dodoc {README,CONTRIBUTING}.md
+	popd || die
+	keepdir /var/log/consul_exporter
+	fowners ${PN}:${PN} /var/log/consul_exporter
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}

diff --git a/app-metrics/consul_exporter/files/consul_exporter.confd b/app-metrics/consul_exporter/files/consul_exporter.confd
new file mode 100644
index 00000000000..eb5fbdeb0cd
--- /dev/null
+++ b/app-metrics/consul_exporter/files/consul_exporter.confd
@@ -0,0 +1,3 @@
+# Please set the flags you wish to pass to consul_exporter in
+# command_args
+# command_args=""

diff --git a/app-metrics/consul_exporter/files/consul_exporter.initd b/app-metrics/consul_exporter/files/consul_exporter.initd
new file mode 100644
index 00000000000..dbbbfa9c247
--- /dev/null
+++ b/app-metrics/consul_exporter/files/consul_exporter.initd
@@ -0,0 +1,15 @@
+#!/sbin/openrc-run
+# Copyright 2016-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+description="Consul Exporter for Prometheus"
+command="/usr/bin/consul_exporter"
+command_background=true
+command_user="${RC_SVCNAME}:${RC_SVCNAME}"
+error_log=/var/log/consul_exporter/${RC_SVCNAME}.log
+output_log=/var/log/consul_exporter/${RC_SVCNAME}.log
+pidfile=/var/run/${RC_SVCNAME}.pid
+
+depend() {
+	after consul net
+}

diff --git a/app-metrics/consul_exporter/metadata.xml b/app-metrics/consul_exporter/metadata.xml
new file mode 100644
index 00000000000..c36c37139fa
--- /dev/null
+++ b/app-metrics/consul_exporter/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>williamh@g.o</email>
+		<name>William Hubbs</name>
+	</maintainer>
+</pkgmetadata>