[gentoo-commits] gentoo-x86 commit in gnome-extra/gdesklets-core: ChangeLog gdesklets-core-0.36.3-r1.ebuild gdesklets-core-0.36.3.ebuild

[Joe Sapp (nixphoeni)]

nixphoeni    11/01/29 02:38:25

  Modified:             ChangeLog
  Added:                gdesklets-core-0.36.3-r1.ebuild
  Removed:              gdesklets-core-0.36.3.ebuild
  Log:
  Adjusted deps mostly per bug #352926; removed unnecessary dodir statements
  
  (Portage version: 2.1.9.35/cvs/Linux x86_64)

Revision  Changes    Path
1.138                gnome-extra/gdesklets-core/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog?rev=1.138&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog?rev=1.138&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog?r1=1.137&r2=1.138

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog,v
retrieving revision 1.137
retrieving revision 1.138
diff -u -r1.137 -r1.138
--- ChangeLog	26 Jan 2011 02:17:47 -0000	1.137
+++ ChangeLog	29 Jan 2011 02:38:25 -0000	1.138
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gdesklets-core
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog,v 1.137 2011/01/26 02:17:47 nixphoeni Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog,v 1.138 2011/01/29 02:38:25 nixphoeni Exp $
+
+*gdesklets-core-0.36.3-r1 (29 Jan 2011)
+
+  29 Jan 2011; Joe Sapp <nixphoeni@g.o> -gdesklets-core-0.36.3.ebuild,
+  +gdesklets-core-0.36.3-r1.ebuild:
+  Adjusted deps mostly per bug #352926; removed unnecessary dodir statements
 
 *gdesklets-core-0.36.3 (26 Jan 2011)
 



1.1                  gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: gdesklets-core-0.36.3-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r1.ebuild,v 1.1 2011/01/29 02:38:25 nixphoeni Exp $

EAPI=2
# desklets don't run with USE=debug
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.4"

inherit gnome2 python eutils autotools multilib bash-completion

MY_PN="${PN/-core}"
MY_P="${MY_PN}-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="GNOME Desktop Applets: Core library for desktop applets"
SRC_URI="http://gdesklets.de/files/${MY_P}.tar.bz2"
HOMEPAGE="http://www.gdesklets.de"
LICENSE="GPL-2"

SLOT="0"
IUSE=""
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"

RDEPEND=">=dev-libs/glib-2.4
	>=gnome-base/librsvg-2.8
	>=gnome-base/libgtop-2.8.2
	>=dev-python/pygtk-2.10
	>=dev-python/libbonobo-python-2.6
	>=dev-python/gconf-python-2.6
	>=dev-python/pygobject-2.6
	>=dev-python/pyorbit-2.0.1
	|| ( >=dev-python/gnome-vfs-python-2.6 >=dev-python/libgnome-python-2.6 )
	>=dev-libs/expat-1.95.8
	>=dev-python/pyxml-0.8.3-r1"

DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/pkgconfig
	dev-util/intltool"

DOCS="AUTHORS ChangeLog NEWS README TODO"
CONVERT_SHEBANGS="ctrlinfo gdesklets gdesklets-daemon gdesklets-logview \
	gdesklets-shell test-control.py contrib/gdesklets-migration-tool"

pkg_setup() {

	python_set_active_version 2

}

src_prepare() {

	gnome2_src_prepare

	# Postpone pyc compiling until pkg_postinst
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile

	eautoreconf
	intltoolize --force || die

	python_convert_shebangs 2 ${CONVERT_SHEBANGS}

}

src_install() {

	gnome2_src_install

	# Install bash completion script
	BASHCOMPLETION_NAME="gDesklets" \
		dobashcompletion "contrib/bash/gdesklets"

	# Install the gdesklets-control-getid script
	insinto "/usr/$(get_libdir)/gdesklets"
	insopts -m0555
	doins "${FILESDIR}/gdesklets-control-getid"

}

pkg_postinst() {

	gnome2_pkg_postinst
	python_need_rebuild
	# Compile pyc files on target system
	python_mod_optimize "/usr/$(get_libdir)/gdesklets"

	echo
	elog "gDesklets Displays are required before the library"
	elog "will be usable.  Core Displays (Calendar, Clock, Quote-of-the-Day,"
	elog "and the 15pieces game) are already installed in"
	elog "           ${ROOT}usr/$(get_libdir)/gdesklets/Displays"
	elog "Additional Displays can be found in -"
	elog "           x11-plugins/desklet-* ,"
	elog "at http://www.gdesklets.de, or at http://archive.gdesklets.info"
	elog
	elog "Next you'll need to start gDesklets using"
	elog "           ${ROOT}usr/bin/gdesklets start"
	elog "If you're using GNOME this can be done conveniently through"
	elog "Applications->Accessories->gDesklets or automatically each login"
	elog "under System->Preferences->Sessions"
	elog
	elog "If you're updating from a version less than 0.35_rc1,"
	elog "you can migrate your desklet configurations by"
	elog "running"
	elog "           ${ROOT}usr/$(get_libdir)/gdesklets/contrib/gdesklets-migration-tool"
	elog "after the first time you run gDesklets"
	elog

	BASHCOMPLETION_NAME="gDesklets" bash-completion_pkg_postinst

}

pkg_postrm() {

	gnome2_pkg_postrm
	# Cleanup after our cavalier python compilation
	# The function takes care of ${ROOT} for us
	python_mod_cleanup "/usr/$(get_libdir)/gdesklets"

}