1 |
mgorny 13/10/02 09:11:49 |
2 |
|
3 |
Modified: systemd-9999-r1.ebuild ChangeLog |
4 |
Added: systemd-208.ebuild |
5 |
Log: |
6 |
Version bump. Fix linking issues, bug #479038. |
7 |
|
8 |
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!) |
9 |
|
10 |
Revision Changes Path |
11 |
1.19 sys-apps/systemd/systemd-9999-r1.ebuild |
12 |
|
13 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild?rev=1.19&view=markup |
14 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild?rev=1.19&content-type=text/plain |
15 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild?r1=1.18&r2=1.19 |
16 |
|
17 |
Index: systemd-9999-r1.ebuild |
18 |
=================================================================== |
19 |
RCS file: /var/cvsroot/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild,v |
20 |
retrieving revision 1.18 |
21 |
retrieving revision 1.19 |
22 |
diff -u -r1.18 -r1.19 |
23 |
--- systemd-9999-r1.ebuild 26 Sep 2013 19:46:56 -0000 1.18 |
24 |
+++ systemd-9999-r1.ebuild 2 Oct 2013 09:11:49 -0000 1.19 |
25 |
@@ -1,6 +1,6 @@ |
26 |
# Copyright 1999-2013 Gentoo Foundation |
27 |
# Distributed under the terms of the GNU General Public License v2 |
28 |
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild,v 1.18 2013/09/26 19:46:56 floppym Exp $ |
29 |
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd/systemd-9999-r1.ebuild,v 1.19 2013/10/02 09:11:49 mgorny Exp $ |
30 |
|
31 |
EAPI=5 |
32 |
|
33 |
@@ -23,7 +23,7 @@ |
34 |
SRC_URI="http://www.freedesktop.org/software/systemd/${P}.tar.xz" |
35 |
|
36 |
LICENSE="GPL-2 LGPL-2.1 MIT public-domain" |
37 |
-SLOT="0" |
38 |
+SLOT="0/1" |
39 |
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86" |
40 |
IUSE="acl audit cryptsetup doc +firmware-loader gcrypt gudev http introspection |
41 |
+kmod lzma openrc pam policykit python qrcode selinux tcpd test |
42 |
|
43 |
|
44 |
|
45 |
1.185 sys-apps/systemd/ChangeLog |
46 |
|
47 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/ChangeLog?rev=1.185&view=markup |
48 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/ChangeLog?rev=1.185&content-type=text/plain |
49 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/ChangeLog?r1=1.184&r2=1.185 |
50 |
|
51 |
Index: ChangeLog |
52 |
=================================================================== |
53 |
RCS file: /var/cvsroot/gentoo-x86/sys-apps/systemd/ChangeLog,v |
54 |
retrieving revision 1.184 |
55 |
retrieving revision 1.185 |
56 |
diff -u -r1.184 -r1.185 |
57 |
--- ChangeLog 29 Sep 2013 14:52:41 -0000 1.184 |
58 |
+++ ChangeLog 2 Oct 2013 09:11:49 -0000 1.185 |
59 |
@@ -1,6 +1,14 @@ |
60 |
# ChangeLog for sys-apps/systemd |
61 |
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2 |
62 |
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd/ChangeLog,v 1.184 2013/09/29 14:52:41 mgorny Exp $ |
63 |
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd/ChangeLog,v 1.185 2013/10/02 09:11:49 mgorny Exp $ |
64 |
+ |
65 |
+*systemd-208 (02 Oct 2013) |
66 |
+ |
67 |
+ 02 Oct 2013; Michał Górny <mgorny@g.o> |
68 |
+ +files/208-0001-Work-around-link-libsystemd-label-to-libsystemd-logi.patch, |
69 |
+ +files/208-0002-Update-Makefile.in.patch, +systemd-208.ebuild, |
70 |
+ systemd-9999-r1.ebuild: |
71 |
+ Version bump. Fix linking issues, bug #479038. |
72 |
|
73 |
29 Sep 2013; Michał Górny <mgorny@g.o> -systemd-204.ebuild: |
74 |
Remove old, vulnerable version. |
75 |
|
76 |
|
77 |
|
78 |
1.1 sys-apps/systemd/systemd-208.ebuild |
79 |
|
80 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/systemd-208.ebuild?rev=1.1&view=markup |
81 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/systemd/systemd-208.ebuild?rev=1.1&content-type=text/plain |
82 |
|
83 |
Index: systemd-208.ebuild |
84 |
=================================================================== |
85 |
# Copyright 1999-2013 Gentoo Foundation |
86 |
# Distributed under the terms of the GNU General Public License v2 |
87 |
# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd/systemd-208.ebuild,v 1.1 2013/10/02 09:11:49 mgorny Exp $ |
88 |
|
89 |
EAPI=5 |
90 |
|
91 |
AUTOTOOLS_PRUNE_LIBTOOL_FILES=all |
92 |
PYTHON_COMPAT=( python2_7 ) |
93 |
inherit autotools-utils bash-completion-r1 fcaps linux-info multilib \ |
94 |
multilib-minimal pam python-single-r1 systemd toolchain-funcs udev \ |
95 |
user |
96 |
|
97 |
DESCRIPTION="System and service manager for Linux" |
98 |
HOMEPAGE="http://www.freedesktop.org/wiki/Software/systemd" |
99 |
SRC_URI="http://www.freedesktop.org/software/systemd/${P}.tar.xz" |
100 |
|
101 |
LICENSE="GPL-2 LGPL-2.1 MIT public-domain" |
102 |
SLOT="0/1" |
103 |
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86" |
104 |
IUSE="acl audit cryptsetup doc +firmware-loader gcrypt gudev http introspection |
105 |
+kmod lzma openrc pam policykit python qrcode selinux tcpd test |
106 |
vanilla xattr" |
107 |
|
108 |
MINKV="3.0" |
109 |
|
110 |
COMMON_DEPEND=">=sys-apps/dbus-1.6.8-r1 |
111 |
>=sys-apps/util-linux-2.20 |
112 |
sys-libs/libcap |
113 |
acl? ( sys-apps/acl ) |
114 |
audit? ( >=sys-process/audit-2 ) |
115 |
cryptsetup? ( >=sys-fs/cryptsetup-1.6 ) |
116 |
gcrypt? ( >=dev-libs/libgcrypt-1.4.5 ) |
117 |
gudev? ( >=dev-libs/glib-2[${MULTILIB_USEDEP}] ) |
118 |
http? ( net-libs/libmicrohttpd ) |
119 |
introspection? ( >=dev-libs/gobject-introspection-1.31.1 ) |
120 |
kmod? ( >=sys-apps/kmod-14-r1 ) |
121 |
lzma? ( app-arch/xz-utils[${MULTILIB_USEDEP}] ) |
122 |
pam? ( virtual/pam ) |
123 |
python? ( ${PYTHON_DEPS} ) |
124 |
qrcode? ( media-gfx/qrencode ) |
125 |
selinux? ( sys-libs/libselinux ) |
126 |
tcpd? ( sys-apps/tcp-wrappers ) |
127 |
xattr? ( sys-apps/attr ) |
128 |
abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r9 |
129 |
!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )" |
130 |
|
131 |
# baselayout-2.2 has /run |
132 |
RDEPEND="${COMMON_DEPEND} |
133 |
>=sys-apps/baselayout-2.2 |
134 |
openrc? ( >=sys-fs/udev-init-scripts-25 ) |
135 |
|| ( |
136 |
>=sys-apps/util-linux-2.22 |
137 |
<sys-apps/sysvinit-2.88-r4 |
138 |
) |
139 |
!sys-auth/nss-myhostname |
140 |
!<sys-libs/glibc-2.10 |
141 |
!sys-fs/udev" |
142 |
|
143 |
PDEPEND=">=sys-apps/hwids-20130717-r1[udev] |
144 |
policykit? ( sys-auth/polkit ) |
145 |
!vanilla? ( sys-apps/gentoo-systemd-integration )" |
146 |
|
147 |
DEPEND="${COMMON_DEPEND} |
148 |
app-arch/xz-utils |
149 |
app-text/docbook-xml-dtd:4.2 |
150 |
app-text/docbook-xsl-stylesheets |
151 |
dev-libs/libxslt |
152 |
dev-util/gperf |
153 |
>=dev-util/intltool-0.50 |
154 |
>=sys-devel/binutils-2.23.1 |
155 |
>=sys-devel/gcc-4.6 |
156 |
>=sys-kernel/linux-headers-${MINKV} |
157 |
virtual/pkgconfig |
158 |
doc? ( >=dev-util/gtk-doc-1.18 )" |
159 |
|
160 |
pkg_pretend() { |
161 |
local CONFIG_CHECK="~AUTOFS4_FS ~BLK_DEV_BSG ~CGROUPS ~DEVTMPFS |
162 |
~EPOLL ~FANOTIFY ~FHANDLE ~INOTIFY_USER ~IPV6 ~NET ~PROC_FS |
163 |
~SECCOMP ~SIGNALFD ~SYSFS ~TIMERFD |
164 |
~!IDE ~!SYSFS_DEPRECATED ~!SYSFS_DEPRECATED_V2" |
165 |
|
166 |
use acl && CONFIG_CHECK+=" ~TMPFS_POSIX_ACL" |
167 |
use pam && CONFIG_CHECK+=" ~AUDITSYSCALL" |
168 |
kernel_is -lt 3 7 && CONFIG_CHECK+=" ~HOTPLUG" |
169 |
use firmware-loader || CONFIG_CHECK+=" ~!FW_LOADER_USER_HELPER" |
170 |
|
171 |
if [[ ${MERGE_TYPE} != binary ]]; then |
172 |
if [[ $(gcc-major-version) -lt 4 |
173 |
|| ( $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 6 ) ]] |
174 |
then |
175 |
eerror "systemd requires at least gcc 4.6 to build. Please switch the active" |
176 |
eerror "gcc version using gcc-config." |
177 |
die "systemd requires at least gcc 4.6" |
178 |
fi |
179 |
fi |
180 |
|
181 |
if [[ ${MERGE_TYPE} != buildonly ]]; then |
182 |
if kernel_is -lt ${MINKV//./ }; then |
183 |
ewarn "Kernel version at least ${MINKV} required" |
184 |
fi |
185 |
|
186 |
if ! use firmware-loader && kernel_is -lt 3 8; then |
187 |
ewarn "You seem to be using kernel older than 3.8. Those kernel versions" |
188 |
ewarn "require systemd with USE=firmware-loader to support loading" |
189 |
ewarn "firmware. Missing this flag may cause some hardware not to work." |
190 |
fi |
191 |
|
192 |
check_extra_config |
193 |
fi |
194 |
} |
195 |
|
196 |
pkg_setup() { |
197 |
use python && python-single-r1_pkg_setup |
198 |
} |
199 |
|
200 |
src_prepare() { |
201 |
local PATCHES=( |
202 |
# missing linking, bug #479038 |
203 |
"${FILESDIR}"/${PV}-0001-Work-around-link-libsystemd-label-to-libsystemd-logi.patch |
204 |
"${FILESDIR}"/${PV}-0002-Update-Makefile.in.patch |
205 |
) |
206 |
|
207 |
autotools-utils_src_prepare |
208 |
} |
209 |
|
210 |
multilib_src_configure() { |
211 |
local myeconfargs=( |
212 |
--localstatedir=/var |
213 |
--with-pamlibdir=$(getpam_mod_dir) |
214 |
# avoid bash-completion dep |
215 |
--with-bashcompletiondir="$(get_bashcompdir)" |
216 |
# make sure we get /bin:/sbin in $PATH |
217 |
--enable-split-usr |
218 |
# disable sysv compatibility |
219 |
--with-sysvinit-path= |
220 |
--with-sysvrcnd-path= |
221 |
# no deps |
222 |
--enable-efi |
223 |
--enable-ima |
224 |
# optional components/dependencies |
225 |
$(use_enable acl) |
226 |
$(use_enable audit) |
227 |
$(use_enable cryptsetup libcryptsetup) |
228 |
$(use_enable doc gtk-doc) |
229 |
$(use_enable gcrypt) |
230 |
$(use_enable gudev) |
231 |
$(use_enable http microhttpd) |
232 |
$(use_enable introspection) |
233 |
$(use_enable kmod) |
234 |
$(use_enable lzma xz) |
235 |
$(use_enable pam) |
236 |
$(use_enable policykit polkit) |
237 |
$(use_enable python python-devel) |
238 |
$(use python && echo PYTHON_CONFIG=/usr/bin/python-config-${EPYTHON#python}) |
239 |
$(use_enable qrcode qrencode) |
240 |
$(use_enable selinux) |
241 |
$(use_enable tcpd tcpwrap) |
242 |
$(use_enable test tests) |
243 |
$(use_enable xattr) |
244 |
|
245 |
# not supported (avoid automagic deps in the future) |
246 |
--disable-chkconfig |
247 |
|
248 |
# hardcode a few paths to spare some deps |
249 |
QUOTAON=/usr/sbin/quotaon |
250 |
QUOTACHECK=/usr/sbin/quotacheck |
251 |
) |
252 |
|
253 |
# Keep using the one where the rules were installed. |
254 |
MY_UDEVDIR=$(get_udevdir) |
255 |
|
256 |
if use firmware-loader; then |
257 |
myeconfargs+=( |
258 |
--with-firmware-path="/lib/firmware/updates:/lib/firmware" |
259 |
) |
260 |
fi |
261 |
|
262 |
if ! multilib_is_native_abi; then |
263 |
myeconfargs+=( |
264 |
ac_cv_search_cap_init= |
265 |
ac_cv_header_sys_capability_h=yes |
266 |
DBUS_CFLAGS=' ' |
267 |
DBUS_LIBS=' ' |
268 |
|
269 |
--disable-acl |
270 |
--disable-audit |
271 |
--disable-gcrypt |
272 |
--disable-gtk-doc |
273 |
--disable-introspection |
274 |
--disable-kmod |
275 |
--disable-libcryptsetup |
276 |
--disable-microhttpd |
277 |
--disable-pam |
278 |
--disable-polkit |
279 |
--disable-qrencode |
280 |
--disable-selinux |
281 |
--disable-tcpwrap |
282 |
--disable-tests |
283 |
--disable-xattr |
284 |
--disable-xz |
285 |
--disable-python-devel |
286 |
) |
287 |
fi |
288 |
|
289 |
# Work around bug 463846. |
290 |
tc-export CC |
291 |
|
292 |
autotools-utils_src_configure |
293 |
} |
294 |
|
295 |
multilib_src_compile() { |
296 |
local mymakeopts=( |
297 |
udevlibexecdir="${MY_UDEVDIR}" |
298 |
) |
299 |
|
300 |
if multilib_is_native_abi; then |
301 |
emake "${mymakeopts[@]}" |
302 |
else |
303 |
# prerequisites for gudev |
304 |
use gudev && emake src/gudev/gudev{enumtypes,marshal}.{c,h} |
305 |
|
306 |
echo 'gentoo: $(lib_LTLIBRARIES) $(pkgconfiglib_DATA)' | \ |
307 |
emake "${mymakeopts[@]}" -f Makefile -f - gentoo |
308 |
fi |
309 |
} |
310 |
|
311 |
multilib_src_test() { |
312 |
multilib_is_native_abi || continue |
313 |
|
314 |
default |
315 |
} |
316 |
|
317 |
multilib_src_install() { |
318 |
local mymakeopts=( |
319 |
udevlibexecdir="${MY_UDEVDIR}" |
320 |
dist_udevhwdb_DATA= |
321 |
DESTDIR="${D}" |
322 |
) |
323 |
|
324 |
if multilib_is_native_abi; then |
325 |
emake "${mymakeopts[@]}" install |
326 |
else |
327 |
mymakeopts+=( |
328 |
install-libLTLIBRARIES |
329 |
install-pkgconfiglibDATA |
330 |
install-includeHEADERS |
331 |
# safe to call unconditionally, 'installs' empty list |
332 |
install-libgudev_includeHEADERS |
333 |
install-pkgincludeHEADERS |
334 |
) |
335 |
|
336 |
emake "${mymakeopts[@]}" |
337 |
fi |
338 |
} |
339 |
|
340 |
multilib_src_install_all() { |
341 |
prune_libtool_files --modules |
342 |
|
343 |
# we just keep sysvinit tools, so no need for the mans |
344 |
rm "${D}"/usr/share/man/man8/{halt,poweroff,reboot,runlevel,shutdown,telinit}.8 \ |
345 |
|| die |
346 |
rm "${D}"/usr/share/man/man1/init.1 || die |
347 |
|
348 |
# Disable storing coredumps in journald, bug #433457 |
349 |
mv "${D}"/usr/lib/sysctl.d/50-coredump.conf{,.disabled} || die |
350 |
|
351 |
# Preserve empty dirs in /etc & /var, bug #437008 |
352 |
keepdir /etc/binfmt.d /etc/modules-load.d /etc/tmpfiles.d \ |
353 |
/etc/systemd/ntp-units.d /etc/systemd/user /var/lib/systemd |
354 |
|
355 |
# Symlink /etc/sysctl.conf for easy migration. |
356 |
dosym ../sysctl.conf /etc/sysctl.d/99-sysctl.conf |
357 |
} |
358 |
|
359 |
migrate_locale() { |
360 |
local envd_locale_def="${EROOT%/}/etc/env.d/02locale" |
361 |
local envd_locale=( "${EROOT%/}"/etc/env.d/??locale ) |
362 |
local locale_conf="${EROOT%/}/etc/locale.conf" |
363 |
|
364 |
if [[ ! -L ${locale_conf} && ! -e ${locale_conf} ]]; then |
365 |
# if locale.conf does not exist... |
366 |
if [[ -e ${envd_locale} ]]; then |
367 |
# ...either copy env.d/??locale if there's one |
368 |
ebegin "Moving ${envd_locale} to ${locale_conf}" |
369 |
mv "${envd_locale}" "${locale_conf}" |
370 |
eend ${?} || FAIL=1 |
371 |
else |
372 |
# ...or create a dummy default |
373 |
ebegin "Creating ${locale_conf}" |
374 |
cat > "${locale_conf}" <<-EOF |
375 |
# This file has been created by the sys-apps/systemd ebuild. |
376 |
# See locale.conf(5) and localectl(1). |
377 |
|
378 |
# LANG=${LANG} |
379 |
EOF |
380 |
eend ${?} || FAIL=1 |
381 |
fi |
382 |
fi |
383 |
|
384 |
if [[ ! -L ${envd_locale} ]]; then |
385 |
# now, if env.d/??locale is not a symlink (to locale.conf)... |
386 |
if [[ -e ${envd_locale} ]]; then |
387 |
# ...warn the user that he has duplicate locale settings |
388 |
ewarn |
389 |
ewarn "To ensure consistent behavior, you should replace ${envd_locale}" |
390 |
ewarn "with a symlink to ${locale_conf}. Please migrate your settings" |
391 |
ewarn "and create the symlink with the following command:" |
392 |
ewarn "ln -s -n -f ../locale.conf ${envd_locale}" |
393 |
ewarn |
394 |
else |
395 |
# ...or just create the symlink if there's nothing here |
396 |
ebegin "Creating ${envd_locale_def} -> ../locale.conf symlink" |
397 |
ln -n -s ../locale.conf "${envd_locale_def}" |
398 |
eend ${?} || FAIL=1 |
399 |
fi |
400 |
fi |
401 |
} |
402 |
|
403 |
pkg_postinst() { |
404 |
# for udev rules |
405 |
enewgroup dialout |
406 |
|
407 |
enewgroup systemd-journal |
408 |
if use http; then |
409 |
enewgroup systemd-journal-gateway |
410 |
enewuser systemd-journal-gateway -1 -1 -1 systemd-journal-gateway |
411 |
fi |
412 |
systemd_update_catalog |
413 |
|
414 |
# Keep this here in case the database format changes so it gets updated |
415 |
# when required. Despite that this file is owned by sys-apps/hwids. |
416 |
if has_version "sys-apps/hwids[udev]"; then |
417 |
udevadm hwdb --update --root="${ROOT%/}" |
418 |
fi |
419 |
|
420 |
udev_reload || FAIL=1 |
421 |
|
422 |
# Bug 468876 |
423 |
fcaps cap_dac_override,cap_sys_ptrace=ep usr/bin/systemd-detect-virt |
424 |
|
425 |
# Bug 465468, make sure locales are respect, and ensure consistency |
426 |
# between OpenRC & systemd |
427 |
migrate_locale |
428 |
|
429 |
if [[ ${FAIL} ]]; then |
430 |
eerror "One of the postinst commands failed. Please check the postinst output" |
431 |
eerror "for errors. You may need to clean up your system and/or try installing" |
432 |
eerror "systemd again." |
433 |
eerror |
434 |
fi |
435 |
|
436 |
if [[ ! -L "${ROOT}"/etc/mtab ]]; then |
437 |
ewarn "Upstream mandates the /etc/mtab file should be a symlink to /proc/mounts." |
438 |
ewarn "Not having it is not supported by upstream and will cause tools like 'df'" |
439 |
ewarn "and 'mount' to not work properly. Please run:" |
440 |
ewarn " # ln -sf '${ROOT}proc/self/mounts' '${ROOT}etc/mtab'" |
441 |
ewarn |
442 |
fi |
443 |
|
444 |
if ! has_version sys-apps/systemd-ui; then |
445 |
elog "To get additional features, a number of optional runtime dependencies may" |
446 |
elog "be installed:" |
447 |
elog "- sys-apps/systemd-ui: for GTK+ systemadm UI and gnome-ask-password-agent" |
448 |
fi |
449 |
} |
450 |
|
451 |
pkg_prerm() { |
452 |
# If removing systemd completely, remove the catalog database. |
453 |
if [[ ! ${REPLACED_BY_VERSION} ]]; then |
454 |
rm -f -v "${EROOT}"/var/lib/systemd/catalog/database |
455 |
fi |
456 |
} |