[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

[Matt Turner]

commit:     466f2d2911ec963834fbc059a6c665f4f69d75f6
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 19 23:46:42 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Feb 19 23:55:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=466f2d29

gnome-extra/gnome-software: Version bump to 41.4

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-41.4.ebuild      | 101 +++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 0a1fdc1e61da..a9fd5e66d41d 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
 DIST gnome-software-40.4.tar.xz 3108460 BLAKE2B 696736d94fe245f98a619a58c8df1a3c6196a9f3f07ccc82f0c92c3226ab4914ee5bdbf2f6414b8e8fca99215451d08ef03b164b5cd885af36d69b1cc9043b7a SHA512 5ef7ad754cb161ad5e181dc9b189fe57066a92ebbe3a5871412b638896a02d6e9114e5fdce91e3225af990a580a1f534b936008ff3a2d50a59154406f055a3e7
+DIST gnome-software-41.4.tar.xz 3243380 BLAKE2B a8511c776d902639a01b1194e7dd23f22e98c6fa5fd0624cf9d7b7ae96f0ca313eb139a396e4bf8c7b2ec94db66a3f6ef89a8d77cbd1820291f01cd6c70ec2db SHA512 97c51fd21bd5fd2f7d11e00811747992ff0e404380f84cda07e5c7cae3962034c9169ebad95f875056233c9b1d44347a0c15c61e0f018bb3128e7c7d5d3c74b2

diff --git a/gnome-extra/gnome-software/gnome-software-41.4.ebuild b/gnome-extra/gnome-software/gnome-software-41.4.ebuild
new file mode 100644
index 000000000000..69002ba173ae
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-41.4.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc spell sysprof udev"
+RESTRICT="test" # writes to and deletes files in /var/tmp/self-test/
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=x11-libs/gtk+-3.22.4:3
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/json-glib-1.2.0
+	>=net-libs/libsoup-2.52.0:2.4
+	>=gui-libs/libhandy-1.2.0:1=
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	spell? ( app-text/gspell:= )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.0.3 )
+	flatpak? (
+		>=sys-apps/flatpak-1.0.4
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+"
+# test? ( dev-util/valgrind )
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+	# Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+	# TODO: Investigate; seems to work outside ebuild .. test/emerge
+	sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dtests=false #$(meson_use test tests)
+		$(meson_use spell gspell)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		-Dvalgrind=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_popular=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+	)
+	meson_src_configure
+}
+
+#src_test() {
+#	virtx meson_src_test
+#}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}