[gentoo-commits] gentoo-x86 commit in net-analyzer/hping: hping-3_pre20051105-r2.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         10/05/11 04:08:19

  Modified:             ChangeLog
  Added:                hping-3_pre20051105-r2.ebuild
  Log:
  Do not hardcode better values in Makefile.in either, but set them in the emake env. Change program name in man page thanks to Džen (bug #318823) and install man page without version suffix.
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.49                 net-analyzer/hping/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	23 Dec 2009 14:02:25 -0000	1.48
+++ ChangeLog	11 May 2010 04:08:17 -0000	1.49
@@ -1,6 +1,14 @@
 # ChangeLog for net-analyzer/hping
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v 1.48 2009/12/23 14:02:25 jer Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v 1.49 2010/05/11 04:08:17 jer Exp $
+
+*hping-3_pre20051105-r2 (11 May 2010)
+
+  11 May 2010; Jeroen Roovers <jer@g.o>
+  +hping-3_pre20051105-r2.ebuild:
+  Do not hardcode better values in Makefile.in either, but set them in the
+  emake env. Change program name in man page thanks to Džen (bug #318823)
+  and install man page without version suffix.
 
   23 Dec 2009; Jeroen Roovers <jer@g.o>
   hping-3_pre20051105-r1.ebuild, +files/hping-3_pre20051105-libtcl.patch:



1.1                  net-analyzer/hping/hping-3_pre20051105-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r2.ebuild?rev=1.1&content-type=text/plain

Index: hping-3_pre20051105-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r2.ebuild,v 1.1 2010/05/11 04:08:16 jer Exp $

EAPI="2"

inherit eutils multilib toolchain-funcs

MY_P="${PN}${PV//_pre/-}"
DESCRIPTION="A ping-like TCP/IP packet assembler/analyzer"
HOMEPAGE="http://www.hping.org"
SRC_URI="http://www.hping.org/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86"
IUSE="tcl"

S="${WORKDIR}/${MY_P}"

DEPEND="net-libs/libpcap
	tcl? ( dev-lang/tcl )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}.patch \
		"${FILESDIR}"/bytesex.h.patch \
		"${FILESDIR}"/${P}-tcl.patch \
		"${FILESDIR}"/${P}-ldflags.patch \
		"${FILESDIR}"/${P}-libtcl.patch

	# Correct hard coded values
	sed -i Makefile.in \
		-e '/^CC=/d' \
		-e '/^AR=/d' \
		-e '/^RANLIB=/d' \
		-e 's:/usr/local/lib:/usr/$(LIBDIR):g' \
		-e 's:-O2:$(CFLAGS):' \
		|| die "sed Makefile.in failed"
	
	# Change name from hping2 to hping3
	sed -i docs/hping3.8 \
		-e 's|HPING2|HPING|g' \
		-e 's|hping2|hping|g' \
		|| die "sed hping3.8 failed"
}

src_configure() {
	myconf=""
	use tcl || myconf="--no-tcl"

	# Not an autotools type configure:
	sh configure ${myconf} || die "configure failed"
}

src_compile() {
	emake \
		DEBUG="" \
		"CFLAGS=${CFLAGS}" \
		"CC=$(tc-getCC)" \
		"AR=$(tc-getAR)" \
		"RANLIB=$(tc-getRANLIB)" \
		"LIBDIR=$(get_libdir)" \
		|| die "emake failed"
}

src_install () {
	dosbin hping3
	dosym /usr/sbin/hping3 /usr/sbin/hping
	dosym /usr/sbin/hping3 /usr/sbin/hping2

	newman docs/hping3.8 hping.8

	dodoc INSTALL NEWS README TODO AUTHORS BUGS CHANGES
}