[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-commander/

[Andreas Sturmlechner]

commit:     2f1401a6a48b36d9730d7374c08d9874e1b4944a
Author:     Uwe Scholz <u.scholz83 <AT> gmx <DOT> de>
AuthorDate: Fri Apr 30 19:37:49 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue May  4 22:56:47 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f1401a6

gnome-extra/gnome-commander: version bump to 1.12.1

Signed-off-by: Uwe Scholz <u.scholz83 <AT> gmx.de>
Closes: https://github.com/gentoo/gentoo/pull/20619
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.12.1.ebuild  | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index 683da85a1f2..6462cce9700 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1 +1,2 @@
 DIST gnome-commander-1.10.3.tar.xz 7474512 BLAKE2B f27f86a470bc919327980ba21c577241034290d74b663d4479195fa21249ce9bd238b12a0fae70c3cc6ab26953a595414efbe04508c73f8deb5e7c6e2de6f784 SHA512 87c4df1534747f21b15e48141180601aef02152b1eef097986b0f8675a6d24e75a81ccb7d0b41b2df38cd40eadae2b0bd09f8e0274a5e5cd8bbd8d23df6ffd7f
+DIST gnome-commander-1.12.1.tar.xz 7532412 BLAKE2B 92a4c71e716aca5354cd53ca10440ce11426f9baa11342c37a8dbd5d3fe2898ea9e7aa577d584d0e91e85a8213a5480dd045c6d0ffbd05155b05d74c2a0b52e7 SHA512 74756af9a720ab81904e3f7834ae008af67d635cc1d1b961420d02c029616465dfe06a18bc5b443d0a9725cfefe6e9f7cdba68faa62515f8ccb85a2246867010

diff --git a/gnome-extra/gnome-commander/gnome-commander-1.12.1.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.12.1.ebuild
new file mode 100644
index 00000000000..6c407b4f188
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.12.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 optfeature toolchain-funcs
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="chm exif gsf pdf samba taglib test +unique"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/yelp-tools
+	>=dev-libs/glib-2.62.0:2
+	>=gnome-base/gnome-vfs-2.0.0
+	>=x11-libs/gtk+-2.24.0:2
+	chm? ( dev-libs/chmlib )
+	exif? ( >=media-gfx/exiv2-0.14 )
+	gsf? ( >=gnome-extra/libgsf-1.12.0 )
+	pdf? ( >=app-text/poppler-0.18 )
+	samba? ( >=gnome-base/gnome-vfs-2.0.0[samba] )
+	taglib? ( >=media-libs/taglib-1.4 )
+	unique? ( >=dev-libs/libunique-0.9.3:1 )
+"
+BDEPEND="
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+
+pkg_pretend() {
+	if tc-is-gcc && [[ $(gcc-major-version) -lt 8 ]]; then
+		eerror "Compilation with gcc older than version 8 is not supported"
+		die "GCC too old, please use gcc-8 or above"
+	fi
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_with chm libchm) \
+		$(use_with exif exiv2) \
+		$(use_with gsf libgsf) \
+		$(use_with pdf poppler) \
+		$(use_with samba) \
+		$(use_with taglib) \
+		$(use_with unique)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "synchronizing files and directories" dev-util/meld
+	optfeature "viewing the documentation" gnome-extra/yelp
+}