[gentoo-commits] gentoo-x86 commit in dev-python/pyopenssl: pyopenssl-0.9-r1.ebuild ChangeLog

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/08/02 05:47:26

  Modified:             ChangeLog
  Added:                pyopenssl-0.9-r1.ebuild
  Log:
  Set SUPPORT_PYTHON_ABIS.
  (Portage version: 13874-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 dev-python/pyopenssl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pyopenssl/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pyopenssl/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pyopenssl/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	17 Jul 2009 18:14:05 -0000	1.32
+++ ChangeLog	2 Aug 2009 05:47:26 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pyopenssl
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/ChangeLog,v 1.32 2009/07/17 18:14:05 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/ChangeLog,v 1.33 2009/08/02 05:47:26 arfrever Exp $
+
+*pyopenssl-0.9-r1 (02 Aug 2009)
+
+  02 Aug 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +pyopenssl-0.9-r1.ebuild:
+  Set SUPPORT_PYTHON_ABIS.
 
   17 Jul 2009; nixnut <nixnut@g.o> pyopenssl-0.9.ebuild:
   ppc stable #274897



1.1                  dev-python/pyopenssl/pyopenssl-0.9-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pyopenssl/pyopenssl-0.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/pyopenssl/pyopenssl-0.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: pyopenssl-0.9-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/pyopenssl-0.9-r1.ebuild,v 1.1 2009/08/02 05:47:26 arfrever Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils eutils

MY_P=${P/openssl/OpenSSL}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Python interface to the OpenSSL library"
HOMEPAGE="http://pyopenssl.sourceforge.net/"
SRC_URI="mirror://sourceforge/pyopenssl/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc"

RDEPEND=">=dev-libs/openssl-0.9.6g"
DEPEND="${RDEPEND}
	doc? ( >=dev-tex/latex2html-2002.2 )"

RESTRICT_PYTHON_ABIS="3*"

src_prepare() {
	epatch "${FILESDIR}/${P}-tests.patch"
}

src_compile() {
	distutils_src_compile
	if use doc; then
		addwrite /var/cache/fonts
		# This one seems to be unnecessary with a recent tetex, but
		# according to bugs it was definitely necessary in the past,
		# so leaving it in.
		addwrite /usr/share/texmf/fonts/pk

		cd "${S}"/doc
		make html ps dvi
	fi
}

src_test() {
	test_package() {
		pushd test > /dev/null
		PYTHONPATH="$(ls -d ../build-${PYTHON_ABI}/lib.*)" "$(get_python)" test_crypto.py || die "test_crypto.py failed"
		PYTHONPATH="$(ls -d ../build-${PYTHON_ABI}/lib.*)" "$(get_python)" test_ssl.py || die "test_ssl.py failed"
		popd > /dev/null
	}
	python_execute_function test_package
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml "${S}"/doc/html/*
		dodoc "${S}"/doc/pyOpenSSL.*
	fi

	# Install examples
	docinto examples
	dodoc "${S}"/examples/*
	docinto examples/simple
	dodoc "${S}"/examples/simple/*
}

pkg_postinst() {
	python_mod_optimize OpenSSL
}

pkg_postrm() {
	python_mod_cleanup OpenSSL
}