Gentoo Archives: gentoo-commits

From: "Olivier Crete (tester)" <tester@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in net-im/pidgin: ChangeLog pidgin-2.10.3-r100.ebuild
Date: Sat, 31 Mar 2012 21:02:20
Message-Id: 20120331210156.669852004B@flycatcher.gentoo.org
1 tester 12/03/31 21:01:56
2
3 Modified: ChangeLog
4 Added: pidgin-2.10.3-r100.ebuild
5 Log:
6 Add package.masked version that uses farstream instead of farsight2
7
8 (Portage version: 2.1.10.49/cvs/Linux x86_64)
9
10 Revision Changes Path
11 1.269 net-im/pidgin/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.269&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.269&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/pidgin/ChangeLog?r1=1.268&r2=1.269
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v
20 retrieving revision 1.268
21 retrieving revision 1.269
22 diff -u -r1.268 -r1.269
23 --- ChangeLog 30 Mar 2012 17:11:29 -0000 1.268
24 +++ ChangeLog 31 Mar 2012 21:01:55 -0000 1.269
25 @@ -1,6 +1,12 @@
26 # ChangeLog for net-im/pidgin
27 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.268 2012/03/30 17:11:29 polynomial-c Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.269 2012/03/31 21:01:55 tester Exp $
30 +
31 +*pidgin-2.10.3-r100 (31 Mar 2012)
32 +
33 + 31 Mar 2012; Olivier CrĂȘte <tester@g.o>
34 + +files/port-to-farstream-v5.patch, +pidgin-2.10.3-r100.ebuild:
35 + Add package.masked version that uses farstream instead of farsight2
36
37 *pidgin-2.10.3 (30 Mar 2012)
38
39
40
41
42 1.1 net-im/pidgin/pidgin-2.10.3-r100.ebuild
43
44 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/pidgin/pidgin-2.10.3-r100.ebuild?rev=1.1&view=markup
45 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/pidgin/pidgin-2.10.3-r100.ebuild?rev=1.1&content-type=text/plain
46
47 Index: pidgin-2.10.3-r100.ebuild
48 ===================================================================
49 # Copyright 1999-2012 Gentoo Foundation
50 # Distributed under the terms of the GNU General Public License v2
51 # $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/pidgin-2.10.3-r100.ebuild,v 1.1 2012/03/31 21:01:56 tester Exp $
52
53 EAPI=4
54
55 GENTOO_DEPEND_ON_PERL=no
56 inherit flag-o-matic eutils toolchain-funcs multilib perl-app gnome2 python autotools
57
58 DESCRIPTION="GTK Instant Messenger client"
59 HOMEPAGE="http://pidgin.im/"
60 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
61
62 LICENSE="GPL-2"
63 SLOT="0"
64 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
65 IUSE="dbus debug doc eds gadu gnutls +gstreamer +gtk idn meanwhile"
66 IUSE+=" networkmanager nls perl silc tcl tk spell sasl ncurses"
67 IUSE+=" groupwise prediction python +xscreensaver zephyr zeroconf" # mono"
68
69 # dbus requires python to generate C code for dbus bindings (thus DEPEND only).
70 # finch uses libgnt that links with libpython - {R,}DEPEND. But still there is
71 # no way to build dbus and avoid libgnt linkage with python. If you want this
72 # send patch upstream.
73 # purple-url-handler and purple-remote require dbus-python thus in reality we
74 # rdepend on python if dbus enabled. But it is possible to separate this dep.
75 RDEPEND="
76 >=dev-libs/glib-2.16
77 >=dev-libs/libxml2-2.6.18
78 ncurses? ( sys-libs/ncurses[unicode]
79 dbus? ( <dev-lang/python-3 )
80 python? ( <dev-lang/python-3 ) )
81 gtk? (
82 >=x11-libs/gtk+-2.10:2
83 x11-libs/libSM
84 xscreensaver? ( x11-libs/libXScrnSaver )
85 spell? ( >=app-text/gtkspell-2.0.2:2 )
86 eds? ( gnome-extra/evolution-data-server )
87 prediction? ( >=dev-db/sqlite-3.3:3 ) )
88 gstreamer? ( =media-libs/gstreamer-0.10*
89 =media-libs/gst-plugins-good-0.10*
90 net-libs/farstream
91 media-plugins/gst-plugins-meta
92 media-plugins/gst-plugins-gconf )
93 zeroconf? ( net-dns/avahi[dbus] )
94 dbus? ( >=dev-libs/dbus-glib-0.71
95 >=sys-apps/dbus-0.90
96 dev-python/dbus-python )
97 perl? ( >=dev-lang/perl-5.8.2-r1[-build] )
98 gadu? ( || ( >=net-libs/libgadu-1.11.0[ssl,gnutls]
99 >=net-libs/libgadu-1.11.0[-ssl] ) )
100 gnutls? ( net-libs/gnutls )
101 !gnutls? ( >=dev-libs/nss-3.11 )
102 meanwhile? ( net-libs/meanwhile )
103 silc? ( >=net-im/silc-toolkit-1.0.1 )
104 tcl? ( dev-lang/tcl )
105 tk? ( dev-lang/tk )
106 sasl? ( dev-libs/cyrus-sasl:2 )
107 networkmanager? ( net-misc/networkmanager )
108 idn? ( net-dns/libidn )
109 !<x11-plugins/pidgin-facebookchat-1.69-r1"
110 # Mono support crashes pidgin
111 #mono? ( dev-lang/mono )"
112
113 # We want nls in case gtk is enabled, bug #
114 NLS_DEPEND=">=dev-util/intltool-0.41.1 sys-devel/gettext"
115
116 DEPEND="$RDEPEND
117 dev-lang/perl
118 dev-perl/XML-Parser
119 dev-util/pkgconfig
120 gtk? ( x11-proto/scrnsaverproto
121 ${NLS_DEPEND} )
122 dbus? ( <dev-lang/python-3 )
123 doc? ( app-doc/doxygen )
124 !gtk? ( nls? ( ${NLS_DEPEND} ) )"
125
126 DOCS="AUTHORS HACKING NEWS README ChangeLog"
127
128 # Enable Default protocols
129 DYNAMIC_PRPLS="irc,jabber,oscar,yahoo,simple,msn,myspace"
130
131 # List of plugins
132 # app-accessibility/pidgin-festival
133 # net-im/librvp
134 # x11-plugins/guifications
135 # x11-plugins/msn-pecan
136 # x11-plugins/pidgin-encryption
137 # x11-plugins/pidgin-extprefs
138 # x11-plugins/pidgin-hotkeys
139 # x11-plugins/pidgin-latex
140 # x11-plugins/pidgintex
141 # x11-plugins/pidgin-libnotify
142 # x11-plugins/pidgin-mbpurple
143 # x11-plugins/pidgin-bot-sentry
144 # x11-plugins/pidgin-otr
145 # x11-plugins/pidgin-rhythmbox
146 # x11-plugins/purple-plugin_pack
147 # x11-themes/pidgin-smileys
148 # x11-plugins/pidgin-knotify
149 # Plugins in Sunrise:
150 # x11-plugins/pidgin-audacious-remote
151 # x11-plugins/pidgin-autoanswer
152 # x11-plugins/pidgin-birthday-reminder
153 # x11-plugins/pidgin-blinklight
154 # x11-plugins/pidgin-convreverse
155 # x11-plugins/pidgin-embeddedvideo
156 # x11-plugins/pidgin-extended-blist-sort
157 # x11-plugins/pidgin-gfire
158 # x11-plugins/pidgin-lastfm
159 # x11-plugins/pidgin-sendscreenshot
160 # x11-plugins/pidgimpd
161
162 pkg_setup() {
163 if ! use gtk && ! use ncurses ; then
164 elog "You did not pick the ncurses or gtk use flags, only libpurple"
165 elog "will be built."
166 fi
167 if use dbus || { use ncurses && use python; }; then
168 python_set_active_version 2
169 python_pkg_setup
170 fi
171
172 # dbus is enabled, no way to disable linkage with python => python is enabled
173 #REQUIRED_USE="gtk? ( nls ) dbus? ( python )"
174 if use gtk && ! use nls; then
175 ewarn "gtk build => nls is enabled!"
176 fi
177 if use dbus && ! use python; then
178 elog "dbus is enabled, no way to disable linkage with python => python is enabled"
179 fi
180 }
181
182 src_prepare() {
183 epatch "${FILESDIR}/${PN}-2.10.0-gold.patch"
184 epatch "${FILESDIR}/port-to-farstream-v5.patch"
185 eautoreconf
186 }
187
188 src_configure() {
189 # Stabilize things, for your own good
190 strip-flags
191 replace-flags -O? -O2
192
193 local myconf
194
195 if use gadu; then
196 DYNAMIC_PRPLS="${DYNAMIC_PRPLS},gg"
197 myconf="${myconf} --with-gadu-includes=."
198 myconf="${myconf} --with-gadu-libs=."
199 fi
200
201 use silc && DYNAMIC_PRPLS+=",silc"
202 use meanwhile && DYNAMIC_PRPLS+=",sametime"
203 use zeroconf && DYNAMIC_PRPLS+=",bonjour"
204 use groupwise && DYNAMIC_PRPLS+=",novell"
205 use zephyr && DYNAMIC_PRPLS+=",zephyr"
206
207 if use gnutls; then
208 einfo "Disabling NSS, using GnuTLS"
209 myconf+=" --enable-nss=no --enable-gnutls=yes"
210 myconf+=" --with-gnutls-includes=/usr/include/gnutls"
211 myconf+=" --with-gnutls-libs=/usr/$(get_libdir)"
212 else
213 einfo "Disabling GnuTLS, using NSS"
214 myconf+=" --enable-gnutls=no --enable-nss=yes"
215 fi
216
217 if use dbus || { use ncurses && use python; }; then
218 myconf+=" --with-python=$(PYTHON)"
219 else
220 myconf+=" --without-python"
221 fi
222
223 econf \
224 --disable-silent-rules \
225 $(use_enable ncurses consoleui) \
226 $(use_enable gtk gtkui) \
227 $(use_enable gtk sm) \
228 $(use gtk || use_enable nls) \
229 $(use gtk && echo "--enable-nls") \
230 $(use gtk && use_enable xscreensaver screensaver) \
231 $(use gtk && use_enable prediction cap) \
232 $(use gtk && use_enable eds gevolution) \
233 $(use gtk && use_enable spell gtkspell) \
234 $(use_enable perl) \
235 $(use_enable tk) \
236 $(use_enable tcl) \
237 $(use_enable debug) \
238 $(use_enable dbus) \
239 $(use_enable meanwhile) \
240 $(use_enable gstreamer) \
241 $(use_enable gstreamer farstream) \
242 $(use_enable gstreamer vv) \
243 $(use_enable sasl cyrus-sasl ) \
244 $(use_enable doc doxygen) \
245 $(use_enable networkmanager nm) \
246 $(use_enable zeroconf avahi) \
247 $(use_enable idn) \
248 --with-system-ssl-certs="/etc/ssl/certs/" \
249 --with-dynamic-prpls="${DYNAMIC_PRPLS}" \
250 --disable-mono \
251 --x-includes=/usr/include/X11 \
252 ${myconf}
253 #$(use_enable mono) \
254 }
255
256 src_install() {
257 gnome2_src_install
258 if use gtk; then
259 # Fix tray pathes for kde-3.5, e16 (x11-wm/enlightenment) and other
260 # implementations that are not complient with new hicolor theme yet, #323355
261 local pixmapdir
262 for d in 16 22 32 48; do
263 pixmapdir=${D}/usr/share/pixmaps/pidgin/tray/hicolor/${d}x${d}/actions
264 mkdir "${pixmapdir}" || die
265 pushd "${pixmapdir}" >/dev/null || die
266 for f in ../status/*; do
267 ln -s ${f} || die
268 done
269 popd >/dev/null
270 done
271 fi
272 use perl && fixlocalpod
273
274 dodoc finch/plugins/pietray.py
275 docompress -x /usr/share/doc/${PF}/pietray.py
276
277 find "${ED}" -type f -name '*.la' -exec rm -rf '{}' '+' || die "la removal failed"
278 }