[gentoo-commits] repo/gentoo:master commit in: dev-util/umockdev/

[Matt Turner]

commit:     bcdb7a889b1fb50eec9926137df79e614faf6be2
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 30 16:58:27 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jan 30 17:08:00 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bcdb7a88

dev-util/umockdev: Version bump to 0.17.16

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/umockdev/Manifest                |  1 +
 dev-util/umockdev/umockdev-0.17.16.ebuild | 59 +++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index 22b3a230131c..22255d692f1a 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1 +1,2 @@
 DIST umockdev-0.17.15.tar.xz 491152 BLAKE2B 40334a0279e81e1af3eb01acafd85c638e8a04af20e4c5b6b64229d89ffcfa231d6ef9e760d24e0cb957fe654252d18dca8579490e52a4c05769163f8a33ac96 SHA512 722339ae0726b00a4ee5fa428f063c5b59f0bad14a8fe24d97276a55dc66c569289c62c4ee5ebdb75a62339444a35468c8c1a33759d76fdf022a1eb4905c0465
+DIST umockdev-0.17.16.tar.xz 491208 BLAKE2B d653e489285437e1111d8841b3628dc3734e799274e9d334b9200c425d8654a18050e9bab7e290dc12ab12f286a4f492219423d1905965a870d843a1809e9ceb SHA512 5d4a094481510f4466e49766512d0959a5a9d9f5a9b7cbd7719bc94e95d9800760482bf3ea2ee97d2138c89680adb4116964688ae13a07e3c1f0ba8e94230584

diff --git a/dev-util/umockdev/umockdev-0.17.16.ebuild b/dev-util/umockdev/umockdev-0.17.16.ebuild
new file mode 100644
index 000000000000..b562b894a04d
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.17.16.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson-multilib python-any-r1 vala
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/martinpitt/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}