[gentoo-commits] gentoo-x86 commit in dev-util/darcs: ChangeLog darcs-2.1.0.ebuild

[Lennart Kolmodin (kolmodin)]

kolmodin    08/10/19 14:51:08

  Modified:             ChangeLog
  Added:                darcs-2.1.0.ebuild
  Log:
  Bump dev-util/darcs to 2.1.0
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.99                 dev-util/darcs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/darcs/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/darcs/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/darcs/ChangeLog?r1=1.98&r2=1.99

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/darcs/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog	18 Oct 2008 18:05:50 -0000	1.98
+++ ChangeLog	19 Oct 2008 14:51:08 -0000	1.99
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/darcs
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/darcs/ChangeLog,v 1.98 2008/10/18 18:05:50 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/darcs/ChangeLog,v 1.99 2008/10/19 14:51:08 kolmodin Exp $
+
+*darcs-2.1.0 (19 Oct 2008)
+
+  19 Oct 2008; Lennart Kolmodin <kolmodin@g.o> +darcs-2.1.0.ebuild:
+  Version bump
 
   18 Oct 2008; nixnut <nixnut@g.o> darcs-2.0.2.ebuild:
   Stable on ppc wrt bug 239368



1.1                  dev-util/darcs/darcs-2.1.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/darcs/darcs-2.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/darcs/darcs-2.1.0.ebuild?rev=1.1&content-type=text/plain

Index: darcs-2.1.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/darcs/darcs-2.1.0.ebuild,v 1.1 2008/10/19 14:51:08 kolmodin Exp $

inherit base autotools eutils

DESCRIPTION="David's Advanced Revision Control System is yet another replacement for CVS"
HOMEPAGE="http://darcs.net"
MY_P0="${P/_rc/rc}"
MY_P="${MY_P0/_pre/pre}"
SRC_URI="http://darcs.net/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86"
IUSE="doc"

DEPEND=">=net-misc/curl-7.10.2
	>=dev-lang/ghc-6.2.2
	=dev-haskell/quickcheck-1*
	dev-haskell/mtl
	dev-haskell/html
	dev-haskell/http
	dev-haskell/parsec
	dev-haskell/regex-compat
	sys-apps/diffutils
	dev-haskell/network
	dev-haskell/filepath
	sys-libs/zlib
	doc?  ( virtual/latex-base
		>=dev-tex/latex2html-2002.2.1_pre20041025-r1 )"

RDEPEND=">=net-misc/curl-7.10.2
	virtual/mta
	dev-libs/gmp"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if use doc && ! built_with_use -o dev-tex/latex2html png gif; then
		eerror "Building darcs with USE=\"doc\" requires that"
		eerror "dev-tex/latex2html is built with at least one of"
		eerror "USE=\"png\" and USE=\"gif\"."
		die "USE=doc requires dev-tex/latex2html with USE=\"png\" or USE=\"gif\""
	fi
}

src_unpack() {
	base_src_unpack

	cd "${S}/tools"
	epatch "${FILESDIR}/${PN}-1.0.9-bashcomp.patch"

	# On ia64 we need to tone down the level of inlining so we don't break some
	# of the low level ghc/gcc interaction gubbins.
	use ia64 && sed -i 's/-funfolding-use-threshold20//' "${S}/GNUmakefile"

	cd "${S}"
	# Since we've patched the build system:
	eautoreconf
}

src_compile() {
	# use --enable-bytestring?
	econf $(use_with doc docs) \
		  --disable-haskeline \
		  --disable-haskell-zlib \
		|| die "configure failed"
	emake all || die "make failed"
}

src_test() {
	make test
}

src_install() {
	make DESTDIR="${D}" installbin || die "installation failed"
	# The bash completion should be installed in /usr/share/bash-completion/
	# rather than /etc/bash_completion.d/ . Fixes bug #148038.
	insinto "/usr/share/bash-completion" \
		&& doins "${D}/etc/bash_completion.d/darcs" \
		&& rm    "${D}/etc/bash_completion.d/darcs" \
		&& rmdir "${D}/etc/bash_completion.d" \
		&& rmdir "${D}/etc" \
		|| die "fixing location of darcs bash completion failed"
	if use doc; then
		dodoc "${S}/doc/manual/darcs.ps" || die "installing darcs.ps failed"
		dohtml -r "${S}/doc/manual/"* || die "installing darcs manual failed"
	fi
}

pkg_postinst() {
	ewarn "NOTE: in order for the darcs send command to work properly,"
	ewarn "you must properly configure your mail transport agent to relay"
	ewarn "outgoing mail.  For example, if you are using ssmtp, please edit"
	ewarn "/etc/ssmtp/ssmtp.conf with appropriate values for your site."
}