[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.7.902a.ebuild libarchive-2.6.2.ebuild libarchive-2.7.1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/01/05 15:12:21

  Modified:             ChangeLog
  Added:                libarchive-2.7.902a.ebuild
  Removed:              libarchive-2.6.2.ebuild libarchive-2.7.1.ebuild
  Log:
  Bump latest alpha; also drop older versions. New version builds tests in parallel during test phase.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.69                 app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	25 Oct 2009 19:37:08 -0000	1.68
+++ ChangeLog	5 Jan 2010 15:12:20 -0000	1.69
@@ -1,6 +1,14 @@
 # ChangeLog for app-arch/libarchive
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.68 2009/10/25 19:37:08 flameeyes Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.69 2010/01/05 15:12:20 flameeyes Exp $
+
+*libarchive-2.7.902a (05 Jan 2010)
+
+  05 Jan 2010; Diego E. Pettenò <flameeyes@g.o>
+  -libarchive-2.6.2.ebuild, -libarchive-2.7.1.ebuild,
+  +libarchive-2.7.902a.ebuild:
+  Bump latest alpha; also drop older versions. New version builds tests in
+  parallel during test phase.
 
 *libarchive-2.7.1-r1 (25 Oct 2009)
 



1.1                  app-arch/libarchive/libarchive-2.7.902a.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.7.902a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.7.902a.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.7.902a.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.7.902a.ebuild,v 1.1 2010/01/05 15:12:20 flameeyes Exp $

EAPI="2"

inherit eutils libtool toolchain-funcs flag-o-matic

DESCRIPTION="BSD tar command"
HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz
	http://people.freebsd.org/~kientzle/libarchive/src/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="static static-libs acl xattr kernel_linux +bzip2 +lzma +zlib"

COMPRESS_LIBS_DEPEND="lzma? ( app-arch/xz-utils )
		bzip2? ( app-arch/bzip2 )
		zlib? ( sys-libs/zlib )"

RDEPEND="!dev-libs/libarchive
	dev-libs/openssl
	acl? ( virtual/acl )
	xattr? ( kernel_linux? ( sys-apps/attr ) )
	!static? ( ${COMPRESS_LIBS_DEPEND} )"
DEPEND="${RDEPEND}
	${COMPRESS_LIBS_DEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

src_prepare() {
	elibtoolize
	epunt_cxx
}

src_configure() {
	local myconf

	if ! use static ; then
		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
	fi

	# force static libs for static binaries
	if use static && ! use static-libs; then
		myconf="${myconf} --enable-static"
	fi

	# Check for need of this in 2.7.1 and later, on 2.7.0, -Werror was
	# added to the final release, but since it's done in the
	# Makefile.am we can just work it around this way.
	append-flags -Wno-error

	# We disable lzmadec because we support the newer liblzma from xz-utils
	# and not liblzmadec with this version.
	econf --bindir=/bin \
		--enable-bsdtar --enable-bsdcpio \
		$(use_enable acl) $(use_enable xattr) \
		$(use_with zlib) \
		$(use_with bzip2 bz2lib) $(use_with lzma) \
		$(use_enable static-libs static) \
		--without-lzmadec \
		${myconf} \
		--disable-dependency-tracking || die "econf failed."
}

src_test() {
	# Replace the default src_test so that it builds tests in parallel
	emake check || die "tests failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	# remove useless .a and .la files (only for non static compilation)
	use static-libs || find "${D}" \( -name '*.a' -or -name '*.la' \) -delete

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc NEWS README
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}