[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     8155f90caa4b6c9ff3c4aabaa016c90136d78938
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 12 11:31:34 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jun 12 11:32:32 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8155f90c

sys-kernel/gentoo-kernel-bin: bump to 5.4.125 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.125-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 091a315d6f3..7c3dfa5b028 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -94,6 +94,7 @@ DIST gentoo-kernel-5.4.124-1.amd64.xpak 61369250 BLAKE2B 8b39782d1f46585d412cc39
 DIST gentoo-kernel-5.4.124-1.arm64.xpak 56357756 BLAKE2B e2a2f1dc942ef7ea3a6860c86ef345c053ddee412c226a03152af9fd14e4927524cb5b20917d1f3f986583fd3a003dab514b224edca2dd0dd02bb8c470e232cd SHA512 1bd6f4b99abba0a2dd6c76574f17f295db277079ddb7a28b9c1211a2a348e945fdaff9e4c9cdb5fc8882f7df901e1074b7f2ee073a095c6cf0a36baa0885b166
 DIST gentoo-kernel-5.4.124-1.x86.xpak 53172119 BLAKE2B 825a7e78f4dcd27fd8b02c86b06955a00b9dfd99cb9cef91acb3de81ec613e42a949e2916985696b4ba592954c4c777e2a783c5178763d46afe4f19cf2c6ed34 SHA512 8e87fe1273b12246ad3a8df6eb2d8a1ccc8b64358e3d04a216a612be6d27c10a0895de51b3542437afe52694caff1ed038165b3c37ed63794fce1cc1b320e451
 DIST gentoo-kernel-5.4.125-1.amd64.xpak 61394912 BLAKE2B ea62eb77e681dc424c5674e9fba88ce3c351273a9e8580c7787bb8c1ae4b9ccfe341f646590398880078cfe8e1750cb349116c02e1bf9fe46c53ccac9f170dac SHA512 8686d58efd6491e99e9680bb3ca398dfed63507c76c77c03ef3ee1f05d3e739bfd9a6a53b14df2f9200a2365485d42ba20989dec700eca764bf289985cf1f010
+DIST gentoo-kernel-5.4.125-1.arm64.xpak 56377793 BLAKE2B ec11f0815df1cc702a0bf384e91ea103c7926655b64f746598a55a4e7af231780ab69ca64197d500e707e62b377320eb861d236ec624ce5f0af1daff4312d701 SHA512 a74116b40eacb1f349cae3fdc4342b6c64f39926731beff4fd8550f186d46b16c8062b532f3384fdcdd0a2f18997aacc32d5ced0905e5dbca910308020b1751f
 DIST gentoo-kernel-5.4.125-1.x86.xpak 53179979 BLAKE2B 6788fa462f05eb162fd10aa4348b032fc5bb7776ae23aebf6df39ba5b442be2cd7e6c0cc7f8b50816c0d59f0f964cfb6e806a2ac70e7b1553a090e534a8c0f8e SHA512 2191a0ee564549d4ecb0dd9ef622e32c49fe41a84e27b73e425178f02193c69cade6330301c02cf9cec7f44f1e3e3ac3b5828a04f157c6b5c784494add7a0143
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.125-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.125-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.125-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}