[gentoo-commits] gentoo-x86 commit in net-libs/gupnp-igd: metadata.xml gupnp-igd-0.2.4.ebuild ChangeLog gupnp-igd-0.2.3.ebuild

[Pacho Ramos (pacho)]

pacho       14/10/02 11:52:56

  Modified:             metadata.xml ChangeLog
  Added:                gupnp-igd-0.2.4.ebuild
  Removed:              gupnp-igd-0.2.3.ebuild
  Log:
  Version bump, drop old, co-maintain it (as we are in fact doing for some time)
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.4                  net-libs/gupnp-igd/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	4 May 2013 11:50:56 -0000	1.3
+++ metadata.xml	2 Oct 2014 11:52:56 -0000	1.4
@@ -1,9 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <herd>net-p2p</herd>
-  <use>
-    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
-			introspection</flag>
-  </use>
+<herd>gnome</herd>
+<herd>net-p2p</herd>
 </pkgmetadata>



1.61                 net-libs/gupnp-igd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	24 Jun 2014 22:16:31 -0000	1.60
+++ ChangeLog	2 Oct 2014 11:52:56 -0000	1.61
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gupnp-igd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.60 2014/06/24 22:16:31 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.61 2014/10/02 11:52:56 pacho Exp $
+
+*gupnp-igd-0.2.4 (02 Oct 2014)
+
+  02 Oct 2014; Pacho Ramos <pacho@g.o> +gupnp-igd-0.2.4.ebuild,
+  -gupnp-igd-0.2.3.ebuild, metadata.xml:
+  Version bump, drop old, co-maintain it (as we are in fact doing for some time)
 
   24 Jun 2014; Michał Górny <mgorny@g.o> gupnp-igd-0.2.3-r1.ebuild:
   Lower dev-libs/glib dep to first known EAPI=5 version, requested by Funtoo for



1.1                  net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild?rev=1.1&content-type=text/plain

Index: gupnp-igd-0.2.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild,v 1.1 2014/10/02 11:52:56 pacho Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
AUTOTOOLS_AUTORECONF=true

inherit eutils gnome.org python-r1 multilib-minimal

DESCRIPTION="Library to handle UPnP IGD port mapping for GUPnP"
HOMEPAGE="http://gupnp.org"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+introspection python"

RDEPEND="
	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
	>=net-libs/gssdp-0.14.7[${MULTILIB_USEDEP}]
	>=net-libs/gupnp-0.20.10[${MULTILIB_USEDEP}]
	introspection? ( >=dev-libs/gobject-introspection-0.10 )
	python? (
		>=dev-libs/gobject-introspection-0.10
		>=dev-python/pygobject-2.16:2[${PYTHON_USEDEP}]
	)"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	sys-devel/gettext
	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
"

# The only existing test is broken
RESTRICT="test"

PATCHES=(
	"${FILESDIR}"/${PN}-0.1.11-disable_static_modules.patch
)

multilib_src_configure() {
	local myconf=(
		--disable-static
		--disable-gtk-doc
		$(multilib_native_use_enable introspection)
		# python is built separately
		--disable-python
	)

	ECONF_SOURCE=${S} \
	econf "${myconf[@]}"

	if multilib_is_native_abi; then
		ln -s "${S}"/doc/html doc/html || die

		python_configure() {
			mkdir -p "${BUILD_DIR}" || die
			cd "${BUILD_DIR}" || die

			ECONF_SOURCE=${S} \
			econf "${myconf[@]}" \
				--enable-python
		}

		use python && python_parallel_foreach_impl python_configure
	fi
}

multilib_src_compile() {
	default

	if multilib_is_native_abi && use python; then
		local native_builddir=${BUILD_DIR}

		python_compile() {
			emake -C "${BUILD_DIR}"/python \
				VPATH="${S}/python:${native_builddir}/python" \
				igd_la_LIBADD="\$(PYGUPNP_IGD_LIBS) ${native_builddir}/libgupnp-igd/libgupnp-igd-1.0.la"
		}

		python_foreach_impl python_compile
	fi
}

multilib_src_install() {
	default

	if multilib_is_native_abi && use python; then
		local native_builddir=${BUILD_DIR}

		python_install() {
			emake -C "${BUILD_DIR}"/python \
				VPATH="${S}/python:${native_builddir}/python" \
				DESTDIR="${D}" install
		}

		python_foreach_impl python_install
	fi
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files
}