[gentoo-commits] gentoo-x86 commit in net-proxy/c-icap: c-icap-0.2.3-r1.ebuild ChangeLog c-icap-0.2.3.ebuild c-icap-0.1.7-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/12/28 12:42:46

  Modified:             ChangeLog
  Added:                c-icap-0.2.3-r1.ebuild
  Removed:              c-icap-0.2.3.ebuild c-icap-0.1.7-r1.ebuild
  Log:
  Remove old; bump to use new init script (and conf file) that will properly 'use logger' if needed.
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.22                 net-proxy/c-icap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/c-icap/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/c-icap/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/c-icap/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/c-icap/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	4 Dec 2012 11:24:10 -0000	1.21
+++ ChangeLog	28 Dec 2012 12:42:46 -0000	1.22
@@ -1,6 +1,14 @@
 # ChangeLog for net-proxy/c-icap
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/ChangeLog,v 1.21 2012/12/04 11:24:10 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/ChangeLog,v 1.22 2012/12/28 12:42:46 flameeyes Exp $
+
+*c-icap-0.2.3-r1 (28 Dec 2012)
+
+  28 Dec 2012; Diego E. Pettenò <flameeyes@g.o> +c-icap-0.2.3-r1.ebuild,
+  +files/c-icap.conf, +files/c-icap.init.3, -c-icap-0.1.7-r1.ebuild,
+  -c-icap-0.2.3.ebuild:
+  Remove old; bump to use new init script (and conf file) that will properly
+  'use logger' if needed.
 
   04 Dec 2012; <ago@g.o> c-icap-0.2.2.ebuild:
   Stable for x86, wrt bug #441494



1.1                  net-proxy/c-icap/c-icap-0.2.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/c-icap/c-icap-0.2.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/c-icap/c-icap-0.2.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: c-icap-0.2.3-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/c-icap/c-icap-0.2.3-r1.ebuild,v 1.1 2012/12/28 12:42:46 flameeyes Exp $

EAPI=4

inherit eutils multilib flag-o-matic autotools

MY_PN=${PN/-/_}
MY_P=${MY_PN}-${PV}

DESCRIPTION="C Implementation of an ICAP server"
HOMEPAGE="http://c-icap.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="berkdb ipv6 ldap"

RDEPEND="berkdb? ( sys-libs/db )
	ldap? ( net-nds/openldap )
	sys-libs/zlib"
DEPEND="${RDEPEND}"
RDEPEND="${RDEPEND}
	sys-apps/openrc"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.2.3-asneeded.patch"
	epatch "${FILESDIR}/${PN}-0.1.3+db-5.0.patch"
	epatch "${FILESDIR}/${PN}-0.1.4-crosscompile.patch"
	epatch "${FILESDIR}/${PN}-0.1.6-implicit.patch"
	eautoreconf
}

src_configure() {
	# some void *** pointers get casted around and can be troublesome to
	# fix properly.
	append-flags -fno-strict-aliasing

	econf \
		--sysconfdir=/etc/${PN} \
		--disable-dependency-tracking \
		--disable-maintainer-mode \
		--disable-static \
		--enable-large-files \
		$(use_enable ipv6) \
		$(use_with berkdb bdb) \
		$(use_with ldap)
}

src_compile() {
	emake LOGDIR="/var/log"
}

src_install() {
	emake \
		LOGDIR="/var/log" \
		DESTDIR="${D}" install

	find "${D}" -name '*.la' -delete || die

	# Move the daemon out of the way
	dodir /usr/libexec
	mv "${D}"/usr/bin/c-icap "${D}"/usr/libexec || die

	# Remove the default configuration files since we have etc-update to
	# take care of it for us.
	rm "${D}"/etc/${PN}/c-icap.*.default || die

	# Fix the configuration file; for some reason it's a bit messy
	# around.
	sed -i \
		-e 's:/usr/var/:/var/:g' \
		-e 's:/var/log/:/var/log/c-icap/:g' \
		-e 's:/usr/etc/:/etc/c-icap/:g' \
		-e 's:/usr/local/c-icap/etc/:/etc/c-icap/:g' \
		-e 's:/usr/lib/:/usr/'$(get_libdir)'/:g' \
		"${D}"/etc/${PN}/c-icap.conf \
		|| die

	dodoc AUTHORS README TODO ChangeLog

	newinitd "${FILESDIR}/${PN}.init.3" ${PN}
	newconfd "${FILESDIR}/${PN}.conf" ${PN}
	keepdir /var/log/c-icap

	insopts -m0644
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${PN}.logrotate ${PN}

	# avoid triggering portage's symlink protection; this is handled by
	# the init script anyway.
	rm -rf "${D}"/var/run
}

pkg_postinst() {
	elog "To enable Squid to call the ICAP modules from a local server you should set"
	elog "the following in your squid.conf:"
	elog ""
	elog "    icap_enable on"
	elog ""
	elog "    # not strictly needed, but some modules might make use of these"
	elog "    icap_send_client_ip on"
	elog "    icap_send_client_username on"
	elog ""
	elog "    icap_service service_req reqmod_precache bypass=1 icap://localhost:1344/service"
	elog "    adaptation_access service_req allow all"
	elog ""
	elog "    icap_service service_resp respmod_precache bypass=0 icap://localhost:1344/service"
	elog "    adaptation_access service_resp allow all"
	elog ""
	elog "You obviously will have to replace \"service\" with the actual ICAP service to"
	elog "use."
}