[gentoo-commits] gentoo-x86 commit in gnome-extra/nautilus-dropbox: nautilus-dropbox-0.7.1.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/12/24 09:12:08

  Modified:             ChangeLog
  Added:                nautilus-dropbox-0.7.1.ebuild
  Log:
  version bump. Bug #392591. Thanks to b1254633 <b1254633@×××××.com>
  
  (Portage version: 2.2.0_alpha82/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 gnome-extra/nautilus-dropbox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	12 Nov 2011 10:37:27 -0000	1.9
+++ ChangeLog	24 Dec 2011 09:12:08 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/nautilus-dropbox
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog,v 1.9 2011/11/12 10:37:27 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/nautilus-dropbox/ChangeLog,v 1.10 2011/12/24 09:12:08 hwoarang Exp $
+
+*nautilus-dropbox-0.7.1 (24 Dec 2011)
+
+  24 Dec 2011; Markos Chandras <hwoarang@g.o>
+  +nautilus-dropbox-0.7.1.ebuild:
+  version bump. Bug #392591. Thanks to b1254633 <b1254633@×××××.com>
 
 *nautilus-dropbox-0.7.0 (12 Nov 2011)
 



1.1                  gnome-extra/nautilus-dropbox/nautilus-dropbox-0.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.7.1.ebuild?rev=1.1&content-type=text/plain

Index: nautilus-dropbox-0.7.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.7.1.ebuild,v 1.1 2011/12/24 09:12:08 hwoarang Exp $

EAPI="3"
PYTHON_DEPEND="2"
inherit autotools eutils python linux-info gnome2

DESCRIPTION="Store, Sync and Share Files Online"
HOMEPAGE="http://www.dropbox.com/"
SRC_URI="http://www.dropbox.com/download?dl=packages/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-linux"
IUSE="debug"

RDEPEND="gnome-base/nautilus
	dev-libs/glib:2
	dev-python/pygtk:2
	net-misc/dropbox
	x11-libs/gtk+:2
	x11-libs/libnotify
	x11-libs/libXinerama"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-python/docutils"

DOCS="AUTHORS ChangeLog NEWS README"
G2CONF="${G2CONF} $(use_enable debug) --disable-static"

CONFIG_CHECK="~INOTIFY_USER"

pkg_setup () {
	check_extra_config
	enewgroup dropbox
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	gnome2_src_prepare
	python_convert_shebangs 2 dropbox.in

	# use sysem dropbox
	sed -e "s|~/[.]dropbox-dist|/opt/dropbox|" \
		-e 's|\(DROPBOXD_PATH = \).*|\1"/opt/dropbox/dropboxd"|' \
			-i dropbox.in || die
	# us system rst2man
	epatch "${FILESDIR}"/${PN}-0.7.0-system-rst2man.patch
	eautoreconf
}

src_install () {
	gnome2_src_install

	local extensiondir="$(pkg-config --variable=extensiondir libnautilus-extension)"
	[ -z ${extensiondir} ] && die "pkg-config unable to get nautilus extensions dir"

	# Strip $EPREFIX from $extensiondir as fowners/fperms act on $ED not $D
	extensiondir="${extensiondir#${EPREFIX}}"

	find "${ED}" -name '*.la' -exec rm -f {} + || die

	use prefix || fowners root:dropbox "${extensiondir}"/libnautilus-dropbox.so
	fperms o-rwx "${extensiondir}"/libnautilus-dropbox.so
}

pkg_postinst () {
	gnome2_pkg_postinst

	elog
	elog "Add any users who wish to have access to the dropbox nautilus"
	elog "plugin to the group 'dropbox'. You need to setup a drobox account"
	elog "before using this plugin. Visit ${HOMEPAGE} for more information."
	elog
}