1 |
commit: 8002a5549b3cd25d17ef9c2ece1a09dcdd63f76e |
2 |
Author: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org> |
3 |
AuthorDate: Thu Mar 31 14:28:27 2022 +0000 |
4 |
Commit: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org> |
5 |
CommitDate: Thu Mar 31 14:31:03 2022 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8002a554 |
7 |
|
8 |
dev-python/spyder: add 5.3.0 |
9 |
|
10 |
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org> |
11 |
|
12 |
dev-python/spyder/Manifest | 2 + |
13 |
dev-python/spyder/spyder-5.3.0.ebuild | 200 ++++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 202 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest |
17 |
index 988a1df37ace..325e79857241 100644 |
18 |
--- a/dev-python/spyder/Manifest |
19 |
+++ b/dev-python/spyder/Manifest |
20 |
@@ -1,2 +1,4 @@ |
21 |
DIST spyder-5.2.2.tar.gz 23913924 BLAKE2B 40bf968212f4b5d343b59ce6fd069f1e6a0d7f8bccbd3ff6eb76960638e9d4ff8f232a764673a75dcea9d8048ed6a5c36d3bd52719c6773cc26e922f5597e35a SHA512 e88a1332da503fcbd55496b7600a7b7dbfa5aa8d2d248b2f4a6cb4e394c07a38b6681db3ac7c0997ff87984a561f1d794a5bec6492f7c7c131c5cfee55c445b2 |
22 |
+DIST spyder-5.3.0.tar.gz 24404638 BLAKE2B 558c0d1ce8cda61786a772bf7ea471eab69755e3852f5701363b3c52cf1cac388a3800d2e59f266ca9e99007c7096582fbd341956752385b23c3af12ef097204 SHA512 c556deb8bed91ad6c59761e70e1e69f2402a216d8c87a57b3fc55f3624418d95114b015f5fc5baf0cb7e405955cd2ae82372105830b405ea52c50d7329ba7f42 |
23 |
DIST spyder-docs-cd0c65d943595da438410559811a5809bf0227a3.tar.gz 90033347 BLAKE2B 11c17ff2e7fd58ca29c927add366490e0e9a218551b2d5b5be8b2e2eaa955cec52983273bfc3630a9b96a76c5650aa2b36a18a44cbcf78ac624758c8f41ed816 SHA512 d0814775026d76156c5c5a3d3a00b764b0803a71416e72c6b974d60dde0b661f06a4cc0940cd3f391a1903a07ceb078918267d332a94e09773906fec4c15eea2 |
24 |
+DIST spyder-docs-f99196cc267b07fa7ad56f0134744b545fa21fcd.tar.gz 90037460 BLAKE2B 8d279e2c2e397a63919c4ba8723ce674d2c5660793330dc578b9a6e05034af016085faedd73894f16241c0ffe1f734217d9e237f7589e59fe2186511552cefe1 SHA512 6c7d35274fd2f627b3b9371c7a2a9f0446c8aee3754b7c7dda6c5a2b9fd4ab04e73637648a188960c71d43f348c6f9ef1911979fec4c281515937e1069e68500 |
25 |
|
26 |
diff --git a/dev-python/spyder/spyder-5.3.0.ebuild b/dev-python/spyder/spyder-5.3.0.ebuild |
27 |
new file mode 100644 |
28 |
index 000000000000..b12d9ce717ad |
29 |
--- /dev/null |
30 |
+++ b/dev-python/spyder/spyder-5.3.0.ebuild |
31 |
@@ -0,0 +1,200 @@ |
32 |
+# Copyright 1999-2022 Gentoo Authors |
33 |
+# Distributed under the terms of the GNU General Public License v2 |
34 |
+ |
35 |
+EAPI=8 |
36 |
+ |
37 |
+PYTHON_COMPAT=( python3_{8..10} ) |
38 |
+DISTUTILS_USE_PEP517=setuptools |
39 |
+ |
40 |
+inherit optfeature xdg distutils-r1 |
41 |
+ |
42 |
+# Commit of documentation to fetch |
43 |
+DOCS_PV="f99196cc267b07fa7ad56f0134744b545fa21fcd" |
44 |
+ |
45 |
+DESCRIPTION="The Scientific Python Development Environment" |
46 |
+HOMEPAGE=" |
47 |
+ https://www.spyder-ide.org/ |
48 |
+ https://github.com/spyder-ide/spyder/ |
49 |
+ https://pypi.org/project/spyder/ |
50 |
+" |
51 |
+SRC_URI=" |
52 |
+ https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz |
53 |
+ https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz |
54 |
+" |
55 |
+ |
56 |
+LICENSE="MIT" |
57 |
+SLOT="0" |
58 |
+KEYWORDS="~amd64 ~x86" |
59 |
+ |
60 |
+# The test suite often hangs or does not work. Technically spyder requires |
61 |
+# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason |
62 |
+# many of the tests fail or hang. RESTRICTing because IMO it is not worth the |
63 |
+# several hours I spend every single version bump checking which tests do and |
64 |
+# do not work. Spyder itself works fine with pyqt5>13. |
65 |
+RESTRICT="test" |
66 |
+ |
67 |
+RDEPEND=" |
68 |
+ >=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}] |
69 |
+ >=dev-python/chardet-2.0.0[${PYTHON_USEDEP}] |
70 |
+ >=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}] |
71 |
+ >=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}] |
72 |
+ >=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}] |
73 |
+ >=dev-python/jellyfish-0.7[${PYTHON_USEDEP}] |
74 |
+ >=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}] |
75 |
+ >=dev-python/keyring-17.0.0[${PYTHON_USEDEP}] |
76 |
+ >=dev-python/nbconvert-4.0[${PYTHON_USEDEP}] |
77 |
+ >=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}] |
78 |
+ >=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}] |
79 |
+ >=dev-python/pickleshare-0.4[${PYTHON_USEDEP}] |
80 |
+ >=dev-python/psutil-5.3[${PYTHON_USEDEP}] |
81 |
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}] |
82 |
+ >=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}] |
83 |
+ >=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}] |
84 |
+ >=dev-python/pyxdg-0.26[${PYTHON_USEDEP}] |
85 |
+ >=dev-python/pyzmq-17[${PYTHON_USEDEP}] |
86 |
+ >=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}] |
87 |
+ <dev-python/qdarkstyle-3.1.0[${PYTHON_USEDEP}] |
88 |
+ >=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}] |
89 |
+ >=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}] |
90 |
+ >=dev-python/qtconsole-5.3.0[${PYTHON_USEDEP}] |
91 |
+ <dev-python/qtconsole-5.4.0[${PYTHON_USEDEP}] |
92 |
+ >=dev-python/QtPy-2.0.1[${PYTHON_USEDEP},svg,webengine] |
93 |
+ >=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}] |
94 |
+ >=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}] |
95 |
+ >=dev-python/spyder-kernels-2.3.0[${PYTHON_USEDEP}] |
96 |
+ <dev-python/spyder-kernels-2.4.0[${PYTHON_USEDEP}] |
97 |
+ >=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}] |
98 |
+ >=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}] |
99 |
+ >=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}] |
100 |
+" |
101 |
+ |
102 |
+BDEPEND=" |
103 |
+ test? ( |
104 |
+ dev-python/cython[${PYTHON_USEDEP}] |
105 |
+ dev-python/flaky[${PYTHON_USEDEP}] |
106 |
+ dev-python/matplotlib[tk,${PYTHON_USEDEP}] |
107 |
+ dev-python/pandas[${PYTHON_USEDEP}] |
108 |
+ dev-python/pillow[${PYTHON_USEDEP}] |
109 |
+ dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}] |
110 |
+ dev-python/pytest-mock[${PYTHON_USEDEP}] |
111 |
+ dev-python/pytest-ordering[${PYTHON_USEDEP}] |
112 |
+ <dev-python/pytest-qt-4[${PYTHON_USEDEP}] |
113 |
+ dev-python/pytest-xvfb[${PYTHON_USEDEP}] |
114 |
+ dev-python/pyyaml[${PYTHON_USEDEP}] |
115 |
+ dev-python/scipy[${PYTHON_USEDEP}] |
116 |
+ dev-python/sympy[${PYTHON_USEDEP}] |
117 |
+ )" |
118 |
+ |
119 |
+# Based on the courtesy of Arfrever |
120 |
+# This patch removes a call to update-desktop-database during build |
121 |
+# This fails because access is denied to this command during build |
122 |
+PATCHES=( |
123 |
+ "${FILESDIR}/${PN}-5.0.0-build.patch" |
124 |
+ "${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch" |
125 |
+) |
126 |
+ |
127 |
+DOCS=( |
128 |
+ "AUTHORS.txt" |
129 |
+ "Announcements.md" |
130 |
+ "CHANGELOG.md" |
131 |
+ "CODE_OF_CONDUCT.md" |
132 |
+ "CONTRIBUTING.md" |
133 |
+ "NOTICE.txt" |
134 |
+ "README.md" |
135 |
+ "RELEASE.md" |
136 |
+) |
137 |
+ |
138 |
+distutils_enable_tests pytest |
139 |
+distutils_enable_sphinx docs/doc \ |
140 |
+ dev-python/sphinx-panels \ |
141 |
+ dev-python/pydata-sphinx-theme \ |
142 |
+ dev-python/sphinx-multiversion |
143 |
+ |
144 |
+python_prepare_all() { |
145 |
+ # move docs into workdir |
146 |
+ mv ../spyder-docs-${DOCS_PV}* docs || die |
147 |
+ |
148 |
+ # these dependencies are packaged separately: |
149 |
+ # dev-python/spyder-kernels, |
150 |
+ # dev-python/python-lsp-server, |
151 |
+ # dev-python/qdarkstyle |
152 |
+ rm -r external-deps/* || die |
153 |
+ # runs against things packaged in external-deps dir |
154 |
+ rm conftest.py || die |
155 |
+ |
156 |
+ # Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5] |
157 |
+ # Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine] |
158 |
+ # Do not depend on parso and jedi, this is dependency is carried in python-lsp-server |
159 |
+ # Do not depend on python-lsp-server, this dependency is carried in pyls-spyder |
160 |
+ # The explicit version requirements only make things more complicated, if e.g. |
161 |
+ # pyls-spyder gains compatibility with a newer version of python-lsp-server |
162 |
+ # in a new release it will take time for this information to propagate into |
163 |
+ # the next spyder release. So just remove the dependency and let the other |
164 |
+ # ebuilds handle the version requirements to speed things up and prevent |
165 |
+ # issues such as Bug 803269. |
166 |
+ sed -i \ |
167 |
+ -e '/pyqt5/d' \ |
168 |
+ -e '/pyqtwebengine/d' \ |
169 |
+ -e '/python-lsp-server/d' \ |
170 |
+ -e '/parso/d' \ |
171 |
+ -e '/jedi/d' \ |
172 |
+ -e '/pylint/d' \ |
173 |
+ requirements/conda.txt || die |
174 |
+ sed -i \ |
175 |
+ -e "/'pyqt5[ 0-9<=>.,]*',/d" \ |
176 |
+ -e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \ |
177 |
+ -e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \ |
178 |
+ -e "/'parso[ 0-9<=>.,]*',/d" \ |
179 |
+ -e "/'jedi[ 0-9<=>.,]*',/d" \ |
180 |
+ -e "/'pylint[ 0-9<=>.,]*',/d" \ |
181 |
+ setup.py || die |
182 |
+ sed -i \ |
183 |
+ -e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \ |
184 |
+ -e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \ |
185 |
+ -e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \ |
186 |
+ -e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \ |
187 |
+ -e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \ |
188 |
+ spyder/dependencies.py || die |
189 |
+ |
190 |
+ # do not check deps, fails because we removed dependencies above |
191 |
+ sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \ |
192 |
+ spyder/tests/test_dependencies_in_sync.py || die |
193 |
+ |
194 |
+ # can't check for update, need network |
195 |
+ rm spyder/workers/tests/test_update.py || die |
196 |
+ |
197 |
+ # skip online test |
198 |
+ rm spyder/widgets/github/tests/test_github_backend.py || die |
199 |
+ |
200 |
+ distutils-r1_python_prepare_all |
201 |
+} |
202 |
+ |
203 |
+# Calling pytest directly makes the tests freeze after completing even if successful |
204 |
+# Exit code is nonzero even upon success, so can't add || die here test results |
205 |
+# should be checked for success manually |
206 |
+python_test() { |
207 |
+ "${EPYTHON}" runtests.py |
208 |
+} |
209 |
+ |
210 |
+pkg_postinst() { |
211 |
+ xdg_pkg_postinst |
212 |
+ |
213 |
+ optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib |
214 |
+ optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas |
215 |
+ optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy |
216 |
+ optfeature "Symbolic mathematics in the IPython console" dev-python/sympy |
217 |
+ optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy |
218 |
+ optfeature "Run Cython files in the IPython console" dev-python/cython |
219 |
+ optfeature "The hdf5/h5py plugin" dev-python/h5py |
220 |
+ # optfeature "The line profiler plugin" dev-python/spyder-line-profiler |
221 |
+ # optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler |
222 |
+ # spyder-autopep8 does not have a release (yet) |
223 |
+ # and are not compatible with >=spyder-4.0.0 at the moment |
224 |
+ # optfeature "The autopep8 plugin" dev-python/spyder-autopep8 |
225 |
+ # optfeature "Vim key bindings" dev-python/spyder-vim |
226 |
+ optfeature "Unittest support" dev-python/spyder-unittest |
227 |
+ # optfeature "Jupyter notebook support" dev-python/spyder-notebook |
228 |
+ optfeature "System terminal inside spyder" dev-python/spyder-terminal |
229 |
+ # spyder-reports not yet updated to >=spyder-4.0.0 |
230 |
+ # optfeature "Markdown reports using Pweave" dev-python/spyder-reports |
231 |
+} |