[gentoo-commits] gentoo-x86 commit in net-misc/dhcpcd: dhcpcd-5.99.6.ebuild ChangeLog dhcpcd-9999.ebuild

[William Hubbs (williamh)]

williamh    13/06/04 01:30:38

  Modified:             ChangeLog dhcpcd-9999.ebuild
  Added:                dhcpcd-5.99.6.ebuild
  Log:
  version bump and sync live ebuild. Also drop the zeroconf use flag since I was advised that use flags should not manipulate configuration files.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

Revision  Changes    Path
1.356                net-misc/dhcpcd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/ChangeLog?rev=1.356&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/ChangeLog?rev=1.356&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/ChangeLog?r1=1.355&r2=1.356

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v
retrieving revision 1.355
retrieving revision 1.356
diff -u -r1.355 -r1.356
--- ChangeLog	23 Apr 2013 22:58:25 -0000	1.355
+++ ChangeLog	4 Jun 2013 01:30:38 -0000	1.356
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/dhcpcd
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v 1.355 2013/04/23 22:58:25 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v 1.356 2013/06/04 01:30:38 williamh Exp $
+
+*dhcpcd-5.99.6 (04 Jun 2013)
+
+  04 Jun 2013; William Hubbs <williamh@g.o> +dhcpcd-5.99.6.ebuild,
+  dhcpcd-9999.ebuild:
+  version bump and sync live ebuild. Also drop the zeroconf use flag since I
+  was advised that use flags should not manipulate configuration files.
 
 *dhcpcd-5.6.8 (23 Apr 2013)
 



1.4                  net-misc/dhcpcd/dhcpcd-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild?r1=1.3&r2=1.4

Index: dhcpcd-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- dhcpcd-9999.ebuild	23 Apr 2013 22:58:25 -0000	1.3
+++ dhcpcd-9999.ebuild	4 Jun 2013 01:30:38 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild,v 1.3 2013/04/23 22:58:25 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/dhcpcd-9999.ebuild,v 1.4 2013/06/04 01:30:38 williamh Exp $
 
 EAPI=5
 
@@ -22,7 +22,7 @@
 HOMEPAGE="http://roy.marples.name/projects/dhcpcd/"
 LICENSE="BSD-2"
 SLOT="0"
-IUSE="+zeroconf elibc_glibc"
+IUSE="elibc_glibc"
 
 DEPEND=""
 RDEPEND=""
@@ -30,14 +30,6 @@
 src_prepare()
 {
 	epatch_user
-	if ! use zeroconf; then
-		elog "Disabling zeroconf support"
-		{
-			echo
-			echo "# dhcpcd ebuild requested no zeroconf"
-			echo "noipv4ll"
-		} >> dhcpcd.conf
-	fi
 }
 
 src_configure()
@@ -59,11 +51,6 @@
 	systemd_dounit "${FILESDIR}"/${PN}.service
 }
 
-pkg_preinst()
-{
-	has_version 'net-misc/dhcpcd[zeroconf]' && prev_zero=true || prev_zero=false
-}
-
 pkg_postinst()
 {
 	# Upgrade the duid file to the new format if needed
@@ -78,12 +65,18 @@
 		cp -p "${old_duid}" "${new_duid}"
 	fi
 
-	if use zeroconf && ! $prev_zero; then
-		elog "You have installed dhcpcd with zeroconf support."
-		elog "This means that it will always obtain an IP address even if no"
-		elog "DHCP server can be contacted, which will break any existing"
-		elog "failover support you may have configured in your net configuration."
-		elog "This behaviour can be controlled with the -L flag."
-		elog "See the dhcpcd man page for more details."
+	elog
+	elog "dhcpcd has zeroconf support active by default."
+	elog "This means it will always obtain an IP address even if no"
+	elog "DHCP server can be contacted, which will break any existing"
+	elog "failover support you may have configured in your net configuration."
+	elog "This behaviour can be controlled with the noipv4ll configuration"
+	elog "file option or the -L command line switch."
+	elog "See the dhcpcd and dhcpcd.conf man pages for more details."
+
+	if ! has_version net-dns/bind-tools; then
+		elog
+		elog "If you activate the lookup-hostname hook to look up your hostname"
+		elog "using the dns, you need to install net-dns/bind-tools."
 	fi
 }



1.1                  net-misc/dhcpcd/dhcpcd-5.99.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.99.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.99.6.ebuild?rev=1.1&content-type=text/plain

Index: dhcpcd-5.99.6.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.99.6.ebuild,v 1.1 2013/06/04 01:30:38 williamh Exp $

EAPI=5

if [[ ${PV} == "9999" ]]; then
	EGIT_REPO_URI="git://roy.marples.name/${PN}.git"
	inherit git-2
else
	MY_P="${P/_alpha/-alpha}"
	MY_P="${MY_P/_beta/-beta}"
	MY_P="${MY_P/_rc/-rc}"
	SRC_URI="http://roy.marples.name/downloads/${PN}/${MY_P}.tar.bz2"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
	S="${WORKDIR}/${MY_P}"
fi

inherit eutils systemd

DESCRIPTION="A fully featured, yet light weight RFC2131 compliant DHCP client"
HOMEPAGE="http://roy.marples.name/projects/dhcpcd/"
LICENSE="BSD-2"
SLOT="0"
IUSE="elibc_glibc"

DEPEND=""
RDEPEND=""

src_prepare()
{
	epatch_user
}

src_configure()
{
	local hooks="--with-hook=ntp.conf"
	use elibc_glibc && hooks="${hooks} --with-hook=yp.conf"
	econf \
			--prefix="${EPREFIX}" \
			--libexecdir="${EPREFIX}/lib/dhcpcd" \
			--dbdir="${EPREFIX}/var/lib/dhcpcd" \
		--localstatedir="${EPREFIX}/var" \
		${hooks}
}

src_install()
{
	default
	newinitd "${FILESDIR}"/${PN}.initd ${PN}
	systemd_dounit "${FILESDIR}"/${PN}.service
}

pkg_postinst()
{
	# Upgrade the duid file to the new format if needed
	local old_duid="${ROOT}"/var/lib/dhcpcd/dhcpcd.duid
	local new_duid="${ROOT}"/etc/dhcpcd.duid
	if [ -e "${old_duid}" ] && ! grep -q '..:..:..:..:..:..' "${old_duid}"; then
		sed -i -e 's/\(..\)/\1:/g; s/:$//g' "${old_duid}"
	fi

	# Move the duid to /etc, a more sensible location
	if [ -e "${old_duid}" -a ! -e "${new_duid}" ]; then
		cp -p "${old_duid}" "${new_duid}"
	fi

	elog
	elog "dhcpcd has zeroconf support active by default."
	elog "This means it will always obtain an IP address even if no"
	elog "DHCP server can be contacted, which will break any existing"
	elog "failover support you may have configured in your net configuration."
	elog "This behaviour can be controlled with the noipv4ll configuration"
	elog "file option or the -L command line switch."
	elog "See the dhcpcd and dhcpcd.conf man pages for more details."

	if ! has_version net-dns/bind-tools; then
		elog
		elog "If you activate the lookup-hostname hook to look up your hostname"
		elog "using the dns, you need to install net-dns/bind-tools."
	fi
}