[gentoo-commits] gentoo-x86 commit in dev-python/pyfits: pyfits-3.2.2.ebuild ChangeLog pyfits-3.2.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    14/05/06 15:56:56

  Modified:             ChangeLog
  Added:                pyfits-3.2.2.ebuild
  Removed:              pyfits-3.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.48                 dev-python/pyfits/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyfits/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyfits/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyfits/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pyfits/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	10 Mar 2014 17:54:49 -0000	1.47
+++ ChangeLog	6 May 2014 15:56:56 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pyfits
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/ChangeLog,v 1.47 2014/03/10 17:54:49 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/ChangeLog,v 1.48 2014/05/06 15:56:56 bicatali Exp $
+
+*pyfits-3.2.2 (06 May 2014)
+
+  06 May 2014; Sébastien Fabbro <bicatali@g.o> +pyfits-3.2.2.ebuild,
+  -pyfits-3.2.ebuild:
+  Version bump
 
 *pyfits-3.2.1 (10 Mar 2014)
 



1.1                  dev-python/pyfits/pyfits-3.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyfits/pyfits-3.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyfits/pyfits-3.2.2.ebuild?rev=1.1&content-type=text/plain

Index: pyfits-3.2.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/pyfits-3.2.2.ebuild,v 1.1 2014/05/06 15:56:56 bicatali Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit distutils-r1 eutils multilib

DESCRIPTION="Provides an interface to FITS formatted files under python"
HOMEPAGE="http://www.stsci.edu/resources/software_hardware/pyfits"
SRC_URI="mirror://pypi/p/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="doc test"

RDEPEND="
	dev-python/numpy[${PYTHON_USEDEP}]
	!<dev-python/astropy-0.3
	sci-libs/cfitsio:0="
DEPEND="${RDEPEND}
	>=dev-python/d2to1-0.2.5[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	>=dev-python/stsci-distutils-0.3[${PYTHON_USEDEP}]
	doc? (
			dev-python/matplotlib
			dev-python/numpydoc
			dev-python/sphinxcontrib-programoutput
			dev-python/stsci-sphinxext
		 )
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"

PATCHES=( "${FILESDIR}"/${PN}-3.2.1-unbundle-cfitsio.patch )

python_prepare_all() {
	sed -i \
		-e "s/\(hook_package_dir = \)lib/\1$(get_libdir)/g" \
		"${S}"/setup.cfg || die
	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	cd "${BUILD_DIR}"/lib* || die
	nosetests || die
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html )
	distutils-r1_python_install_all
	dodoc FAQ.txt CHANGES.txt
	rename_binary() {
		local binary
		for binary in "${ED}"/usr/bin/* "${D}$(python_get_scriptdir)"/*
		do
			mv ${binary}{,-${PN}} || die "failed renaming"
		done
	}
	python_foreach_impl rename_binary
}