[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream-glib/

[Matt Turner]

commit:     2afca2ff37835ea702abee03122204ebb54afb69
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  6 15:36:00 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Nov  6 18:25:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2afca2ff

dev-libs/appstream-glib: Version bump to 0.8.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/appstream-glib/Manifest                   |  1 +
 .../appstream-glib/appstream-glib-0.8.2.ebuild     | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-libs/appstream-glib/Manifest b/dev-libs/appstream-glib/Manifest
index d33923c1aa9a..c232ef7e06a3 100644
--- a/dev-libs/appstream-glib/Manifest
+++ b/dev-libs/appstream-glib/Manifest
@@ -1 +1,2 @@
 DIST appstream-glib-0.8.1.tar.xz 2320596 BLAKE2B de8d68c541cd6700fff0bc22a71d59510ccf584ac1380e2aed3e5aa122825cb3087d65b42ac1dc35acbd4b171382d9560545cdeaffa9d6bda721784444bf7a36 SHA512 32462a32ea25c945abb8d9084af1c84850f264b3a2136c6f54444e0168acf0d74ee450f8cbf483a504e417dc29b85a2e9bbc0a5bb8a217296eccacaa02db5ef5
+DIST appstream-glib-0.8.2.tar.xz 2320880 BLAKE2B 6c3c90298ae8bf362caea8c46643afaaab0bb0071271f5244eeca9356ed96a6a956c1b2ffa4a8500201e4bc494a54a15b3db4937b81c6f5f8b80f83299ac58ee SHA512 c9c21049ab43f5da8595aa07a3c2e097163a05b5e0fc030e4e3326136cd18127f04ad9edf08c12aea823b89048b43808cc60759cc26fcf2541cd9c1acbb29e28

diff --git a/dev-libs/appstream-glib/appstream-glib-0.8.2.ebuild b/dev-libs/appstream-glib/appstream-glib-0.8.2.ebuild
new file mode 100644
index 000000000000..27c3f6959920
--- /dev/null
+++ b/dev-libs/appstream-glib/appstream-glib-0.8.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg meson
+
+DESCRIPTION="Provides GObjects and helper methods to read and write AppStream metadata"
+HOMEPAGE="https://people.freedesktop.org/~hughsient/appstream-glib/ https://github.com/hughsie/appstream-glib"
+SRC_URI="https://people.freedesktop.org/~hughsient/${PN}/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/8" # soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="gtk-doc fonts +introspection stemmer"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	sys-apps/util-linux
+	app-arch/libarchive:=
+	>=net-misc/curl-7.56.0
+	>=dev-libs/json-glib-1.1.2
+	>=x11-libs/gdk-pixbuf-2.31.5:2[introspection?]
+
+	fonts? (
+		x11-libs/gtk+:3
+		>=media-libs/freetype-2.4:2
+	)
+	>=media-libs/fontconfig-2.11:1.0
+	dev-libs/libyaml
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	dev-util/gperf
+
+	dev-libs/libxml2:2
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.9
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+"
+
+src_configure() {
+	local emesonargs=(
+		-Ddep11=true
+		-Dbuilder=true
+		-Drpm=false
+		-Dalpm=false
+		$(meson_use fonts)
+		$(meson_use stemmer)
+		-Dman=true
+		$(meson_use gtk-doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}