[gentoo-commits] gentoo-x86 commit in dev-python/boto3: boto3-1.1.1.ebuild metadata.xml ChangeLog

[Alex Brandt (alunduil)]

alunduil    15/07/29 18:53:19

  Added:                boto3-1.1.1.ebuild metadata.xml ChangeLog
  Log:
  add version 1.1.1
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 11A8217C!)

Revision  Changes    Path
1.1                  dev-python/boto3/boto3-1.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/boto3-1.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/boto3-1.1.1.ebuild?rev=1.1&content-type=text/plain

Index: boto3-1.1.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/boto3/boto3-1.1.1.ebuild,v 1.1 2015/07/29 18:53:19 alunduil Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 python3_3 python3_4 )

inherit distutils-r1 vcs-snapshot

DESCRIPTION="The AWS SDK for Python"
HOMEPAGE="https://github.com/boto/boto3"
SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc test"

CDEPEND="
	>=dev-python/botocore-1.1.0[${PYTHON_USEDEP}]
	<dev-python/botocore-1.2.0[${PYTHON_USEDEP}]
	>=dev-python/jmespath-0.6.2[${PYTHON_USEDEP}]
	<dev-python/jmespath-1.0.0[${PYTHON_USEDEP}]
	$(python_gen_cond_dep '=dev-python/futures-2.2.0[${PYTHON_USEDEP}]' 'python2_7')
"
DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? (
		>=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
		<dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
		>=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
	)
	test? (
		${CDEPEND}
		dev-python/mock[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
	)
"
RDEPEND="${CDEPEND}"

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	nosetests tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html/. )

	distutils-r1_python_install_all
}



1.1                  dev-python/boto3/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>alunduil@g.o</email>
		<name>Alex Brandt</name>
	</maintainer>
	<longdescription lang="en">
	</longdescription>
</pkgmetadata>



1.1                  dev-python/boto3/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/boto3/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-python/boto3
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/boto3/ChangeLog,v 1.1 2015/07/29 18:53:19 alunduil Exp $

*boto3-1.1.1 (29 Jul 2015)

  29 Jul 2015; Alex Brandt <alunduil@g.o> +boto3-1.1.1.ebuild,
  +metadata.xml:
  add version 1.1.1