[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     bbb2ee478b606d8e6f76502bdee0ae602e791599
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun May 30 00:16:22 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun May 30 00:16:22 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bbb2ee47

sys-kernel/gentoo-kernel-bin: bump to 5.12.8 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.12.8-r1.ebuild             | 115 +++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 4097c8ecfe2..53613b4c2e9 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -51,6 +51,7 @@ DIST gentoo-kernel-5.12.7-1.amd64.xpak 66367675 BLAKE2B bd18556dd73a9eaf2f737376
 DIST gentoo-kernel-5.12.7-1.arm64.xpak 60178910 BLAKE2B 602a7ee863d43a0d9d40fac9a34f0a5506f154fca66e4749fae1abb380c8b841986af40cf120d6cd0f01804b6fe9f45954b3d4b884e4eedc15e60a2e8b9ad136 SHA512 c673db22709b7fbebb02aee347a71e534a1df97e324345dd9418fe687eeaca61a672740b84eda7e0531a5a3eb6d42310ff78681cb1670d9d6918b83cc82b43e6
 DIST gentoo-kernel-5.12.7-1.x86.xpak 58091403 BLAKE2B d4648d72e421aa8a2e85529e83394b8ac788a17eaef70d0e19f29c3f3d2272c3dbc914f4ab66c3137c9ff6c84b76b59711670eaec9f46cc93ca932335c8b6c23 SHA512 315bfe67d1aecbd16d91364eae039598f1d7886be4e42a1808fec3668372dcbfdfdbe3ed445c20035d0a799e83e03fc0f03e43f9855e1f87c79c8be0d41ba3d9
 DIST gentoo-kernel-5.12.8-1.amd64.xpak 66367297 BLAKE2B adadd41d205de9376e4f2c7c1354e692f04050940dc2d98d0b0381c8d45b2bb6b63a79c797dc31c9b9374f6d6d1533a5e2c30a3a9c2d0a389179ae75ed732ab8 SHA512 6b9bc14c4ebf757f14cbcba1c1190fb6329891af4558c5d9705a946aa36adc514bdcbd352f044c57c2026f4619def0720106dbb0e7aaec545e894cd1bc25697a
+DIST gentoo-kernel-5.12.8-1.arm64.xpak 59934047 BLAKE2B f2ecf71fe91aaad771ef380e029d419114dc13133a1021d378dd89c70ea3f31b88e445da2a110bff43d43c75446fbfce753aa13008977f2a9f795d1c767507e5 SHA512 cb0fe3d3937739dd2f218d895f6c9185f71606d3016a15020703e03e97d2903a0b3865a0751811f6771f9a367f68e0fc36a56b667cf21ae2e673e6e86d934114
 DIST gentoo-kernel-5.12.8-1.x86.xpak 58087343 BLAKE2B 11d7693cf474bf9b736e2c347831da8208475c1ecc09a9a974fb4512f941c98108379bbca25011a2f2dfb7a229a69a39c69e5687947744edf20e3e6d7193b0c3 SHA512 409aeefe20ed363b7b7bf944707c884c963afb7054767ba6793ad889ac3edfc698234d8b8bef2e7ab708c529178905ce7aec877e3c35e3976545b4aa0e5ab838
 DIST gentoo-kernel-5.4.115-1.amd64.xpak 61381562 BLAKE2B e36468cb61a73daffd9709bc8e13eb1c11a0ec1e8f68df55c07eaa50e7538337534ca48342b019b308c99c121628f55c868a5577b2c1a5a4a67cdd72a6fea8ef SHA512 5bb1836cfd7b746aa5d8e947d6fe63c368f86a0d439e56106a77b3f3c3999d3761f238bfd76b5785035ff68869da271a2c3a4dfb5f09fb16b343e0d296ad9d60
 DIST gentoo-kernel-5.4.115-1.arm64.xpak 56473345 BLAKE2B ba662f7d08629dc4fd8978de1db9f0f4400cde21802590a168f9737da03013e27c09a5ecbadcc99f482c935f20db61f9395bc006390b46bea45af305f1677620 SHA512 2ee5adf31d0a8c2bfa76cfadd5c56e818cf31cea3323c91517cd752ce4c87256c2a4f33583119977e37538669d5e2046f77fdd0b9c6adf15ccc498e7179a2088

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.8-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.8-r1.ebuild
new file mode 100644
index 00000000000..9cc54d1c175
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.8-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}