[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

[Matt Turner]

commit:     3969703b2768a294ac2972154bc4cfe09961aa6a
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 18 03:55:31 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 18 04:20:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3969703b

gnome-extra/gnome-software: Version bump to 40.0

* Add IUSE=flatpak (bug #754282)

Closes: https://bugs.gentoo.org/754282
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-40.0.ebuild      | 103 +++++++++++++++++++++
 gnome-extra/gnome-software/metadata.xml            |   2 +
 3 files changed, 106 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 10c440e0699..2450a7abf4a 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-software-3.34.2.tar.xz 5945736 BLAKE2B 89e7e0a606a832aedbfa32024f201e71b3edb3c8df527efea1be72236b4bfb86901f3af689b10bf706f9c4f16e6badc00080a1244ce30eb09dfd1dad5833e8cf SHA512 4deb09530fbeeadd54e69d03ef4cecaef47c6766bce0ec5230bb090d27e54664577a227416933b6ec4780249f4565e51202a25517fba5dd040fd895bd3a26397
 DIST gnome-software-3.36.1.tar.xz 8277796 BLAKE2B bf3d5f3f67b211cfd4af87ae500691085ab83aed9f85e211972d408a1bfa5d7c6de162acc2088bf9ba9323369e73dba27a06b2491745ef2ceb04943e4acbf72d SHA512 7d0e8c16192bbbc8f166db137dbd2e6ff9e85f7d3d37f63f41211ba3838e392bd87a8d9bf09d31b43f6d21e1a099ecdeff9114ae27fae40d563671f0bcbe50d4
+DIST gnome-software-40.0.tar.xz 3087252 BLAKE2B 4b834113c0770a3acfbcf21b5db3d6da57a885e6b235c3328947f218f28daf70c6f636253283dd77d0c4a1fc59f8ac66a140412694a61352147c13c27e7a76af SHA512 052c520ab25af4257bb978aaa9e1c7a555f8d24dbd782d9f12f3c3def22e65588d3c76d16e4b3dc26f034a762c2ee3e773026b158d468e9e169369dc3d156a2a

diff --git a/gnome-extra/gnome-software/gnome-software-40.0.ebuild b/gnome-extra/gnome-software/gnome-software-40.0.ebuild
new file mode 100644
index 00000000000..c81ec02d2b5
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-40.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc packagekit spell sysprof udev"
+RESTRICT="test" # writes to and deletes files in /var/tmp/self-test/
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.22.4:3
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/json-glib-1.2.0
+	>=net-libs/libsoup-2.52.0:2.4
+	>=gui-libs/libhandy-1.0.2:1=
+	sysprof? ( >=dev-util/sysprof-capture-3.38.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	spell? ( app-text/gspell:= )
+	sys-auth/polkit
+	packagekit? ( >=app-admin/packagekit-base-1.1.0 )
+	firmware? ( >=sys-apps/fwupd-1.0.3 )
+	flatpak? (
+		>=sys-apps/flatpak-1.0.4
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+"
+# test? ( dev-util/valgrind )
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+	# Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+	# TODO: Investigate; seems to work outside ebuild .. test/emerge
+	sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dtests=false #$(meson_use test tests)
+		$(meson_use spell gspell)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		$(meson_use packagekit)
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dodrs=false
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		-Dvalgrind=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_popular=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+	)
+	meson_src_configure
+}
+
+#src_test() {
+#	virtx meson_src_test
+#}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

diff --git a/gnome-extra/gnome-software/metadata.xml b/gnome-extra/gnome-software/metadata.xml
index 92751ac281c..827a2d6f77a 100644
--- a/gnome-extra/gnome-software/metadata.xml
+++ b/gnome-extra/gnome-software/metadata.xml
@@ -7,6 +7,8 @@
 	</maintainer>
 	<use>
 		<flag name="firmware">Enable firmware update support through <pkg>sys-apps/fwupd</pkg></flag>
+		<flag name="flatpak">Enable support for flatpak applications using <pkg>sys-apps/flatpak</pkg></flag>
 		<flag name="packagekit">Enable module for package manager integration</flag>
+		<flag name="sysprof">Enable profiling data capture support using <pkg>dev-util/sysprof-capture</pkg></flag>
 	</use>
 </pkgmetadata>