[gentoo-commits] gentoo-x86 commit in media-video/gnome-mplayer: ChangeLog gnome-mplayer-1.0.5.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/01/03 15:53:58

  Modified:             ChangeLog
  Added:                gnome-mplayer-1.0.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 media-video/gnome-mplayer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	22 Dec 2011 13:01:38 -0000	1.67
+++ ChangeLog	3 Jan 2012 15:53:58 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gnome-mplayer
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.67 2011/12/22 13:01:38 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.68 2012/01/03 15:53:58 ssuominen Exp $
+
+*gnome-mplayer-1.0.5 (03 Jan 2012)
+
+  03 Jan 2012; Samuli Suominen <ssuominen@g.o>
+  +gnome-mplayer-1.0.5.ebuild:
+  Version bump.
 
   22 Dec 2011; Samuli Suominen <ssuominen@g.o>
   gnome-mplayer-1.0.4.ebuild, gnome-mplayer-1.0.5_beta1.ebuild:



1.1                  media-video/gnome-mplayer/gnome-mplayer-1.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5.ebuild?rev=1.1&content-type=text/plain

Index: gnome-mplayer-1.0.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5.ebuild,v 1.1 2012/01/03 15:53:58 ssuominen Exp $

EAPI=4
inherit fdo-mime gnome2-utils

DESCRIPTION="A GTK+ interface to MPlayer"
HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="alsa +dbus +dconf gnome ipod libnotify musicbrainz pulseaudio"

COMMON_DEPEND=">=dev-libs/glib-2.26
	>=media-libs/gmtk-${PV}[dconf=]
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libXScrnSaver
	alsa? ( media-libs/alsa-lib )
	dbus? ( >=dev-libs/dbus-glib-0.92 )
	gnome? ( gnome-base/nautilus )
	ipod? ( >=media-libs/libgpod-0.7 )
	libnotify? ( >=x11-libs/libnotify-0.7 )
	musicbrainz? ( net-misc/curl
		>=media-libs/musicbrainz-3 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
RDEPEND="${COMMON_DEPEND}
	|| ( >=media-video/mplayer-1.0_rc4_p20100101[ass] media-video/mplayer2[ass] )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

DOCS="ChangeLog README DOCS/*.txt DOCS/tech/*.txt"

src_configure() {
	econf \
		--enable-gtk3 \
		$(use_enable gnome nautilus) \
		--with-gio \
		$(use_with dbus) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with libnotify) \
		$(use_with ipod libgpod) \
		$(use_with musicbrainz libmusicbrainz3)
}

src_install() {
	default
	rm -rf "${ED}"usr/share/doc/${PN}
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}