[gentoo-commits] gentoo-x86 commit in net-misc/siproxd: ChangeLog siproxd-0.7.1.ebuild

[Jeremy Olexa (darkside)]

darkside    09/03/01 02:32:31

  Modified:             ChangeLog
  Added:                siproxd-0.7.1.ebuild
  Log:
  (non maintainer commit) Version bump, ebuild by Mounir Lamouri in bug 235720
  (Portage version: 2.1.6.7/cvs/Linux x86_64)

Revision  Changes    Path
1.13                 net-misc/siproxd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/siproxd/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/siproxd/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/siproxd/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/siproxd/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	16 Feb 2009 18:47:41 -0000	1.12
+++ ChangeLog	1 Mar 2009 02:32:31 -0000	1.13
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/siproxd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/siproxd/ChangeLog,v 1.12 2009/02/16 18:47:41 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/siproxd/ChangeLog,v 1.13 2009/03/01 02:32:31 darkside Exp $
+
+*siproxd-0.7.1 (01 Mar 2009)
+
+  01 Mar 2009; Jeremy Olexa <darkside@g.o> +siproxd-0.7.1.ebuild:
+  (non maintainer commit) Version bump, ebuild by Mounir Lamouri in bug 235720
 
   16 Feb 2009; Jeremy Olexa <darkside@g.o> -siproxd-0.5.11.ebuild:
   (non maintainer commit) remove old ebuild that has QA issues, bug 226605



1.1                  net-misc/siproxd/siproxd-0.7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/siproxd/siproxd-0.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/siproxd/siproxd-0.7.1.ebuild?rev=1.1&content-type=text/plain

Index: siproxd-0.7.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/siproxd/siproxd-0.7.1.ebuild,v 1.1 2009/03/01 02:32:31 darkside Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A proxy/masquerading daemon for the SIP protocol"
HOMEPAGE="http://siproxd.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples doc static"
# TODO: debug can be used but dmalloc is breaking the build 
# upstream has been contacted, see bug 2649238 in their bugtracker

RDEPEND=">=net-libs/libosip-3.0.0"
#	debug? ( dev-libs/dmalloc[threads] )"
DEPEND="${RDEPEND}
	doc? ( app-text/docbook-sgml-utils
		app-text/docbook-sgml-dtd:4.2 )"
# docbook-sgml-utils is for building doc
# docbook-sgml-dtd is for the doc dtd even if docbook-sgml-utils depends on it

pkg_setup() {
	enewgroup siproxd
	enewuser siproxd -1 -1 /dev/null siproxd
}

src_prepare() {
	# to be sure doc is not compiled nor installed with -doc
	# quickiest way to get it disabled, other way would be patching .in file
	# upstream has been contacted, see bug 2649325 in their bugtracker
	if ! use doc; then
		sed -i -e 's/test "$docbook2/test "/' configure \
			|| die "patching configure failed"
	fi

	# make the daemon run as user 'siproxd' by default
	sed -i -e "s:nobody:siproxd:" doc/siproxd.conf.example \
		|| die "patching doc/siproxd.conf.example failed"
}

src_configure() {
	# NOTE: $(use flag && use_enable flag) is to avoid a bug
	# that makes --disable like --enable, see bug #205765
	# static-libosip2 make it link statically against libosip2
	# static build static version of plugins, forced to true
	# upstream has been contacted, see bug 2649286 in their bugtracker
	econf \
		$(use static && use_enable static static-libosip2) \
		--enable-static
		#$(use debug && use_enable debug dmalloc) \

	# statically linked plugins to libosip2 causes a shared lib linking with
	# static lib (gcc seems not to like it : portable issue it says).
	# there was also DT_TEXREL issue and stripping of static plugins failed
	# so shared lib has to be used for plugins
	# upstream has been contacted, see bug 2649351 in their bugtracker
	if use static; then
		sed -i -r -e \
			"s:LIBS =(.*)( \/[^ ]*libosip[^ ]*\.a)( \/[^ ]*libosip[^ ]*\.a)(.*):LIBS_STATIC =\1\2\3\4\nLIBS = \1\4 -losip2 -losipparser2:" \
			src/Makefile || die "patching src/Makefile failed"
		sed -i -e \
			"s:\$(siproxd_LDADD) \$(LIBS):\$(siproxd_LDADD) \$(LIBS_STATIC):" \
			src/Makefile || die "patching src/Makefile failed"
	fi
}

src_install() {
	einstall || die "einstall failed"

	newinitd "${FILESDIR}"/${PN}.rc6 ${PN} || die "newinitd failed"

	dodoc AUTHORS ChangeLog NEWS README RELNOTES TODO \
		doc/FAQ doc/FLI4L_HOWTO.txt doc/KNOWN_BUGS \
		|| die "dodoc failed"

	if use doc; then
		dodoc doc/RFC3261_compliance.txt || die "dodoc failed"
		# auto-generated doc is not auto-installed
		# upstream has been contacted, see bug 2649333 in their bugtracker
		dohtml -r doc/html/ || die "dohtml failed"
		# pdf is not build all the time
		if built_with_use app-text/docbook-sgml-utils jadetex; then
			dodoc doc/pdf/*.pdf || die "dodoc failed"
		fi
	fi

	if use examples; then
		docinto examples
		dodoc doc/sample_*.txt || die "dodoc failed"
	fi

	# set up siproxd directories
	keepdir /var/{lib,run}/${PN} || die "keepdir failed"
	fowners siproxd:siproxd /var/{lib,run}/${PN} || die "fowners failed"
}

pkg_postinst() {
	if use static; then
		elog "static USE flag does not build a _fully_ statically linked binary"
		elog "only libosip2 and libosipparser2 are statically linked"
		elog "In addition, plugins are dynamically linked with those libs"
	fi
}