[gentoo-commits] gentoo-x86 commit in sys-block/gparted: metadata.xml ChangeLog gparted-0.7.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/11/23 10:14:20

  Modified:             metadata.xml ChangeLog
  Added:                gparted-0.7.0.ebuild
  Log:
  Version bump. Add support for btrfs, fix some crashers on start and when moving logical partitions. Fix some memory leaks.
  
  (Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  sys-block/gparted/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-block/gparted/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	7 Jan 2010 22:42:34 -0000	1.8
+++ metadata.xml	23 Nov 2010 10:14:20 -0000	1.9
@@ -14,6 +14,7 @@
 	déplacer et copier différents systèmes de fichiers.
 </longdescription>
 <use>
+  <flag name='btrfs'>Include Btrfs support (<pkg>sys-fs/btrfs-progs</pkg>)</flag>
   <flag name="dmraid">Support for dmraid devices, also known as ATA-RAID, or
   Fake RAID.</flag>
   <flag name='fat'>Include FAT16/FAT32 support (<pkg>sys-fs/dosfstools</pkg>)



1.88                 sys-block/gparted/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-block/gparted/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	20 Aug 2010 17:05:10 -0000	1.87
+++ ChangeLog	23 Nov 2010 10:14:20 -0000	1.88
@@ -1,6 +1,13 @@
 # ChangeLog for sys-block/gparted
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-block/gparted/ChangeLog,v 1.87 2010/08/20 17:05:10 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-block/gparted/ChangeLog,v 1.88 2010/11/23 10:14:20 eva Exp $
+
+*gparted-0.7.0 (23 Nov 2010)
+
+  23 Nov 2010; Gilles Dartiguelongue <eva@g.o> +gparted-0.7.0.ebuild,
+  metadata.xml:
+  Version bump. Add support for btrfs, fix some crashers on start and when
+  moving logical partitions. Fix some memory leaks.
 
   20 Aug 2010; Jeroen Roovers <jer@g.o> gparted-0.5.2.ebuild,
   gparted-0.6.2.ebuild:



1.1                  sys-block/gparted/gparted-0.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/gparted-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/gparted/gparted-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: gparted-0.7.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/gparted/gparted-0.7.0.ebuild,v 1.1 2010/11/23 10:14:20 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Gnome Partition Editor"
HOMEPAGE="http://gparted.sourceforge.net/"

SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="btrfs dmraid fat gnome hfs jfs kde mdadm ntfs reiserfs reiser4 xfs xfce"

common_depends=">=sys-block/parted-2.3
	>=dev-cpp/gtkmm-2.16:2.4"

RDEPEND="${common_depends}
	gnome? ( x11-libs/gksu )
	xfce? ( x11-libs/gksu )
	kde? ( || ( kde-base/kdesu kde-base/kdebase ) )

	>=sys-fs/e2fsprogs-1.41
	btrfs? ( sys-fs/btrfs-progs )
	dmraid? ( || (
			>=sys-fs/lvm2-2.02.45
			sys-fs/device-mapper )
		sys-fs/dmraid
		sys-fs/multipath-tools )
	fat? ( sys-fs/dosfstools )
	hfs? (
		sys-fs/udev
		sys-fs/hfsutils )
	jfs? ( sys-fs/jfsutils )
	mdadm? ( sys-fs/mdadm )
	ntfs? ( sys-fs/ntfsprogs )
	reiserfs? ( sys-fs/reiserfsprogs )
	reiser4? ( sys-fs/reiser4progs )
	xfs? ( sys-fs/xfsprogs sys-fs/xfsdump )"

DEPEND="${common_depends}
	>=dev-util/pkgconfig-0.12
	>=dev-util/intltool-0.35.5
	app-text/scrollkeeper
	app-text/gnome-doc-utils
	app-text/docbook-xml-dtd:4.1.2"

pkg_setup() {
	DOCS="AUTHORS NEWS ChangeLog README"
	G2CONF="${G2CONF}
		--enable-doc
		--disable-scrollkeeper
		GKSUPROG=$(type -P true)"
}

src_prepare() {
	gnome2_src_prepare

	# Revert upstream changes to use gksu inconditionally
	sed "s:Exec=@gksuprog@ :Exec=:" \
		-i gparted.desktop.in.in || die "sed 1 failed"
}

src_install() {
	gnome2_src_install

	if use kde; then
		cp "${D}"/usr/share/applications/gparted.desktop \
			"${D}"/usr/share/applications/gparted-kde.desktop

		sed -i "s:Exec=:Exec=kdesu :" "${D}"/usr/share/applications/gparted-kde.desktop
		echo "OnlyShowIn=KDE;" >> "${D}"/usr/share/applications/gparted-kde.desktop
	fi

	if use gnome || use xfce; then
		sed -i "s:Exec=:Exec=gksu :" "${D}"/usr/share/applications/gparted.desktop
		echo "OnlyShowIn=GNOME;XFCE;" >> "${D}"/usr/share/applications/gparted.desktop
	else
		echo "OnlyShowIn=X-NeverShowThis;" >> "${D}"/usr/share/applications/gparted.desktop
	fi
}