[gentoo-commits] gentoo-x86 commit in www-client/epiphany: ChangeLog epiphany-2.24.0.1.ebuild

[Mart Raudsepp (leio)]

leio        08/10/06 05:01:42

  Modified:             ChangeLog
  Added:                epiphany-2.24.0.1.ebuild
  Log:
  New version. Improves xulrunner-1.9 usage, user cert saving in particular; complete-download sound with libcanberra; bug fixes and code cleanups
  (Portage version: 2.2_rc11/cvs/Linux 2.6.26-gentoo-r1 x86_64)

Revision  Changes    Path
1.171                www-client/epiphany/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.171&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.171&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?r1=1.170&r2=1.171

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v
retrieving revision 1.170
retrieving revision 1.171
diff -u -r1.170 -r1.171
--- ChangeLog	25 Sep 2008 15:55:56 -0000	1.170
+++ ChangeLog	6 Oct 2008 05:01:42 -0000	1.171
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/epiphany
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.170 2008/09/25 15:55:56 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.171 2008/10/06 05:01:42 leio Exp $
+
+*epiphany-2.24.0.1 (06 Oct 2008)
+
+  06 Oct 2008; Mart Raudsepp <leio@g.o> +epiphany-2.24.0.1.ebuild:
+  New version. Improves xulrunner-1.9 usage, user cert handling in
+  particular; complete-download sound with libcanberra; bug fixes and code
+  cleanups
 
   25 Sep 2008; Jeroen Roovers <jer@g.o> epiphany-2.22.3.ebuild:
   Stable for HPPA (bug #236971).



1.1                  www-client/epiphany/epiphany-2.24.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/epiphany-2.24.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/epiphany-2.24.0.1.ebuild?rev=1.1&content-type=text/plain

Index: epiphany-2.24.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-2.24.0.1.ebuild,v 1.1 2008/10/06 05:01:42 leio Exp $

EAPI="1"
inherit gnome2 eutils multilib

DESCRIPTION="GNOME webbrowser based on the mozilla rendering engine"
HOMEPAGE="http://www.gnome.org/projects/epiphany/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi doc networkmanager python spell"

RDEPEND=">=dev-libs/glib-2.16.0
	>=x11-libs/gtk+-2.14.0
	>=dev-libs/libxml2-2.6.12
	>=dev-libs/libxslt-1.1.7
	>=gnome-base/libglade-2.3.1
	>=gnome-base/libgnome-2.14
	>=gnome-base/libgnomeui-2.14
	>=gnome-base/gnome-desktop-2.9.91
	>=x11-libs/startup-notification-0.5
	>=x11-libs/libnotify-0.4
	>=media-libs/libcanberra-0.3
	>=dev-libs/dbus-glib-0.71
	>=gnome-base/gconf-2
	>=app-text/iso-codes-0.35
	avahi? ( >=net-dns/avahi-0.6.22 )
	networkmanager? ( net-misc/networkmanager )
	=net-libs/xulrunner-1.9*
	python? (
		>=dev-lang/python-2.3
		>=dev-python/pygtk-2.7.1
		>=dev-python/gnome-python-2.6
	)
	spell? ( app-text/enchant )
	x11-themes/gnome-icon-theme"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40
	>=app-text/gnome-doc-utils-0.3.2
	doc? ( >=dev-util/gtk-doc-1 )"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"

pkg_setup() {
	# FIXME: I'm automagic
	if ! built_with_use media-libs/libcanberra gtk; then
		eerror "You need to rebuild media-libs/libcanberra with gtk support."
		die "Rebuild media-libs/libcanberra with USE='gtk'"
	fi

	G2CONF="${G2CONF}
		--disable-scrollkeeper
		--with-gecko=libxul-embedding
		--enable-certificate-manager
		--with-distributor-name=Gentoo
		$(use_enable avahi zeroconf)
		$(use_enable networkmanager network-manager)
		$(use_enable spell spell-checker)
		$(use_enable python)"
}

src_compile() {
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat.tmp
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/compreg.dat.tmp

	# Why are these write-opened per bug 228589?
	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat
	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat.tmp

	gnome2_src_compile
}