[gentoo-commits] proj/kde:master commit in: dev-libs/statusnotifier/

[Andreas Sturmlechner]

commit:     38d59469deea09be110c03040acdc3cfb4242db4
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 12 13:14:21 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec 12 13:14:21 2018 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=38d59469

dev-libs/statusnotifier: 1.0.0 version bump

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../statusnotifier/statusnotifier-1.0.0.ebuild     | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-libs/statusnotifier/statusnotifier-1.0.0.ebuild b/dev-libs/statusnotifier/statusnotifier-1.0.0.ebuild
new file mode 100644
index 0000000000..8edf109f88
--- /dev/null
+++ b/dev-libs/statusnotifier/statusnotifier-1.0.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Library to use KDE's StatusNotifierItem via GObject"
+HOMEPAGE="https://github.com/jjk-jacky/statusnotifier"
+SRC_URI="https://github.com/jjk-jacky/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dbus examples introspection"
+
+BDEPEND="dev-util/gtk-doc"
+DEPEND="
+	dev-libs/glib:2
+	x11-libs/gdk-pixbuf:2
+	x11-libs/cairo
+	dbus? (
+		dev-libs/libdbusmenu[gtk3]
+		x11-libs/gtk+:3
+	)
+	examples? ( x11-libs/gtk+:3 )
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	eautoreconf
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		$(use_enable dbus dbusmenu)
+		$(use_enable introspection)
+		$(use_enable examples example)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}