[gentoo-commits] gentoo-x86 commit in sys-apps/v86d: ChangeLog v86d-0.1.10.ebuild

[Michael Januszewski (spock)]

spock       11/02/26 00:34:44

  Modified:             ChangeLog
  Added:                v86d-0.1.10.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 sys-apps/v86d/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/v86d/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/v86d/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/v86d/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/v86d/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	28 Nov 2010 18:27:20 -0000	1.31
+++ ChangeLog	26 Feb 2011 00:34:44 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/v86d
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/v86d/ChangeLog,v 1.31 2010/11/28 18:27:20 spock Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/v86d/ChangeLog,v 1.32 2011/02/26 00:34:44 spock Exp $
+
+*v86d-0.1.10 (26 Feb 2011)
+
+  26 Feb 2011; Michał Januszewski <spock@g.o> +v86d-0.1.10.ebuild:
+  Version bump.
 
   28 Nov 2010; Michał Januszewski <spock@g.o> v86d-0.1.9.ebuild:
   Disable stack protector (bug #346397).



1.1                  sys-apps/v86d/v86d-0.1.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/v86d/v86d-0.1.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/v86d/v86d-0.1.10.ebuild?rev=1.1&content-type=text/plain

Index: v86d-0.1.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/v86d/v86d-0.1.10.ebuild,v 1.1 2011/02/26 00:34:44 spock Exp $

EAPI=2

inherit eutils flag-o-matic linux-info multilib

DESCRIPTION="A daemon to run x86 code in an emulated environment."
HOMEPAGE="http://dev.gentoo.org/~spock/projects/uvesafb/"
SRC_URI="http://dev.gentoo.org/~spock/projects/uvesafb/archive/${P/_/-}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug x86emu"

DEPEND="dev-libs/klibc"
RDEPEND=""

S="${WORKDIR}/${P//_*/}"

pkg_setup() {
	if [ -z "$(grep V86D /usr/$(get_libdir)/klibc/include/linux/connector.h)" ]; then
		eerror "You need to compile klibc against a kernel tree patched with uvesafb"
		eerror "prior to merging this package."
		die "Kernel not patched with uvesafb."
	fi
	linux-info_pkg_setup
}

src_configure() {
	./configure --with-klibc $(use_with debug) $(use_with x86emu) || die
}

src_compile() {
	# Disable stack protector, as it does not work with klibc (bug #346397).
	filter-flags -fstack-protector -fstack-protector-all
	emake KDIR="${KV_DIR}" || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc README ChangeLog

	insinto /usr/share/${PN}
	doins misc/initramfs
}

pkg_postinst() {
	elog "If you wish to place v86d into an initramfs image, you might want to use"
	elog "'/usr/share/${PN}/initramfs' in your kernel's CONFIG_INITRAMFS_SOURCE."
}