[gentoo-commits] repo/gentoo:master commit in: dev-python/setuptools/

[Michał Górny]

commit:     4bf0976fcd01ab25f89c096000622fd81636ea9e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  1 10:32:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Feb  1 10:43:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bf0976f

dev-python/setuptools: Bump to 60.6.0

Bump to 60.6.0 release.  Remove *.extern modules that sometimes breaks
packaging.version when the dependencies are unbundled.

Closes: https://bugs.gentoo.org/832473
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/setuptools/Manifest                 |   1 +
 dev-python/setuptools/setuptools-60.6.0.ebuild | 106 +++++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index d303038daf1a..e9243a199451 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -4,3 +4,4 @@ DIST setuptools-60.2.0.tar.gz 2282807 BLAKE2B 97d54353050d4e8a009e617a112c23d707
 DIST setuptools-60.3.0.tar.gz 2283824 BLAKE2B c0e1ffb6c19fd4c85aed2878a95e23372131e5c069551b39af477c72d591608e73d1bd9710d34a8540c226a0dbb91dd9def170121672daf2928d039f589c238e SHA512 71c19147e8f34a5eb2c830ad0942bcb1a468a3ae07c91035fb19eb50d549dbc3b9e992dd2b654383843ac6ba088a46dedfe928850417da92c24f1c5bf3e8b6c9
 DIST setuptools-60.3.1.tar.gz 2284193 BLAKE2B 0138acaf830d7f29db95c759e60d77986113385b13e96446974b63abf3621db2d2fd033f0f45bf380b6cfb2066ed66ff008446ca595f741c3f5446107f2a554b SHA512 7a2434d857b2914136d5ec0a7b9fbd89352a5dd3452bf2e3f7c0e2ef7317b45a3cfe6d3921b7f61a1f0a99a7c06f73428f9871dac0d7ae481fa1a1a0b97042cb
 DIST setuptools-60.5.0.tar.gz 2292478 BLAKE2B e41b2717b34d454b3959ee5b6f4fdc70dfec13d97fe6962bd1c1ea2296be8ee2d27bb14ed2cc5e6fb9a757661a0415984b3cf7cf1665347c62a50965f651f9d4 SHA512 b2cf7d99e60d0c862a7a4fd8e806019db52502de48ff77556df26ce39a8620f476de767e2e8be8aa260366f54d1429db8a42d538345ec2cd2cfd5286e62e770d
+DIST setuptools-60.6.0.tar.gz 2292575 BLAKE2B 410f4eee4e83c14dd1ebc3ab103f9e12bc5092e2e82dece8e71e7be57abc3d41c50763560e94343fe5089c7b903fa223fdab9c9c4648f423fcbd525551c501ef SHA512 9c0bed3d5f3e051fc996c26c2bc8d7ba0193c119a98678c7ef38ee1fdf8b42e569995598e64b527b5c6f1b4c77de655d1d7bdcd526a6d90288fd34efca92ff03

diff --git a/dev-python/setuptools/setuptools-60.6.0.ebuild b/dev-python/setuptools/setuptools-60.6.0.ebuild
new file mode 100644
index 000000000000..1088bc0dce27
--- /dev/null
+++ b/dev-python/setuptools/setuptools-60.6.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/ordered-set[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	dev-python/wheel[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/tomli[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]extern ::' -e 's:\w*[.]extern[.]::' \
+		-i {} + || die
+
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}