[gentoo-commits] gentoo-x86 commit in app-i18n/ibus: metadata.xml ChangeLog ibus-1.3.1.ebuild

[Matsuu Takuto (matsuu)]

matsuu      10/04/03 04:03:39

  Modified:             metadata.xml ChangeLog
  Added:                ibus-1.3.1.ebuild
  Log:
  Version bumped. Fixed python dependency, bug #311211. Added new USE flags.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  app-i18n/ibus/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/ibus/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	1 Oct 2008 16:20:57 -0000	1.2
+++ metadata.xml	3 Apr 2010 04:03:39 -0000	1.3
@@ -7,4 +7,7 @@
 full featured and user friendly input method user interface. It also may help
 developers to develop input method easily.
 </longdescription>
+<use>
+  <flag name='gconf'>Enable support for <pkg>gnome-base/gconf</pkg></flag>
+</use>
 </pkgmetadata>



1.56                 app-i18n/ibus/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	27 Mar 2010 07:03:28 -0000	1.55
+++ ChangeLog	3 Apr 2010 04:03:39 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/ibus
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.55 2010/03/27 07:03:28 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.56 2010/04/03 04:03:39 matsuu Exp $
+
+*ibus-1.3.1 (03 Apr 2010)
+
+  03 Apr 2010; MATSUU Takuto <matsuu@g.o> +ibus-1.3.1.ebuild,
+  metadata.xml:
+  Version bumped. Fixed python dependency, bug #311211. Added new USE flags.
 
 *ibus-1.2.1 (27 Mar 2010)
 



1.1                  app-i18n/ibus/ibus-1.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ibus-1.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ibus-1.3.1.ebuild?rev=1.1&content-type=text/plain

Index: ibus-1.3.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.1.ebuild,v 1.1 2010/04/03 04:03:39 matsuu Exp $

EAPI="2"
PYTHON_DEPEND="python? 2:2.5"
inherit eutils gnome2-utils multilib python

DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
HOMEPAGE="http://code.google.com/p/ibus/"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gconf nls python"

RDEPEND=">=dev-libs/glib-2.18
	>=x11-libs/gtk+-2
	gconf? ( >=gnome-base/gconf-2.12 )
	>=gnome-base/librsvg-2
	sys-apps/dbus
	app-text/iso-codes
	x11-libs/libX11
	python? (
		>=dev-python/pygobject-2.14
		dev-python/notify-python
		>=dev-python/dbus-python-0.83
	)
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	>=dev-lang/perl-5.8.1
	dev-perl/XML-Parser
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.9 )
	nls? ( >=sys-devel/gettext-0.16.1 )"
RDEPEND="${RDEPEND}
	python? (
		dev-python/pygtk
		dev-python/pyxdg
	)"

RESTRICT="test"

update_gtk_immodules() {
	if [ -x /usr/bin/gtk-query-immodules-2.0 ] ; then
		GTK2_CONFDIR="/etc/gtk-2.0"
		# An arch specific config directory is used on multilib systems
		has_multilib_profile && GTK2_CONFDIR="${GTK2_CONFDIR}/${CHOST}"
		mkdir -p "${ROOT}${GTK2_CONFDIR}"
		gtk-query-immodules-2.0 > "${ROOT}${GTK2_CONFDIR}/gtk.immodules"
	fi
}

src_prepare() {
	mv py-compile py-compile.orig || die
	ln -s "$(type -P true)" py-compile || die
	echo "ibus/_config.py" >> po/POTFILES.skip || die
}

src_configure() {
	econf \
		$(use_enable doc gtk-doc) \
		$(use_enable gconf) \
		$(use_enable nls) \
		$(use_enable python) || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	# bug 289547
	keepdir /usr/share/ibus/{engine,icons} || die

	dodoc AUTHORS ChangeLog NEWS README || die
}

pkg_postinst() {

	elog "To use ibus, you should:"
	elog "1. Get input engines from sunrise overlay."
	elog "   Run \"emerge -s ibus-\" in your favorite terminal"
	elog "   for a list of packages we already have."
	elog
	elog "2. Setup ibus:"
	elog
	elog "   $ ibus-setup"
	elog
	elog "3. Set the following in your user startup scripts"
	elog "   such as .xinitrc, .xsession or .xprofile:"
	elog
	elog "   export XMODIFIERS=\"@im=ibus\""
	elog "   export GTK_IM_MODULE=\"ibus\""
	elog "   export QT_IM_MODULE=\"xim\""
	elog "   ibus-daemon -d -x"

	update_gtk_immodules

	use python && python_mod_optimize /usr/share/${PN}
	gnome2_icon_cache_update
}

pkg_postrm() {
	update_gtk_immodules

	use python && python_mod_cleanup /usr/share/${PN}
	gnome2_icon_cache_update
}